Accessのコンボボックスで表示させるデータを1500件の中から条件値で絞り込むにはどうしたらいいのでしょうか？

質問

Access2003を使用しています
次のようなことをしたいのですが、方法がわからず悩んでいます。

「対応履歴」というフォームがあります。
その中にテキストボックス「ユーザNO」と「顧客名」があります。
●このフォームの「顧客名」を入力したら、「ユーザNO」が自動的に入るようにしたいです●
　（顧客から問合せが入った時点で顧客から聞きだせるのは顧客名で、ユーザIDは受付担当者がデータベースで調べたあとじゃないとわからないからです）。
「顧客名」はコンボボックスにして抽出をしたいです。
それの元ソースは、テーブル「顧客情報」から引っ張りたいのですが、1500件ほどあるので、見つけるのが困難なのがネックです。
そこで私が思いついたのは、抽出条件を指定するテキストボックスを別に設けて、そこに入力した文字を含む顧客名だけを顧客名コンボボボックスに表示させる方法です。（[山]と入力すれば、山中、大山、(株)山田屋など「山」を含むすべての顧客名が候補にあがる）
その中から該当する顧客名を選ぶと、ユーザNOテキストボックスにも自動的に入力される・・・といったものです。

このようなことは可能でしょうか？

とすれば、どのような設定をすればいいのでしょうか？

私なりにやってみましたが、「顧客名」コンボボックスの候補の絞込みが出来ません。

私が考えた方法以外でも構わないのです。
F対応履歴の入力画面で「顧客名」から「ユーザNO」（T顧客情報にある顧客名とユーザNO）が連動されて入力できればいいのです。

F対応履歴
ユーザNO・・・テキストボックス
顧客名・・・コンボボックス
対応履歴ID

T対応履歴
ユーザNO・・・テキスト型
顧客名・・・テキスト型
対応履歴ID・・・オートナンバー―――主キー

T顧客情報
ユーザNO・・・テキスト型―――主キー
顧客名・・・テキスト型
フリガナ・・・テキスト型

どなたかお知恵をお貸しください。
よろしくお願いいたします。

回答No.2

venzou · ベストアンサー

まず、電話では漢字が分かり難い。
渡辺、渡邉、渡邊など、同音異字は沢山あります。
正確な氏名を聞きだすには手間が掛かります。

フリガナがあるなら、フリガナで抽出の方が良いと思います。

--------------------------------------------------
同姓同名の顧客が居たらどうするのか？
名前だけでは顧客が特定出来ません。

質問の、T顧客情報には、名前とフリガナしか書いていませんが、
その他にも情報があるなら、それも使って絞り込む必要があります。

コンボボックスでは表示出来る情報に限りがあるので、
別途検索フォームを作る方が良いと思います。

その場合の手順は・・・
・F対応履歴に「検索」ボタンを作る。
・ボタンを押すと検索用のフォームが開く。
・検索用のフォームでは、氏名やフリガナ、その他の情報を使って、
　顧客を絞り込みむ。
・顧客を選択したら、F対応履歴へ情報を送る。

検索フォームの仕様は・・・
・T顧客情報を元にした、帳票フォーム
・フォームヘッダに条件を入力するテキストボックスを作る
・条件が入力されたら、Filterプロパティ等でレコードを絞り込む
・詳細には「選択」ボタンを作っておき、ボタンを押したら、
　F対応履歴の「ユーザNO」と「顧客名」を変更し、閉じる

こういう感じの方が良いと思います。いかがでしょう？

検索フォームの詳細に関しては、ご希望があれば補足させて頂きます。

補足

ご回答ありがとうございます。
ご回答者様のご提案を試してみたいので、検索フォームの設定の詳しい説明をいただいてもよろしいでしょうか？

＞・顧客を選択したら、F対応履歴へ情報を送る。

この部分が特にわかりません。

お手数をおかけして申し訳ありませんがお願いします。

回答No.4

venzou

No2回答者です。

F対応履歴の「検索」ボタンのイベントプロシージャは
下記のような感じで。

----------------------------------------------------------
Private Sub コマンド検索_Click()
　DoCmd.OpenForm "F顧客情報検索", acNormal, , , , acDialog
End Sub

