Excel VBA 日付の認識など

質問

こんにちは。
VBA初心者のものですが質問させていただきます。
※エクセル２００３です

「sheet1のD4:FA4のうち、09年8月以外の日付のセルすべてを選択する」
の構文を下記のように作ってみたのですがうまくいきません・・・
(1)「09年8月」の認識
(2)「～以外のセル全て選択」
の2点がネックで困っています。

ちなみに日付のセルには「2009/8/5」のように入力されており、
表示は「09/8/5」です。

すみませんがご教示お願いいたします。

Sub Macro1()
Dim 日付 As Range
For Each 日付 In Worksheets("sheet1").Range("D4:FA4")
If 日付.Value like"*09/8/*"= false Then
日付.select
End If
Next
End Sub

回答No.3

Wendy02 · ベストアンサー

こんばんは。

日付を文字列比較でもかまいませんが、VBAらしく書くと、以下のようになります。
必ず日付が入っているとは限らないので、IsDate でチェックします。

'-------------------------------------------
Sub DateChecker1()
　　Dim c As Range
　　Dim myRng As Range
　　For Each c In Worksheets("Sheet1").Range("D4:FA4")
　　　　If IsDate(c.Text) Then
　　　　　　If CDate(c.Value) < DateSerial(2009, 8, 1) Or CDate(c.Value) > DateSerial(2009, 8, 31) Then
　　　　　　　　If myRng Is Nothing Then
　　　　　　　　　　Set myRng = c
　　　　　　　　Else
　　　　　　　　　　Set myRng = Union(c, myRng)
　　　　　　　　End If
　　　　　　End If
　　　　End If
　　Next c
　　If Not myRng Is Nothing Then
　　　　myRng.Select
　　Else
　　　　MsgBox "該当セルはありません。", 48
　　End If
End Sub

お礼

お礼が遅くなりまして申し訳ありません。
ご回答ありがとうございました。

DateSerialとUnionは初めて知りました…
もっと勉強して活用させていただきます。

回答No.4

imogasi

エクセルは標準では、セルの値を日付シリアル値で持ってます。正整数の値です。１９００年１月１日からの何日目かの数です。
またＶＢＡではセルの値（．Ｖａｌｕｅ）を判別、加工の対象にすることがほとんどです。
ですから本当は２００９年８月１日ー２００９年８月３１日までは、具体的には４００２６－４００５６までの値か判別することになります。しかしその数値は直ちにはわかりにくいので、ＤａｔｒＳｅｒｉａｌ関係の関数で考えたり、"2009/8/1"で考えたり（期間範囲の判別は大小比較になる）します。
ーー
またエクセルＶＢＡや関数にはＹｅａｒ関数、Ｍｏｎｔｈ関数、Ｄａｙ関数があるので、Ｙｅａｒ関数の結果が２００９、Ｍｏｎｔｈ関数が８のＡＮＤ条件で考える手もあります。
ーー
さらには書式適用結果（シート上の見た目）を関数では
=TEXT(A2,"geee年ｍｍ月")
ＶＢＡでは
Sub test01()
Cells(1, 3) = Format(Cells(1, 1), "ge年mm月")
End Sub
のように書式結果を文字列に直して、それを対象に判別する方法もあります。
こちらなら、平成２１年の判別の例で
Sub Macro1()
Dim d As Range
For Each d In Worksheets("sheet1").Range("A1:A5")
'MsgBox Format(d, "ge年mm月")
If Format(d, "ge年mm月") Like "H21*" = True Then
MsgBox d
End If
Next
End Sub
もできる。
＝＝＝
それと、条件を満たしたときの
日付.select
ですが、これでは１セルすつあくちぶセル選択セルが移動してしまい、条件を満たしたセル全体を掴んだ事にならない。
他の回答者がしておられるように、ＵＮＩＯＮメソッドで集合化しないとなりません。
ＵＮＩＯＮ以外でセル選択を累積していくコードを、いままで探しているのですが出会いません。

お礼

お礼が遅くなりまして申し訳ありません。
ご回答ありがとうございました。

日付の認識一つとってもいろいろやり方があるのですね。
今後活用させていただきます。

回答No.2

n-jun

Sub　try()
　Dim　r　As　Range,　rr　As　Range

　For　Each　r　In　Range("D4:FA4")
　　　　　If　Format(r.Value,　"yy/m")　<>　"09/8"　Then
　　　　　　　　If　rr　Is　Nothing　Then
　　　　　　　　　　　Set　rr　=　r
　　　　　　　　Else
　　　　　　　　　　　Set　rr　=　Union(rr,　r)
　　　　　　　　End　If
　　　　　End　If
　Next
　rr.Select
End　Sub

こんな感じの事ですか？

お礼

お礼が遅くなりまして申し訳ありません。
ご回答ありがとうございました。

SetとUnionは初めて知りました…
もっと勉強して活用させていただきます。

回答No.1

rivoisu

YearとMonthの関数を使います
If year(日付）&　Right("00" & month(日付))="200908"=false then
とします。
Right("00" & month(日付))は月を2ケタで統一するためです。

お礼

お礼が遅くなりまして申し訳ありません。
ご回答ありがとうございました。
日付は単なる数値とは違うのですね。
ぜひ活用させていただきます。