ＥＸＣＥＬ関数を使って抽出したい。

質問

ＥＸＣＥＬ関数を使った作り込みをしたいのですが、悩んでいます。
以下の様なＤＢがあって（ちなみに数値データで異なる日付間でデータが重複することはありません。あるデータは必ず唯一その日付のものです。）、

日付1　　　日付2　　・・・
データ　　データ
データ　　データ　　・・・
データ　　データ

このＤＢからあるいずれかのデータを入力すると同じ列の日付を表示させると言うものです。なお日付は当月１～３１とします。

ヒントになる助言でも結構です。
詳しい方いらっしゃいましたら教えて頂きたいです。
ちなみにオフィス２０００です。
お願いします。

回答No.5

web2525 · ベストアンサー

No3です

よく考えたら作業セルの必要なかったです。

日付回答欄に
｛=SUM((データ領域=日付入力セル)*日付領域)｝
の一発で出来ます。
データ領域：データの入っている範囲（No3の回答で言うとB3:D5）
日付領域：日付の入っている範囲（同じくB2:D2）
入力は
=SUM((データ領域=日付入力セル)*日付領域)
の入力後shift]+[ctrl]+[Enter]で

ただあまりデータが多いと計算に時間がかかる可能性があります。

お礼

さっそく試してみました。
感動しました。
てっきりＩＮＤＥＸとかＶＬＯＯＫＵＰなどの関数を想定してたのですがまさかＳＵＭで出来るとは思ってもいませんでした。
さらに入力と回答欄を行方向に拡張して実用的にしようと思っています。
ご回答ありがとうございます。

回答No.6

zap35

A2:D30にデータ、D2に検索したいデータがあるとき適当なセルに
　=OFFSET($A$1,0,SUMPRODUCT((A2:C30=D2)*COLUMN(A2:C30))-1)
で行けるように思います。

データ範囲は実際のシートに合わせて変更して下さい。なお検索データが表中にない場合は#REF!エラーになりますので適宜エラー処理を追加して下さい

お礼

初級レベルなので関数の意味すら解からないのでコピペして範囲修正したらうまくいきました。
みなさまの良回答を元に実データを使ってさらなる作り込みをして実用化しようと思っています。
ご回答ありがとうございます。
本当に助かりました。

回答No.4

Ce_faci

こんばんわ
ご質問から外れるかもしれません。
関数を使ってとのことですが、使わなくても日付は出せます。
アクティブなセルの列と行は、色が変わるなり立体的に見せる（セルB2にカーソルがあればグレーの部分のBと２が目立ちますよね）ことと画面分割を利用します。

以下がやり方です
（１）12月1日にカーソルを合わせてメニューの[ウィンドウ]－[分割]を選択。ワークシートに太線が12月1日に出ます。（もし他の位置に太線が出た場合はマウスでクリックすれば動きますので、縦の太線は12月1日と2日の間に、横の太線は日付のすぐ下に移動させます）
（２）もう一度、メニューの[ウィンドウ]を開いて今度は[ウィンドウ枠の固定]を選択。
（３）キーボードで[Ctrl]キーを押しながら[F]キーを押します。（マウスなら[編集]－[検索]、または望遠鏡アイコン）
（４）白の長四角の中に探したい「データ」を入力して、”セル内容が完全に……”のすぐ左の□にチェックをつけて[次を検索]をクリック。

出したい日付がすぐ見つかります。

回答No.3

web2525

データが重複していないことが前提ですが
一部作業セルを利用します
Ａ　　Ｂ　　Ｃ　　Ｄ・・・・・
1　　＜　　作用セル　　＞
2　12/1　12/2　12/3　12/4
3　data　data　data　data
4　data　data　data　data
5　data　data　data　data

作業セルA1に
=NOT(ISERROR(MATCH(日付入力セル,A3:A100,0)))
を入力し右方向にコピー
この際に日付セルは絶対参照で。
日付回答欄には
｛=SUM(A1:E1*A2:E2)｝
を入力、E1　E2の部分は検証したのが５日分なので実際の場合はデータの最終列を選択してくださ
実際の入力は
=SUM(A1:E1*A2:E2)
を入力後[shift]+[ctrl]+[Enter]で行います。
後は、日付回答欄の書式を日時に設定で完了。

回答No.2

noname#64582

しろうとです。
少し考えてみました。
データは3行分だけですか？　
3行だったら何とかなりました。あまりにも美しくないけど。

例）　　A　　　B　　　C
1列目　12/1　12/2　　12/3
2列目　　1　　　4　　　7
3列目　　2　　　5　　　8
4列目　　3　　　6　　　9

とあれば、5行目に1列目（日付）をコピペします。見せたくなければ非表示にすればいいです。

入力セルを仮にE1とします。
日付の回答欄をF1とします。

F1セルに
=IF(ISERROR(HLOOKUP(E1,A2:C5,4,0))=FALSE,HLOOKUP(E1,A2:C5,4,0),IF(ISERROR(HLOOKUP(E1,A3:C5,3,0))=FALSE,HLOOKUP(E1,A3:C5,3,0),HLOOKUP(E1,A4:C5,2,0)))

データの行数があまり多いとこの方法は無理ですけどね。
IF関数のネスト数まで（７つまででしたか）なら対応できます。式を書くのにめんどくさいのが難点。

補足

ご回答ありがとうございます。
即答でこんな複雑な関数式が・・。
唖然としました。すばらしいの一言です。
説明不足でたびたび申し訳ないのですが、一日あたりおおよそ１００行分のデータでお願いしたいです。大変恐縮です。

回答No.1

imogasi

＞作り込みをしたいのですが
あまり聞きなれない表現です。
関数を使って（オートフィルタやVBAを使うのでなく）実現したいということでしょう。
＞ちなみに数値データで異なる日付間でデータが重複す
ることはありません。あるデータは必ず唯一その日付のものです
この意味がわかりません。
例をあげる場合、「データ」と抽象化しないで、（仮のものでも）具体的な例を入れ、それが何に当たるデータなのか説明した方が、回答者・読者にイメージがわいて判りやすいと思う。
＞抽出したい
関数で条件に合ったものを、別シートに抜き出す（１つの）方法は、
googleで「imogasi方式」でWEB照会してもらえば、沢山例が出ます。
ほかにもOKWAVEで、「関数　抜き出し　抽出」などで検索してみては。

補足

ご回答ありがとうございます。
説明不足でしたね。
ＥＸＣＥＬを単にテキスト入力の用途ではなく関数を使った作り込みといった表現が正しかったかもしれません。
あとデータを具体化してみると、

１２/１　　１２／２　　１２／３　　　　入力欄　日付の回答
　１　　　　　４　　　　　７　　　　　　　1　　　１２／１
　２　　　　　５　　　　　８　　　　　　　　　↑
　３　　　　　６　　　　　９　　　　　　　みたいな答え

いずれのデータも単一のものです。