最終行に貼り付けるマクロ

質問

個人の住所録ブックＡがあります。

1行目　作成日　郵便番号　住所　名前　

です。（これは常に１行です）

この１行をコピーして、共有のブックＢに追加して保存したいのです。
共有のブックＢは、パスワード（****）があります。
そして、これまでのデータが入っています。
その最終行を検索して貼り付けるマクロを教えてください。

エクセル2003です。
よろしくお願いします。

回答No.6

onntao · ベストアンサー

#2,4,5 onntao です

追記です
構文中のパスワードが正しいものとして
WriteResPassword:="ぱすわーど"
　　　　　　↓
　　Password:="ぱすわーど"
としてみてください

お礼

ありがとうございました！！
無事パスワードもクリアしました。

とっても助かりました。
またよろしくお願いします♪

回答No.8

papayuka

> でも、同じエラーが出るのですが・・
> インデックスエラーです。

当然ですが、Workbooks("xxx") の "Book1" や "Book2" をご自分の環境に合わせなければエラーになります。

それ以外では A65536 まで行が使われているとエラーが起こります。

お礼

もちろん、ブック名・シート名は変えています。

ご協力、ありがとうございます。
とっても助かりました。

回答No.7

Wendy02

こういうことかな？
パスワード等は、ご自身で入れてください。

'---------------------------------------
'パスワード
Const MYPW As String = "abc"
Sub test()
　Dim Fname As String
　Dim myWb As Workbook
　'共有ブックパス:注意－必ず最後に『\』をいれてください。
　Const myPath As String = "○○\●●●\"
　'共有ブック名
　Fname = "B.xls"
　'データソースブック
　Set myWb = Workbooks("A.xls")
　'すでに開いている場合のメッセージを出さない
　Application.DisplayAlerts = False
　'画面のちらつきを止める
　Application.ScreenUpdating = False
　　'パスワード付ブックオープン
　With Workbooks.Open(myPath & Fname, , , , MYPW, MYPW")
　　'貼り付け(作成日,郵便番号,住所,名前)
　　.Worksheets("Sheet1").Range("A65536").End(xlUp).Offset(1).Resize(, 4).Value = _
　　myWb.Worksheets("Sheet1").Range("A1").Resize(, 4).Value
　　'終了と保存
　　.Close True
　End With
　Application.ScreenUpdating = True
　Application.DisplayAlerts = True
　Set myWb = Nothing
End Sub

お礼

ありがとうございます。
説明を入れてもらったんですね♪

自分でＶＢＡの勉強をする前に、みなさんに頼ってしまってごめんなさい。

回答No.5

onntao

#2,4 onntao です

>共有のブックＢは、パスワード（****）があります。
のパスワードとはどのような手順で設定したものでしょうか？

WriteResPassword:="ぱすわーど"
の部分はファイル＜名前をつけて保存　の中のツール（L)＜全般オプション<書き込みパスワード　にて設定したものに対するものです。
また、"ぱすわーど"はmarilinさんが実際にお使いのものに修正されていますよね　(^-^)/

回答No.4

onntao

#2 onntao です

Sub Test()

Workbooks.Open Filename:="C:\Documents and Settings\○○○\○○○\ブックＢ.xls", WriteResPassword:="ぱすわーど"

Workbooks("ブックＡ.xls").Worksheets("入力").Rows(1).Copy

Workbooks("ブックＢ.xls").Worksheets("データベース"). _
Range("A65536").End(xlUp).Offset(1, 0).PasteSpecial Paste:=xlPasteValues

Workbooks("ブックＢ.xls").Close SaveChanges:=True

Application.CutCopyMode = False

End Sub

"入力"、"データベース"などのシート名をmarilinさんが実際にお使いのものにしてください

お礼

ありがとうございます。

今、自宅でテストしてみたら、うまくいきそうです。
月曜日に会社でやってみます。

ただ、ブックBのパスワードを入れるようにメッセージが出ますが、これは仕方ないのですか？

回答No.3

papayuka

#1です。

> コピーして貼り付けるときに、「値」を貼り付ける場合、どうなりますか？

Sub Test1()
　Workbooks("Book1").ActiveSheet.Rows(1).Copy
　Workbooks("Book2").ActiveSheet.Range("A65536").End(xlUp). _
　　　　　　　　Offset(1, 0).EntireRow.PasteSpecial xlPasteValues
　Application.CutCopyMode = False
End Sub

お礼

ありがとうございました。

でも、同じエラーが出るのですが・・
インデックスエラーです。

回答No.2

onntao

Sub Test()
Workbooks.Open Filename:="C:\Documents and Settings\○○○\○○○\ブックＢ.xls", WriteResPassword:="ぱすわーど"

Workbooks("ブックＡ.xls").Worksheets("sheet1").Rows(1).Copy Destination:= _
Workbooks("ブックＢ.xls").Worksheets("sheet1"). _
Range("A65536").End(xlUp).Offset(1, 0).EntireRow

Workbooks("ブックＢ.xls").Close SaveChanges:=True

End Sub

ご希望にそっていなかったらごめんなさい

お礼

早速のご回答、ありがとうございました。

この書き込みをしたら、実行時エラー9と出ました。
インデックスが有効範囲にありません。

Range("A65536")・・・の行をさしています。

どうしてでしょうか？

それからコピーして貼り付けるのを「値」にしたいのですが・・

よろしくお願いします。

回答No.1

papayuka

ブックＡ.xls と ブックＢ.xls は共に開いていて、それぞれのシートがアクティブになっているとして、ブックＡの１行目をブックＢのA列最終行+1に貼りつけるなら

Sub Test()
　Workbooks("ブックＡ.xls").ActiveSheet.Rows(1).Copy Destination:= _
　　　Workbooks("ブックＢ.xls").ActiveSheet. _
　　　　　Range("A65536").End(xlUp).Offset(1, 0).EntireRow
End Sub

お礼

早速のご回答、ありがとうございました。

コピーして貼り付けるときに、「値」を貼り付ける場合、どうなりますか？