Ａｃｃｅｓｓでのあいまい検索について

質問

Access2010の使用者で＆初心者です。
クエリの抽出条件に別テーブルのフィールドを文字列検索させ、その文字列が含まれていた場合は、その文字列を別フィールドに抜き出すというクエリを作成したいのですが・・
・検索したいテーブル(T商品情報)
・年月日
・品目情報
・検索する文字列が入ったテーブル(T品目)
・検索文字
検索したいテーブル(T商品情報)の「品目情報」から、検索する文字列が入ったテーブル(T品目)の「検索文字」を検索し、その検索文字列が含まれていた場合は別フィールにその検索文字列を抽出。という作業を行いたく思っております。

例
---------------------------T商品情報
年月日｜品目情報
20010/8/10｜武田様より、口頭にてもも大を53個受け付けました
20010/8/10｜上坂様より、電話にてりんごを3個受け付けました
20010/8/10｜木村様より、電話にてももを3個受け付けました
---------------------------

---------------------------T品目
検索文字
もも大
りんご
もも
---------------------------
↓

---------------------------クエリ
年月日｜品目情報 | 検索文字
20010/8/10｜武田様より、口頭にてもも大を53個受け付けました｜もも大
20010/8/10｜上坂様より、電話にてりんごを3個受け付けました｜りんご
20010/8/10｜木村様より、電話にてももを3個受け付けました｜もも
---------------------------
このようなクエリ結果を望んでおります。文章の中から商品名を抜き出し、その抜き出した商品に価格をひもづけたいのです。このようなことをクエリで行えますでしょうか？

回答No.2

30246kiku

＃１です

> 到着したデータが、残念ながら下記のようなかたちでしか届きません。

加工しない状態での抽出については、他の方の回答を待ってください。

以降に控えているもの・事をやりやすいように加工する、という選択肢はないのでしょうか。
なければ、以下スルーしてください。

テーブル「TS1」として以下を作っておいたとします。

・受注NO（オートナンバ）
・年月日（日付）
・顧客（テキスト）　（武田、上坂、木村、・・・）
・方法（テキスト）　（口頭、電話、・・・）
・品目（テキスト）　（もも大、りんご、もも、・・・）
・数量（数値）　　　（53、3、3、・・・）

以下を標準モジュールに記述し、MkTable を実行すると内容が出来上がります

Private Function CutMoji(sSrc As String _
　　　　　　　　　　, sLeft As String, sRight As String) As String
　　Dim iPosS As Long, iPosE As Long

　　If (Len(sSrc) = 0) Then Exit Function
　　If (Len(sLeft) = 0) Then
　　　　iPosS = 1
　　Else
　　　　iPosS = InStr(sSrc, sLeft)
　　　　If (iPosS = 0) Then
　　　　　　iPosS = 1
　　　　Else
　　　　　　iPosS = iPosS + Len(sLeft)
　　　　End If
　　End If
　　If (Len(sRight) = 0) Then
　　　　iPosE = Len(sSrc) + 1
　　Else
　　　　iPosE = InStr(iPosS, sSrc, sRight)
　　　　If (iPosE = 0) Then iPosE = Len(sSrc) + 1
　　End If
　　CutMoji = Mid(sSrc, iPosS, iPosE - iPosS)
End Function

Public Sub MkTable()
　　Dim rsTo As New ADODB.Recordset
　　Dim rsFrom As New ADODB.Recordset
　　Dim sSrc As String

　　rsFrom.Open "T商品情報", CurrentProject.Connection, adOpenForwardOnly, adLockReadOnly
　　rsTo.Open "TS1", CurrentProject.Connection, adOpenForwardOnly, adLockOptimistic
　　While (Not rsFrom.EOF)
　　　　rsTo.AddNew
　　　　rsTo("年月日") = rsFrom("年月日")
　　　　sSrc = rsFrom("品目情報")
　　　　rsTo("顧客") = CutMoji(sSrc, "", "様より")
　　　　rsTo("方法") = CutMoji(sSrc, "、", "にて")
　　　　rsTo("品目") = CutMoji(sSrc, "にて", "を")
　　　　rsTo("数量") = CutMoji(sSrc, "を", "個")
　　　　rsTo.Update
　　　　rsFrom.MoveNext
　　Wend
　　rsTo.Close
　　rsFrom.Close
End Sub

※ 作る先のテーブル「TS1」をクリアしてから実行する・・・　とか
　元の「品目情報」が Null なら・・・　とか
　「年月日」の 20010/8/10 を 2010/8/10 に変更する・・・　とか
　rsTo.Update　でエラーになった品目情報を表示する様にする・・・　とか
　元テーブル「T商品情報」で期間絞り込み後のものを対象にする・・・　とか

上記は、DB化が目的ではありません。が、
データを受け取ったタイミングで MkTable を実行するだけで、
以降のやりたいもの・事がしやすいような気がします。

※　いろいろと不都合部分は修正してください。