このマクロ、どこがおかしいですか？

質問

i5とj5のセルの文字が同じ場合はセル同士を結合して一つ下の行へ行き、i5とj5のセルに何も書かれていないときはそのまま一つ下の列へ行き、行った先のセルでも同じように処理(i6とj6のセルの文字が同じ場合はセル同士を結合して一つ下の行へ行き、i6とj6のセルに何も書かれていないときはそのまま一つ下の列へ行き)を繰り返し、と言うことをi33とj33のセルまで続けたいと思っています。

Sub よろしくお願いします()
Dim i As Integer
For i = 5 To 33
Cells(i, 9).Select
If Cells(i, 9).Value = Cells(i, 10).Value Then
Range(Cells(i, 9), Cells(i, 10)).Merge
Selection.Offset(i + 1).Select
ElseIf Cells(i, 9).Value = "" Then
Selection.Offset(i + 1).Select
Next i
End If
End Sub
と書いたのですが、『Nextに対応するForがありません』と言われてしまいます。どうすれば思い通りにできるでしょうか？

極めて初心者で、伝わりにくい点があるかもしれません。よろしくお願いします。

回答No.3

merlionXX · ベストアンサー

No1-2の方の指摘もそうですが、あとはご要望の動きをさせるためにはもっと変えなくてはいけないと思います。

こんな感じではどうでしょう？

Sub TEST()
Dim i As Integer
For i = 5 To 33
Cells(i, 9).Select
If Cells(i, 9).Value <> "" And Cells(i, 9).Value = Cells(i, 10).Value Then
Application.DisplayAlerts = False '結合の警告を止める
Range(Cells(i, 9), Cells(i, 10)).Merge
Application.DisplayAlerts = True '警告を元通りに
End If
Next i
End Sub

Application.DisplayAlerts = False は警告を止めるものですので警告が必要でしたら不用です。

お礼

まさにこれがしたかったんです！ありがとうございます。

回答No.6

Wendy02

こんにちは。

たぶん、こんなところだと思います。

＞i5とj5のセルに何も書かれていないときはそのまま一つ下の列へ行き、
というロジックですと、i5 か j 5 のどちらかにある場合はどうするか書かれていませんが、たぶん、どちらかにある時も、結合するものだと考えました。

もし、そうだとすれば、ロジックとしては、これは思ったよりも簡単ではありませんね。
もし違うなら、
ElseIf WorksheetFunction.Count(c.Resize(, 2)) = 1 Then
c.Resize(, 2).Merge

の部分は余分です。

それから、Mergeメソッドを使う時は、最初に、片方を削除してから行います。

なお、Resize(,2) というのは、Range(c, c.offset(,1)) の意味です。

Sub MergeCellsProc()
Dim c As Range
　 For Each c In Range("I5:I33")
　　　 If WorksheetFunction.Count(c.Resize(, 2)) = 2 And _
　　　　 c.Value = c.Offset(, 1).Value Then
　　　　　c.Offset(, 1).ClearContents
　　　　　c.Resize(, 2).Merge
　　　 ElseIf WorksheetFunction.Count(c.Resize(, 2)) = 1 Then
　　　　　c.Resize(, 2).Merge　'片方に数値がある場合
　　　 End If
　 Next c
End Sub

お礼

皆さんすごいですよねぇ。素直に尊敬します。回答ありがとうございました！

回答No.5

noname#22222

If Len(Cells(I, C).Value & Cells(I, D).Value & "") > 0 Then
　　　　　　　　　　　　　　　　　　|
　　　　　　　　　　　　　　　　　　バグ！！

回答No.4

noname#22222

Private Sub CommandButton1_Click()
　　Application.DisplayAlerts = False
　　MargeCels2 5, 11, 9
　　　　　　　　　　|　　|　 |
　　　　　　　　　　|　　|　 +--->　Marge 列
　　　　　　　　　　|　　+----->　Marge 終了行
　　　　　　　　　 +-------->　Marge 開始行
　　Application.DisplayAlerts = True
End Sub

Public Sub MargeCels(ByVal S As Integer, ByVal E As Integer, ByVal C As Integer)
　　Dim I As Integer
　　Dim D As Integer

　　D = C + 1
　　For I = S To E
　　　　If Len(Cells(I, C).Value & Cells(I, C).Value & "") > 0 Then
　　　　　　If Cells(I, C).Value = Cells(I, D).Value Then
　　　　　　　　Range(Cells(I, C), Cells(I, D)).Merge
　　　　　　End If
　　　　End If
　　Next I
End Sub

※単にマージするだけであれば、こんな感じでもOKかと！
※一応は、質問者のコードと実行結果を比較してみましたが、両者の差異が判りません！
※Excel　は、一度しか使ったことがない門外漢ですので悪しからず！

お礼

う～ん、難しい…。まだまだ修行が足りませんね。この回答が理解できるように頑張ります。回答ありがとうございました！

回答No.2

cockerel

If文の中にNext iが入ってしまっています。
そのほかの詳細については検討していません。
なお、エディタ等を使用して作成している場合にはインデントを使用してレベルを整理するとわかりやすくなります。

お礼

そうですね。ごちゃごちゃになると何をしているのかが分かりにくいし…。回答ありがとうございます。

回答No.1

edomin

中身については全く検証していませんが、
「EndIf」と「Next i」の位置が逆でしょう？
この場合、ElseIfが実行されないとNextが実行されませんよ。

お礼

なるほど！確かにできました。
回答ありがとうございます。