ACCESS ３レコード毎に認識したい

質問

どなたか教えて下さい。
『やりたいこと』
あるテーブルのデータでレポートを作成しました。
３レコード印字したら、改ページせず、フッダーを表示したい。
（フッターには図形の□を表示）
或いは、
３レコード目の横にレコード内容以外のものを表示したい（図形）

『例』
みかん
りんご
バナナ
------------フッダー
□

カキ
ナシ
もも
------------フッダー
□

或いは、

みかん
りんご
バナナ　　　　□
カキ
ナシ
もも　　　　　□　　　　　

いずれにしても、これが３レコード目よ！！と認識させる方法が
わかりません。
レポート内でおこなうのか、
テーブルやクエリー等で、1.2.3.1.2.3.とNoを振るのか。。
案も方法もサッパリです・・・。
どなたか、お知恵を貸してくださいませ！！！

回答No.3

chie65536 · ベストアンサー

１．レポートの「詳細」の一番右端に「マーカー」と言う名前のラベルを貼り、表題に「□」と入れます。

２．レポートのプロパティを見て、イベントの「開く時」を「イベントプローシジャ」にして、以下のコードを埋め込みます。
Private Sub Report_Open(Cancel As Integer)
　　LineCount = 0
End Sub

３．コードページの
Option Compare Database
Option Explicit
の下に
Public LineCount As Integer
の１行を足して
Option Compare Database
Option Explicit
Public LineCount As Integer
にします。

４．レポートの「詳細」のプロパティを見て、イベントの「フォーマット時」を「イベントプローシジャ」にして、以下のコードを埋め込みます。
Private Sub 詳細_Format(Cancel As Integer, FormatCount As Integer)
　　LineCount = LineCount + 1
　　マーカー.Visible = (LineCount Mod 3) = 0
End Sub

コードページが、全体で
Option Compare Database
Option Explicit

Public LineCount As Integer

Private Sub Report_Open(Cancel As Integer)
　　LineCount = 0
End Sub

Private Sub 詳細_Format(Cancel As Integer, FormatCount As Integer)
　　LineCount = LineCount + 1
　　マーカー.Visible = (LineCount Mod 3) = 0
End Sub
となっていればＯＫです。

これで
－－－－－－－－－
みかん
りんご
バナナ　　　　□
カキ
ナシ
もも　　　　　□
白挑
（改ページ）
黄桃
いちご　　　　　□
ぶどう
巨峰
マンゴー　　　　□
－－－－－－－－－
と言うレポートが出来ます。

２ページ目の「いちご」は２行目、「マンゴー」は５行目ですが、それぞれ９、１２レコード目なので、マーカーが付きます。

フッターを使う場合はもう少し複雑で、ちょっと工夫が要ります。

お礼

ありがとうございました！
無事に出来ました！！

回答No.4

CHRONOS_0

3レコード目にイメージを表示させればいいのですね

詳細に非連結テキストボックスを置き
=1
集計実行を全体

詳細に表示させたいイメージを置きます

詳細フォーマット時イベントに

Private Sub 詳細_Format(Cancel As Integer, FormatCount As Integer)

If Me.テキスト12 Mod 3 = 0 Then
Me.イメージ11.Height = 300
Else
Me.イメージ11.Height = 0
End If
Me.詳細.Height = 200
End Sub

イメージの高さは適当に調整してくださいね

お礼

ありがとうございました！

回答No.2

noname#140971

SELECT (DBCount("ID","Tab1","ID<=" & ID)+2)\3 AS GNumber, ID, fld_1
FROM tab1
ORDER BY ID;

ORDER BY 句がないと誤カウントするケースもあります。

お礼

ありがとうございました！

回答No.1

noname#140971

テーブル_tab1:

ID_fld_1
1__Ａ
2__Ｂ
3__Ｃ
4__Ｄ
5__Ｅ
6__Ｆ
7__Ｇ

レポート_クエリ1:

1
___1__Ａ
___2__Ｂ
___3__Ｃ
2
___4__Ｄ
___5__Ｅ
___6__Ｆ
3
___7__Ｇ

このレポートの[並び替え/グループ化]は次のようです。

GNumber___昇順
ID________昇順

クエリ_クエリ1:

GNumber__ID__fld_1
______1___1__Ａ
______1___2__Ｂ
______1___3__Ｃ
______2___4__Ｄ
______2___5__Ｅ
______2___6__Ｆ
______3___7__Ｇ

SELECT (DBCount("ID","Tab1","ID<=" & ID)+2)\3 AS GNumber, ID, fld_1
FROM tab1;

Access では標準モジュールで作成した関数をSQL文に組み込むことも可能。
そこで、DBCount() を使って３レコード毎にグループ番号を付与しています。
このようなグループ化をしておけばレポートの[並び替え/グループ化]機能が利用できます。

Public Function DBCount(ByVal strField As String, _
　　　　　　　　　　　　ByVal strTable As String, _
　　　　　　　　　　　　Optional ByVal strWhere As String = "", _
　　　　　　　　　　　　Optional ByVal ReturnValue = 0) As Variant
On Error GoTo Err_DBCount
　　 Dim N
　　 Dim strQuerySQL As String
　　 Dim rst　　　　 As ADODB.Recordset

　　 Set rst = New ADODB.Recordset
　　 strQuerySQL = "SELECT COUNT(" & strField & ") FROM " & strTable
　　 If Len(strWhere) > 0 Then
　　　　 strQuerySQL = strQuerySQL & " WHERE " & strWhere
　　 End If
　　 With rst
　　　　 .Open strQuerySQL, _
　　　　　　　 CurrentProject.Connection, _
　　　　　　　 adOpenStatic, _
　　　　　　　 adLockReadOnly
　　　　 If Not .BOF Then
　　　　　　 .MoveFirst
　　　　　　 N = .Fields(0)
　　　　 End If
　　 End With
Exit_DBCount:
On Error Resume Next
　　 rst.Close
　　 Set rst = Nothing
　　 DBCount = IIf(N <> 0, N, ReturnValue)
　　 Exit Function
Err_DBCount:
　　 MsgBox "SELECT 文の実行時にエラーが発生しました。(DBCount)" & Chr$(13) & Chr$(13) & _
　　　　　　"・Err.Description=" & Err.Description & Chr$(13) & _
　　　　　　"・SQL Text=" & strQuerySQL, _
　　　　　　vbExclamation, " 関数エラーメッセージ"
　　 Resume Exit_DBCount
End Function

お礼

ありがとうございました！