-----------------------------------------------------------
acDialog を指定した方が良いと思います。

===========================================================
次に検索フォーム「F顧客情報検索」の詳細です。
各コントロールの名前を下記の様に仮定します。

検索条件を入れるテキストボックス（フォームヘッダ等へ）
・検索フリガナ
・検索顧客名
（その他の情報があれば追加）

検索をキャンセルするためのボタン（フォームヘッダ等へ）
・コマンドキャンセル

顧客を選択するためのボタン（詳細へ）
・コマンド選択

その他のコントロール名はデータソースのフィールド名と
同じだと仮定します。

フォームのソースのサンプル
-----------------------------------------------------------
Option Compare Database
Option Explicit

'フォームのフィルタを更新するためのサブルーチン
Private Sub フィルター更新()
　Dim strFilter As String

　strFilter = ""

　If "" & Me![検索フリガナ] <> "" Then
　　If strFilter <> "" Then
　　　strFilter = strFilter + " and "
　　End If
　　strFilter = strFilter + "フリガナ like '*" & Me![検索フリガナ] & "*'"
　End If

　If "" & Me![検索顧客名] <> "" Then
　　If strFilter <> "" Then
　　　strFilter = strFilter + " and "
　　End If
　　strFilter = strFilter + "顧客名 like '*" & Me![検索顧客名] & "*'"
　End If

　'その他の条件があれば、同様の処理を追加

　'フィルターの設定
　If strFilter <> "" Then
　　Me.Filter = strFilter
　　Me.FilterOn = True
　Else
　　Me.FilterOn = False
　End If

End Sub

'検索用のテキストボックスが更新されたらフィルタを更新
'そして次の項目へ移動
Private Sub 検索フリガナ_AfterUpdate()
　フィルター更新
　Me![検索顧客名].SetFocus
End Sub

Private Sub 検索顧客名_AfterUpdate()
　フィルター更新
　Me![検索フリガナ].SetFocus
End Sub

Private Sub コマンドキャンセル_Click()
　DoCmd.Close
End Sub

Private Sub コマンド選択_Click()
　'F対応履歴が開いている場合、データを更新
　If SysCmd(acSysCmdGetObjectState, acForm, "F対応履歴") <> 0 Then
　　'↓ここが「F対応履歴へ情報を送る」と表現した部分です。
　　Forms![F対応履歴]![ユーザNO] = Me![ユーザNO]
　　Forms![F対応履歴]![顧客名] = Me![顧客名]
　End If
　DoCmd.Close
End Sub
-----------------------------------------------------------

細かい説明は割愛しますので、
詳細はソースとコメントを読んで下さい。

不明な点があれば、補足欄へお願いします。

回答No.3

noname#140971

クエリ方式:

Option Compare Database
Option Explicit

Private Sub Form_Current()
　　Me.テキスト_顧客名 = DLookup("KName", "Customer", "ID=" & Nz(Me.テキスト_顧客ID, 0))
　　Me.テキスト_顧客ID.SetFocus
　　Me.コンボ_顧客名一覧.Visible = False
End Sub

・・・・

Private Sub テキスト_顧客名_AfterUpdate()
　　Dim strRowSource As String

　　If Len(Me.テキスト_顧客名 & "") > 0 Then
　　　　Me.コンボ_顧客名一覧.Requery
　　　　If Me.コンボ_顧客名一覧.ListCount <> 0 Then
　　　　　　Me.コンボ_顧客名一覧.SetFocus
　　　　　　Me.コンボ_顧客名一覧.Dropdown
　　　　　　Me.コンボ_顧客名一覧 = Me.コンボ_顧客名一覧.ItemData(0)
　　　　Else
　　　　　　MsgBox "該当する顧客名は登録されていません。"
　　　　End If
　　End If
End Sub

値集合ソース=SELECT Customer.ID, Customer.KName FROM Customer WHERE (((Customer.KName) Like Forms!フォーム2!テキスト_顧客名 & "*"));

このように、コンボボックスの値集合ソースをクエリにすれば、自作関数は無用。
もちろん、検索は＜フリガナ＞ですよ。

