エクセルのマクロでDOSのコマンドを記述するには？

質問

デスクトップにa.prnとb.prnというファイルがあります。a.prnとb.prnを結合しa.prnを作成したのちb.prnを削除する作業をエクセルのマクロに記入したいのですがどうしらいいでしょうか？おしえてください。

回答No.3

Wendy02 · ベストアンサー

#2 の Wendy02です。
#1 さんのおっしゃっていたものを作ってみました。ただし、アペンドモードにしました。
結合中にエラー（バイナリコードが入るなど)が、でると、最初のファイルはアペンドモードですから、戻しが利きませんので、バックアップファイルが必要です。

なお、#2 の
　TmpFn = " tmp.prn"
製作中の段階で、作っていたもので、これは不要の行ですから、削除してしまってください。
別に試さなくてもよいです。こちらのほうが確実です。

Sub FileCombine()
Dim Fn1 As String
Dim Fn2 As String
Dim msg As String

Dim Fno1 As Integer
Dim Fno2 As Integer
Dim LineText As String

'ファイル名設定
Fn1 = "a.prn"
Fn2 = "b.prn"

If Len(Dir(Fn1)) = 0 Or Len(Dir(Fn2)) = 0 Then
　 msg = Left$(Fn1, Len(Fn1) - Len(Dir(Fn1))) & " " & _
　　　　 Left$(Fn2, Len(Fn2) - Len(Dir(Fn2)))
　 MsgBox msg & "のファイルがありません。"
　 Exit Sub
End If

Fno2 = FreeFile()
Open Fn2 For Input As #Fno2

Fno1 = FreeFile()
Open Fn1 For Append As #Fno1

Do Until EOF(Fno2)
　Line Input #Fno2, LineText
　Print #Fno1, LineText
Loop
Close #Fno1
Close #Fno2

'ファイル削除
Kill Fn2

MsgBox "結合しました。", vbInformation

End Sub

お礼

ありがとうございます。参考にさせていただきました。

回答No.4

gori8063

#1です。先を越されたかな（ｗ

単純な系で書いてます。

Sub Merge_Files()

Dim dt
Open "c:\file1.prn" For Input As #1
Open "c:\Output_File.prn" For Output As #2

Do Until EOF(1) = True

Line Input #1, dt
Print #2, dt

Loop

Close #1

Open "c:\file2.prn" For Input As #1
Do Until EOF(1) = True

Line Input #1, dt
Print #2, dt

Loop

Close #1
Close #2

FileCopy "c:\Output_File.prn", "c:\file1.prn"
Kill "c:\Output_File.prn"

End Sub

お礼

ありがとうございます。勉強になりました。

回答No.2

Wendy02

こんばんは。

>a.prnとb.prnを結合しa.prnを作成したのち

prn ファイルはテキストファイルですから、一見、MS-DOSのほうが楽のようですね。

Win のバージョンがあるので、XP でしたら、下記のようなCMD.EXE ですが、そうでないなら、Command.Com になります。　スペースを削除しないでください。
たぶん、そのままでいけると思いますが、どうも、確実性に欠けるようです。#1 さんのご指摘にある方法がよいかもしれませんね。

Sub ShellCommandPrc()
Dim Fn1 As String
Dim Fn2 As String
Dim ComExe As String
Dim myPath As String
Dim ret As Integer

myPath = CurDir

'フォルダ変更する場合は、以下で行う
' Chdir

'ファイル名設定

Fn1 = "a.prn"
Fn2 = "b.prn"

If Dir(Fn1) = "" Or Dir(Fn2) = "" Then
　 MsgBox "どちらかのファイルがありません。"
　 Exit Sub
End If

ComExe = "CMD.EXE /C COPY " 'Win 2x系
'ComExe = "COMMAND.COM /C "　'Win 9x 系

TmpFn = " tmp.prn"

ret = Shell(ComExe & Fn1 & "+" & Fn2 & " " & Fn1)

'タイムラグ
Application.Wait Now() + TimeValue("00:00:03")

If ret > 0 Then
　　Kill Fn2
End If

ChDir myPath
End Sub

バックアップを取ったほうがよさそうです。要するに、Dos ステージに行って、帰ってくるタイムロスは、VBA上で行うスピードとは違うので、素通りしてしまい、コピーし結合前に、第二番目のファイルを削除してしまうことがあります。

回答No.1

gori8063

shellコマンドで行けそうな気もしますが。
http://homepage2.nifty.com/kasayan/vba/vba3.htm

MS-DOS窓が出てくると表示がスマートではないですよね。

prn形式って、テキストベースですよね。
VBAのファイル操作で１枚目のファイル開いてデータ読んで、ファイルに書き出して、２枚目のファイル開いてデータ読んで、ファイルに書き出して、最後に書き出しファイルを閉じてその名前を変更する。という手順でどうでしょうかね。