Exelで簡単に差し込み印刷したい

質問

こんにちは。
業務でエクセルを使用して差込の証明書を印刷したいと思っています。
量が多いのでＶＢＡを使って簡単に自動印刷させたいです。

まず、以下のようなシートがあります。
＜sheet1＞
A　　　　　　｜　B　　　　　　｜　　C　　　　　｜D
印刷番号　｜事業所番号　｜事業所名　　｜代表者名
＜sheet2＞　証明書文書
A4サイズの紙の中に３つ、違う事業所で証明書があります。
（Ｆ２）に１つ目の印刷番号
(N2)に２つ目の印刷番号
（Ｖ２）に３つ目の印刷番号があり、５行目以降に証明書の文書があります。
これに＜sheet１＞の事業所番号、事業所名、代表者名を差し込んでいます。

そして、AA列→AF列までを印刷範囲で設定しています。

　AA ＡＢ AC AD ＡＥ　　　　ＡＦ
　自１ 自２ 自３ 至１ 至２ 至３
　　1 　2 　3 　7 　8 　9　←印刷番号
----------------------------------------------
Sub 証明書印刷()

Range("f2") = Range("自1")
Range("ｎ2") = Range("自２")
Range("ｖ2") = Range("自３")
With ActiveSheet
Do While .Range("f2") <= Range("至1")
.Range ("ｎ2") <= .Range("至２")
.Range ("ｖ2") <= .Range("至３")
Sheets("sheet2").PrintOut

.Range("f2") = .Range("f2") + 3
.Range("ｎ2") = .Range("n2") + 3
.Range("ｖ2") = .Range("v2") + 3
Loop

End With

End Sub
----------------------------------------------

というのを自分なりに調べて作りましたがエラーがでてどこが悪いのかわからなくなっています。
何分初心者なので、どこが悪いのか解説してもらえると助かります。
あと、こうすればもっと簡単にできますよ。というのでも結構です。
よろしくお願いいたします。

回答No.1

end-u · ベストアンサー

>Range("f2") = Range("自1")

この『Range("自1")』の『自1』というのは何ですか？
「名前定義」を使ってセル位置を定義しているのですか？
そしてそれはAA2のセルの事でしょうか？

自1がAA2、自2がAB2、..のセルの事だとして、素直に修正するなら
Sub 証明書印刷()
　　With ActiveSheet
　　　　.Range("f2") = .Range("AA2")
　　　　.Range("n2") = .Range("AB2")
　　　　.Range("v2") = .Range("AC2")
　　　　Do While .Range("f2") <= .Range("AD2") And .Range("n2") <= .Range("AE2") And .Range("v2") <= .Range("AF2")
　　　　　　.PrintOut preview:=True
　　　　　　.Range("f2") = .Range("f2") + 3
　　　　　　.Range("n2") = .Range("n2") + 3
　　　　　　.Range("v2") = .Range("v2") + 3
　　　　Loop
　　End With
End Sub
こんな感じです。

Do While条件で「.Range("f2") <= .Range("AD2")」かつ
「.Range("n2") <= .Range("AE2")」かつ
「.Range("v2") <= .Range("AF2")」
という条件なら、And で結びます。

VBAコードが横に長くなって見にくい場合、折り返して記述できます。上記例なら
Do While .Range("f2").Value <= .Range("AD2").Value And _
　　　　 .Range("n2").Value <= .Range("AE2").Value And _
　　　　 .Range("v2").Value <= .Range("AF2").Value

xxxxxxxx _
yyyyyyyy _
zzzzzzzz
..というように行末に『 _』半角スペースと半角アンダーバーを付けます。

そもそも、セルF2とN2とV2の印刷番号についての関係が、常に連続数値の関係なら、
F2セルの『自』から『至』だけを指定すれば済むような気もしますが。

Sub try()
　　Dim i As Long
　　With ActiveSheet
　　　　For i = .Range("AA2").Value To .Range("AD2").Value Step 3
　　　　.Range("f2").Value = i
　　　　.Range("n2").Value = i + 1
　　　　.Range("v2").Value = i + 2
　　　　　　.PrintOut preview:=True
　　　　Next
　　End With
End Sub

#印刷は preview:=True を削除またはコメントアウト。
#N2セルに =F2+1 V2セルに =N2+1 という数式をセットしておけば変更はF2セルだけ。

お礼

お礼が遅くなってすみません。
『Range("自1")』の『自1』はend-uさんのいうとおり「名前定義」を使ってセル位置を定義しています。
本当に自分がしたかったのは『自』から『至』だけを指定して印刷をしたかったのですが、１枚の紙に３つ違う印刷をするプログラムが見つからなかったので継ぎ足しで「こうすればいいかな」と初心者なりにやっておりました。
『至』ばかりに目がいって『自』をプラスすればいいことに気づきませんでした。
とても助かりました。ありがとうございました。