Ａ列の数値データの桁数に応じて、Ｂ列に異なる値を記入する方法

質問

初心者です。エクセル2000　で入力します。すみませんが、教えてください。
　Ａ列のデータが４桁ならＢ列に　01　を記入、Ａ列のデータが６桁なら　60　を記入、Ａ列のデータが７桁なら　06　を記入したいのです。

　　　 　Ａ列　　　　　　 Ｂ列
1行　　4001　　→→　01
2行　 270006　→→　60
3行　 6300021 →→　06　
4行　 4101　　 →→　01
5行　 271001　→→　60
6行　 6200032 →→　06

回答No.3

koko88okok · ベストアンサー

直訳的な数式ですが・・・

セルB1に下記を入力して、下にオートフィルしてください。
=IF(LEN(A1)=4,"01",IF(LEN(A1)=6,"60",IF(LEN(A1)=7,"06","")))

なお、4桁、6桁、7桁 以外の桁数では、空白になります。
また、"01" "60" "06" は文字列で表示するために「" "」でくくっています。

「LEN関数の使い方」
http://excel.onushi.com/function/len.htm

お礼

有難うございます。うまく記入できました。LEN関数の使い方も参考になりました。

回答No.5

maron--5

◆ついでに、4桁、6桁、7桁 以外の桁数では、空白にするには
★少し、式が長くなりますが
B1=IF(OR(LEN(A1)={4,6,7}),LOOKUP(LEN(A1),{4,6,7},{"01","60","06"}),"")

お礼

有難うございます。うまく記入できました。

回答No.4

maron--5

◆こんな方法もありますよ
B1=CHOOSE(LEN(A1),,,,"01",,"60","06")
または、
B1=LOOKUP(LEN(A1),{4,6,7},{"01","60","06"})
★下にコピー

お礼

有難うございます。うまく記入できました。

回答No.2

noname#204879

[ユーザー定義]で 00 に書式設定したセル B1 に次式を入力して、此れを下方にズズーッと複写
=(LEN(A1)=4)+(LEN(A1)=6)*60+(LEN(A1)=7)*6

お礼

有難うございます。うまく記入できました。

回答No.1

deecyan

桁数は　LOG10という関数と　切捨て（INTまたはRoundDown）を使います
あと桁数によって　文字を入れていけばいいので　INDEX関数等で　指定します

A列が0より大きい場合は　
=INDEX({"XX","XX","XX","01","XX","60","06","XX"},INT(LOG(A1))+1)

お礼

有難うございます。うまく記入できました。INDEXを使う方法も有るのですね。