VB 特定の文字列が入っている行を削除したい

質問

職場で、データの照合をしているのですが、毎回かわるキーワードが入っている
文字列が含まれる行を削除したいと考えています。
下のものは、ネットサーフィンで拾ってきたものです。
こちらでは、「文字列が含まれている行以外のものを残す」もので、
私が目的としているものと逆になっています。

アプリケーションボックスを利用して、「特定の文字列が含まれている行を削除」
できるのが理想です。

下のものを利用して（作成された方、ごめんなさい）、なんとかできるようにしたいと考えています。
どなたか助けてただけないでしょうか？

当方は、まったくの素人です。

Sub MacroTest1()
　　Dim keyWord As Variant
　　Dim FirstAdd As String
　　Dim UR As Range
　　Dim c As Range
　　Const col As Long = 1 '列数
　　keyWord = Application.InputBox("除外対象の文字列は？", Type:=2)
　　If VarType(keyWord) = vbBoolean Or Len(keyWord) = 0 Then Exit Sub

　　With ActiveSheet
　　　　With .UsedRange
　　　　　　Set c = .Find( _
　　　　　　What:="*" & keyWord & "*", _
　　　　　　LookIn:=xlValues, _
　　　　　　LookAt:=xlPart, _
　　　　　　SearchOrder:=xlByRows)

　　　　　　If Not c Is Nothing Then
　　　　　　　　FirstAdd = c.Address
　　　　　　　　Set UR = c
　　　　　　　　Do
　　　　　　　　　　Set c = .FindNext(c)
　　　　　　　　　　Set UR = Union(UR, c)
　　　　　　　　　　If c.Address = FirstAdd Then Exit Do
　　　　　　　　Loop Until c Is Nothing
　　　　　　End If
　　　　End With
　　　　If Not UR Is Nothing Then
　　　　　　UR.EntireRow.Hidden = True
　　　　　　.UsedRange.SpecialCells(xlCellTypeVisible).Delete
　　　　　　.UsedRange.EntireRow.Hidden = False
　　　　End If
　　End With
End Sub

回答No.4

toshi_2010 · ベストアンサー

そんなにむやみにマクロ使わなくても、エクセルの基本機能を使えば簡単に出来ます。

フィルタで消したい行（特定の文字列が含まれている行）だけを表示

全体を選択して可視アイコンをクリックして削除

回答No.3

keithin

そんなにむやみに複雑なマクロにしなくても、エクセルの基本機能を使えば簡単に出来ます。

例えばＡ列を対象に：
sub macro1()
　dim res as string
　res = inputbox("WORD?")
　if res = "False" or res = "" then exit sub

　range("A:A").autofilter field:=1,criteria1:="*" & res & "*"
　activesheet.autofilter.range.offset(1).entirerow.delete shift:=xlshiftup
　activesheet.autofiltermode = false

end sub

＃余談
エクセルのマクロはＶＢＡと言って、「ＶＢ」は全然別物です。

回答No.2

INTLINSIDE

下の方の
If Not UR Is Nothing Then ～ End If を

If Not UR Is Nothing Then
UR.EntireRow.Delete
End If

あるいは

UsedRange.SpecialCells(xlCellTypeVisible).Delete

を

UsedRange.SpecialCells(xlCellTypeInVisible).Delete

としたら、どうなりますかね。

（若干の調整は必要になると思います。）

回答No.1

K Kazz（@JazzCorp）

Sub MatchPartDelRow()
Dim R As Range
Dim keyWord As Variant
keyWord = Application.InputBox("除外対象の文字列は？", Type:=2)
If VarType(keyWord) = vbBoolean Or Len(keyWord) = 0 Then Exit Sub
Do
Set R = ActiveSheet.Range("A:A").Find(What:=keyWord, LookAt:=xlPart)
If R Is Nothing Then Exit Sub
R.EntireRow.Delete
Loop
End Sub