関数で複数の条件から選択する方法

質問

エクセルを使用しています。
図にあるように２つの条件が合致した時に、リーグの「１部」～「４部」というテキストを表示させたいのですが、どのようにやったらよいでしょうか？

例）　担当エリア店舗数が「４」で、更に点数が「８０点以上」だった場合、「１部」リーグをセル“T3”に表示させたい。

回答No.4

tom04 · ベストアンサー

こんばんは！

No.3のkagakusukiさんが回答されているように、表を昇順に作成すれば
「～未満」　の表示が可能です。

質問では降順の表を参照していますので、極力質問内容に沿うような感じでやってみました。
↓の画像の表は　「～以下」の表示になりますので、敢えて表内に小数点を表示しています。

T3セルに
=IF(COUNTBLANK(R3:S3),"",INDEX(D3:D6,MATCH(S3,OFFSET(A3:A6,,MATCH(R3,A2:C2,0)-1,,1),-1)))
という数式を入れると何とかご希望の表示になると思います。

参考になれば良いのですが・・・m（＿ ＿）m

お礼

出来ました！
ありがとうございました！！

回答No.3

kagakusuki

まず、以下の様な表を作成して下さい。

　　　　　　　　　A列　　　　　　　　B列　 C列　 D列　 E列
1行目　　担当エリア店舗数　　　 2　　　3　　　4　　リーグ
2行目　　　　　点数　　　　　　　　　0　　　0　　　0　　 4部
3行目　　　　　　　　　　　　　　　　 80　　60　　　30　　3部
4行目　　　　　　　　　　　　　　　　　　　　80　　　60　　2部
5行目　　　　　　　　　　　　　　　　　　　　　　　　 80　 1部

　次に、T3セルに次の数式を入力して下さい。

=IF(AND($R3<>"",COUNTIF($B$1:$D$1,$R3)=1,ISNUMBER($S3)),INDEX($E$2:$E$5,MATCH($S3,OFFSET($A$2:$A$5,,MATCH($R3,$B$1:$D$1,0)))),"")

　そして、R3セルに担当エリア店舗数を、S3セルに点数を、それぞれ入力して下さい。

お礼

ありがとうございました！！

回答No.2

KURUMITO

この程度の表でしたら次の式で十分対応できますね。
例えばR3セルに担当エリア店舗数、S3セルに点数が入力されるとしたらT3セルには次の式を入力します。

=IF(COUNT(R3:S3)<>2,"",IF(R3=4,IF(S3>=80,"１部",IF(S3>=60,"２部",IF(S3>=30,"３部","４部"))),IF(R3=3,IF(S3>=80,"２部",IF(S3>=60,"３部","４部")),IF(R3=2,IF(S3>=80,"３部","４部"),""))))

上記のデータが下行に入力されているのでしたらR3に上記の式を入力して下行にオートフィルドラッグします。

お礼

ありがとうございました！！

回答No.1

DJ-Potato

変則的ですが

R3に点数　S3に担当エリア店舗数　T3に結果、として
T3 =MIN(IF(R3<30,8,IF(R3<60,7,IF(R3<80,6,5)))-S3,4)&"部"

なんてどうでしょう。

お礼

ありがとうございました！！