【VBA】データシートから4件ずつ印刷させたいです

質問

VBAでうまくいかない事があり質問させていただきます。

■やりたい事
------------------------------------
ユーザーフォームに開始の番号と　終了の番号を手入力し、
印刷開始　ボタンを押すと
印刷フォームにデータを４個ずつ並べて印刷
それを終了の番号まで繰り返す。
-------------------------------------
A4-1枚目　 1 2 3 4
A4-2枚目 5 6 7 8
A4-3枚目 9 10 11 12
A4-4枚目 13 14 15 16
-------------------------------------

■状況　添付画像確認ください
------------------------------------
１データシート（16アイテム）
２印刷フォーマット（A41枚に4アイテムづつ表示）
３印刷結果(希望)
------------------------------------

■コード
-------------------------------------
Private Sub CB1_Click()
Dim NO As Integer
Dim a As Integer
Dim n As Integer
'ユーザーフォームの開始番号です
a = TB1.Value
’ユーザーフォームの終了番号です。
n = TB2.Value

For NO = a To n

Sheets("sheet1").Range("c24").Value = NO
Sheets("sheet1").Range("D24").Value = NO + 1
Sheets("sheet1").Range("E24").Value = NO + 2
Sheets("sheet1").Range("F24").Value = NO + 3
Sheets("sheet1").PrintOut
Next NO

Unload Me

End Sub
-------------------------------------

■上記コードの結果
-------------------------------------
A4-1枚目　1 2 3 4
A4-2枚目 2 3 4 5
A4-3枚目 3 4 5 6
A4-4枚目 4 5 6 7
-------------------------------------

■考えられる原因
-------------------------------------
VBAのfor に対して
　Next NO
を指定しているので、４番号ごとの出力が出来ない。

できれば
　NEXT NO +3
のように出来れば思い通りの結果が得られるのではないかと考えていますが、
構文エラーとなります。

回答No.1

chie65536（@chie65535） · ベストアンサー

For NO = a To n
を
For NO = a To n Step 4
にします。

お礼

chie65535 様
お礼が遅くなり申し訳ございませんでした。

教えていただいた方法で出来ました。

ありがとうございました。

回答No.3

HohoPapa

例えばデータ総数が27行で
印刷指示範囲が3行目から12行目までといった
４の整数倍ではない場合。

あるいは、
データ総数が27行で
印刷指示範囲が25行目から40行目までといった
異常な指示の場合。

このようなことまで考慮すると
ちょっと仕込みが必要になりましょう。

添付画像のイメージで、以下のコードでいかがでしょうか。

なお、
印刷指示の開始と終了が逆転している場合、
印刷指示の開始と終了が数値以外の場合、
印刷開始の開始行、終了行が0以下の場合を考慮していません。
また、データの終了行は、2列目が空欄かどうかで判断しています。

Sub aaa()

　Dim a As Integer
　Dim n As Integer

　Dim wkL As Integer
　Dim DRange As Range

　a = 1 'ユーザーフォームで取得
　n = 5 'ユーザーフォームで取得

　With ThisWorkbook.Sheets(1)

　　'データ格納範囲を定義
　　Set DRange = Range(.Cells(3, 8), .Cells(6, 11))　

　　Do

　　　DRange.ClearContents '印刷範囲をクリアー

　　　For wkL = 1 To 4　　 '印刷データをセット
　　　　If a + wkL > n + 1 Then Exit For
　　　　If .Cells(a + 2 + wkL, 2).Value = "" Then Exit For
　　　　DRange.Cells(1, wkL).Value = .Cells(a + 2 + wkL, 2).Value
　　　　DRange.Cells(2, wkL).Value = .Cells(a + 2 + wkL, 3).Value
　　　　DRange.Cells(3, wkL).Value = .Cells(a + 2 + wkL, 4).Value
　　　　DRange.Cells(4, wkL).Value = .Cells(a + 2 + wkL, 5).Value
　　　Next wkL

　　　.PrintOut '印刷

　　　If a + wkL > n + 1 Then Exit Do
　　　If .Cells(a + 2 + wkL, 2).Value = "" Then Exit Do
　　　a = a + 4

　　Loop

　End With

End Sub

お礼

HohoPapa 様

お礼が遅くなり申し訳ございません。

いろいろな方法があるんですね!

VBA判らないながらも、少しずつ勉強しています。
教えていただいた方法もこれから試してみたいと思いまう。

ありがとうございました。

回答No.2

imogasi

印刷シートの先頭には、元データの４行おきに、出現するものが来るのだから、
For NO = a To n　step 4
にして「Step 4」を使って繰り返せばよいでしょう。
ーー
プリントエリアは、印刷後、セル範囲をクリアしておくべきではないか。
３行で印刷最終行がくる場合があるだろう。その際前の第４番目が残らないように。
ーー
この程度のことで、ユーザーフィームを使うのは大げさすぎるように、個人的に思う。InputBoxで聞くので済むのでは。
ーー
ub test01()
x = InputBox("先頭,最終行=")
y = Split(x, ",")
MsgBox "先頭行=" & y(0)
MsgBox "最終行=" & y(1)
End Sub
のy(0)とy(1)で済む。
＝＝＝
データ最終行は
Sub test02()
最終行 = Range("A100000").End(xlUp).Row
MsgBox 最終行
End Sub
で済むかもしれない。

お礼

imogasi 様
お礼が遅くなり申し訳ございません。

教えていただいた　Step 4　でうまくいきました。

また、よりよいプログラムのアドバイスを頂きましてありがとうございました。