回答No.1

noname#140971

Cutomer:

ID__KName
01__山田 太郎
02__山下 達郎
03__田中 一郎
04__田上 五郎

例えば、このようなテーブル[Customer]があったとします。
フォームには、[テキスト_顧客ID]と[テキスト_顧客名]を並べます。
まあ、ＩＤとＩＤに基づく参照の関係です。
[テキスト_顧客ID]=0ならば、[テキスト_顧客名]が検索のための入力欄になります。
[テキスト_顧客ID]<>0ならば、[テキスト_顧客名]はロックします。

さて、[テキスト_顧客名]で検索する文字が入力されると[コンボ_顧客名一覧]のリストが更新される。
しかし、この[コンボ_顧客名一覧]は検索フォームみたいなものだから常時表示する必要はないです。
場所も、フォームのフッター部で構わないです。

以上のようなコードを示して欲しいとのことですが、これが実に至難かと思います。

１、フォームカレントの時、既存レコードの顧客名をどのように表示するのか？
２、直接にＩＤを入力するのを許すのか否か？
３、許した場合、どのようにカーソルを移動させるのか？

次は、値リストを使った場合のサンプルコードです。
同じテーブルとフォームを用意すれば、’山’と入力すれば山田 太郎、山下 達郎がコンボボックスに。
山下 達郎を選べばIDも更新されるのが確認されるでしょう。

Option Compare Database
Option Explicit

Private Sub Form_Current()
　　Me.テキスト_顧客名 = DBLookup("KName", "Customer", "ID=" & Nz(Me.テキスト_顧客ID, 0))
　　Me.テキスト_顧客ID.SetFocus
　　Me.コンボ_顧客名一覧.RowSource = ""
　　Me.コンボ_顧客名一覧.Visible = False
End Sub

Private Sub コンボ_顧客名一覧_Click()
　　Me.テキスト_顧客ID = Me.コンボ_顧客名一覧
End Sub

Private Sub テキスト_顧客ID_AfterUpdate()
　　Me.テキスト_顧客名 = DBLookup("KName", "Customer", "ID=" & Nz(Me.テキスト_顧客ID, 0))
　　Me.テキスト_顧客名.SetFocus
End Sub

Private Sub テキスト_顧客ID_LostFocus()
　　Dim isLookupKName As Boolean

　　isLookupKName = CBool(Nz(Me.テキスト_顧客ID, 0) = 0)
　　Me.テキスト_顧客名.Locked = Not isLookupKName
　　Me.テキスト_顧客名.TabStop = Not isLookupKName
　　Me.コンボ_顧客名一覧.Visible = isLookupKName
End Sub

Private Sub テキスト_顧客名_AfterUpdate()
　　Dim strRowSource As String

　　If Len(Me.テキスト_顧客名 & "") > 0 Then
　　　　strRowSource = DBSelect("SELECT ID, KName FROM Customer WHERE KName LIKE '" & Me.テキスト_顧客名 & "%'")
　　　　If strRowSource <> "" Then
　　　　　　Me.コンボ_顧客名一覧.RowSource = strRowSource
　　　　　　Me.コンボ_顧客名一覧.SetFocus
　　　　　　Me.コンボ_顧客名一覧.Dropdown
　　　　　　Me.コンボ_顧客名一覧 = Me.コンボ_顧客名一覧.ItemData(0)
　　　　Else
　　　　　　MsgBox "該当する顧客名は登録されていません。"
　　　　End If
　　End If
End Sub

ところで、かかる自作の DBLookup関数、DBSelect関数を作成する方式が質問者の望みなんでしょうか？
確かに、クエリも用意する必要はないし Jetよりも高速に動作するでしょう。
しかし、このように ADO を使うかどうかですよ。
仮に、ADO を使わなきゃ、DBLookup=>DLookup、DBSelect＝＞クエリに置き換える必要があります。
そこんとこを明確にすれば、クエリ方式の回答も付くかと思います。
私は、一切、クエリを使わないので、その辺は不得手です。
なお、ADO方式でも構わなきゃー、更に、DBLookup関数、DBSelect関数を補足します。