マス計算問題を作るプログラムを教えてください。

質問

１００ます計算を作るマクロとしての次の回答がありました。
１０×５で、一桁の整数だけをつかうなど、アレンジ方法を教えてください。
さしあたって必要なのが、6×１０の60マスで、数字は０から９までです。そのあと、７×１０の７０マスと進んでいきたいです。その後は、１０×５の５０マスの引き算で、１０から１９の２けたから０から９のひとけたを引く表を作りたいと思っています。
よろしくお願いします。

以下が、以前の回答です。

VBAでやるのが簡単です。以下は重複の無い乱数発生のVBAサンプルです。

【手順】
1.　[Alt]+[F11]で Visual Basic Editor（以下VBE）起動
2.　[挿入]-[標準モジュール]クリック
3.　下記VBAコードをコピー&ペースト
4.　VBEを閉じる
5.　[ツール]-[マクロ]-[マクロ]で実行

【VBAコード】（次行から終わりまで）

'10×10の重複しない乱数表
Sub Sample()

　　Dim NumberBuf%(1 To 10, 1 To 10)
　　Dim intNum%, i%, j%, ItemNum%
　　Dim tmpBuf
　　Dim Dic As Object

　　'Dictionaryオブジェクト生成
　　Set Dic = CreateObject("Scripting.Dictionary")
　　'Dictionaryの登録数が100になるまでループ
　　Do Until Dic.Count = 100
　　　　'1～100までの整数で乱数発生
　　　　intNum = Int((100 * Rnd) + 1)
　　　　'Dictionaryに登録されているか？
　　　　If Not Dic.Exists(intNum) Then
　　　　　　'登録されていなければ追加
　　　　　　Dic.Add Key:=intNum, Item:=Empty
　　　　End If
　　Loop
　　tmpBuf = Dic.Keys
　　'乱数を10×10の配列に代入
　　ItemNum = 0
　　For i = 1 To 10
　　　　For j = 1 To 10
　　　　　　　NumberBuf(i, j) = tmpBuf(ItemNum)
　　　　　　　ItemNum = ItemNum + 1
　　　　Next j
　　Next i
　　'転記先を変えるにはRange("A1")のA1の部分を変更
　　'10×10のセル範囲左上角のセルになります
　　Range("A1").Resize(10, 10).Value = NumberBuf

End Sub

以上、引用終わり。

回答No.3

merlionXX · ベストアンサー

> さしあたって必要なのが、6×１０の60マスで、数字は０から９までです。そのあと、７×１０の７０マスと進んでいきたいです。その後は、１０×５の５０マスの引き算で、１０から１９の２けたから０から９のひとけたを引く表を作りたいと思っています。

No1-2　merlionXXです。
すべてに対応できるようにしてみました。

Sub 任意行10列表()
Dim ans As Integer, i As Integer, r As Integer, c As Integer
Dim e As String
Dim myDic As Object
Dim gyo, myAr

ans = MsgBox("加算でいいですか？" _
& vbCr & "「はい」なら、1桁同士の加算" _
& vbCr & "「いいえ」なら、2桁から1桁の減算とします。）", vbYesNo + vbQuestion)

If ans = vbYes Then
e = "+"
Else
e = "-"
End If

gyo = InputBox("何行×10列 にしますか？")
If gyo = "" Then Exit Sub

If gyo * 1 > 10 Then
MsgBox "行数超過です。", vbCritical
Exit Sub
End If

Range("A1").CurrentRegion.ClearContents

Set myDic = CreateObject("Scripting.Dictionary")
Do Until myDic.Count = gyo * 1
i = Int((10 * Rnd) + 1)
If Not myDic.Exists(i) Then
myDic.Add Key:=i, Item:=""
End If
Loop
Range("A2").Resize(myDic.Count, 1).Value = Application.Transpose(myDic.Keys)
myDic.RemoveAll
Do Until myDic.Count = 10
i = Int((IIf(e = "+", 10, 90) * Rnd) + IIf(e = "+", 1, 10))
If Not myDic.Exists(i) Then
myDic.Add Key:=i, Item:=""
End If
Loop
Range("B1").Resize(, myDic.Count).Value = myDic.Keys

ans = MsgBox("解答も表示しますか？", vbYesNo + vbQuestion)
If ans = vbNo Then Exit Sub

myAr = Range("A1").CurrentRegion.Value

For r = 2 To UBound(myAr, 1)
For c = 2 To UBound(myAr, 2)
myAr(r, c) = Evaluate(myAr(1, c) & e & myAr(r, 1))
Next c
Next r
Range("A1").Resize(UBound(myAr, 1), UBound(myAr, 2)).Value = myAr
Range("A1").Value = e

Set myDic = Nothing
End Sub

回答No.2

merlionXX

> 1行目と1列目にだけ数字をいれたいのです。

では一例です。

Sub test_6行10列()
Set myDic = CreateObject("Scripting.Dictionary") 'Dictionaryオブジェクト
Do Until myDic.Count = 6 '登録数が6になるまでループ（行のデータ）
i = Int((10 * Rnd) + 1) '1～10までの整数で乱数発生
If Not myDic.Exists(i) Then '重複しなければ
myDic.Add Key:=i, Item:="" '追加
End If
Loop '繰り返し
Range("A2").Resize(myDic.Count, 1).Value = Application.Transpose(myDic.Keys) '転記
myDic.RemoveAll 'myDicをクリア
Do Until myDic.Count = 10 '登録数が10になるまでループ（列のデータ）
i = Int((10 * Rnd) + 1) '1～10までの整数で乱数発生
If Not myDic.Exists(i) Then '重複しなければ
myDic.Add Key:=i, Item:="" '追加
End If
Loop '繰り返し
Range("B1").Resize(, myDic.Count).Value = myDic.Keys '転記
End Sub

回答No.1

merlionXX

百ます計算とは縦10×横10のますの左と上にそれぞれ0から9の数字をランダムに並べそれぞれ交差するところに指定された加法、減法、乗法、除法などの答えを記入する計算シートですよね？
でもご提示のマクロは100個のセルに重複しない1～100までの整数を入れるもののようです。
ご要望はどちらなのでしょうか？（重複しない整数で満たすのか、それとも1行目と1列目にだけ数字をいれたいのか？）

補足

1行目と1列目にだけ数字をいれたい　のです。

前の回答を応用し、中身を削除して使っています。