￥マークがダブります。

質問

Private Sub CommandButton4_Click()

Dim varRag As Variant
Dim myArray As Integer
varRag = Array(TextBox1, TextBox2)

If TextBox1 <> Empty Then
'初めて入力される場合は、最初の行を選択します。
If Range("A16") = Empty Then
Range("A16").Select
TextBox1 = TextBox1.Value

For myArray = 0 To 1
With Selection
.Offset(, myArray) = varRag(myArray)
End With
Next myArray
Else
'2回目以降の入力であれば最終行の1行次の行を選択します。
Range("A65536").End(xlUp).Offset(1).Select
For myArray = 0 To 1
With Selection
TextBox1 = TextBox1.Value
TextBox2 = "￥" & TextBox2.Value
.Offset(, myArray) = varRag(myArray)
End With
Next myArray
End If
'テキストボックスをすべて初期化します。
TextBox1 = ""
TextBox2 = ""
TextBox1.SetFocus
Else
'テキストボックスに名前を入力しないで登録を押した時に出すエラーメッ
セージです。
MsgBox "科目を入力して下さい。"
End If
End Sub
*********************************************************************
上記のコードですが、ワークシートに転記すると、￥マークが二つ表示されま
す。
'2回目以降の入力であれば最終行の1行次の行を選択します。
Range("A65536").End(xlUp).Offset(1).Select
For myArray = 0 To 1
With Selection
TextBox1 = TextBox1.Value
TextBox2 = "￥" & TextBox2.Value
　　　　　　　　　　　↑　　　　　　　　　↑
上記部分を消すと、テキストのみの内容で、￥マークは表示されません。どこ
が間違っているのでしょうか。

回答No.1

papayuka · ベストアンサー

For myArray = 0 To 1
　　With Selection
　　　　TextBox1 = TextBox1.Value
　　　　TextBox2 = "￥" & TextBox2.Value
　　　　.Offset(, myArray) = varRag(myArray)
　　End With
Next myArray

ここでループしていますから TextBox2 が 2000 の場合、最初のループで TextBox2 は "￥2000" になり、次のループで "￥￥2000" になります。
そもそも、TextBox1 = TextBox1.Value の処理も何を意味しているのか不明です。TextBox1にTextBox1のValue値を代入しても意味が無いような、、、
また、「￥」を付けて文字列化してしまっては、その後の計算に差し支えるような気がします。

少し書き換えましたのでご参考に。

Private Sub CommandButton4_Click()
Dim r As Range

With ActiveSheet

　　If TextBox1 = Empty Then
　　　 'テキストボックス1に名前を入力しないで登録を押した時に出すエラーメッセージです。
　　　 MsgBox "Text1は科目を入力して下さい。", vbCritical, "エラー"
　　　 Exit Sub
　　End If

　　If Not IsNumeric(TextBox2) Then
　　　 'テキストボックス2に数値を入力しないで登録を押した時に出すエラーメッセージです。
　　　 MsgBox "Text2は数値を入力して下さい。", vbCritical, "エラー"
　　　 Exit Sub
　　End If

　　'初めて入力される場合は、最初の行を選択します。
　　If .Range("A16") = Empty Then
　　　 .Range("A16").Value = TextBox1.Value
　　　 .Range("A16").Offset(0, 1).Value = TextBox2.Value
　　　 .Range("A16").Offset(0, 1).NumberFormatLocal = "\#,##0;[赤]\-#,##0"
　　Else
　　　　'2回目以降の入力であれば最終行の1行次の行を選択します。
　　　 Set r = .Range("A65536").End(xlUp).Offset(1)
　　　 r.Value = TextBox1.Value
　　　 r.Offset(0, 1).Value = TextBox2.Value
　　　 r.Offset(0, 1).NumberFormatLocal = "\#,##0;[赤]\-#,##0"
　　End If
　　'テキストボックスをすべて初期化します。
　　TextBox1 = ""
　　TextBox2 = ""
　　TextBox1.SetFocus

End With

End Sub

お礼

とても参考になりました。有難うございました。