エクセル上で英数のみを半角するにはどうしたらいいでしょうか？

質問

エクセル上で、英数のみを全角から半角にするソフトはあるでしょうか？
英数・カナ・記号・スペースまで一括に半角にするものや、英数でも日本文の中の英数１文字は半角にしないものなどは見つけることができたのですが、英数だけをすべて半角にするものは見つけられません。
何かいいものがありましたら教えてください。

回答No.3

mach999 · ベストアンサー

こんなマクロでいけるかと思います。

Public Sub Convert()
　　Dim s As String
　　Dim c As String
　　Dim i As Integer
　　Dim cell As Range

　　If Not (TypeOf Selection Is Range) Then Exit Sub

　　For Each cell In Selection.Cells
　　　　s = cell.Value
　　　　For i = 1 To Len(s)
　　　　　　c = Mid(s, i, 1)
　　　　　　If IsWideAlphabet(c) Or IsWideNumber(c) Then
　　　　　　　　Mid(s, i, 1) = StrConv(c, vbNarrow)
　　　　　　End If
　　　　Next i

　　　　cell.Value = s
　　Next
End Sub

Private Function IsWideAlphabet(c As String) As Boolean
　　IsWideAlphabet = Asc("Ａ") <= Asc(c) And Asc(c) <= Asc("Ｚ") _
　　　　　　　　　　　　Or Asc("ａ") <= Asc(c) And Asc(c) <= Asc("ｚ")
End Function

Private Function IsWideNumber(c As String) As Boolean
　　IsWideNumber = Asc("０") <= Asc(c) And Asc(c) <= Asc("９")
End Function

お礼

ありがとうございました。
私にもできました。
とても感激しております。
本当にありがとうございました。

回答No.4

imogasi

＃２のお礼に関して。
（１）私も少数例ですが、テストして確認済みで上げてます。
（２）Ａ列に全角データがあり、Ｃ列に半角データをセットしてます。Ｃ列は意味ありません。Ｂ列はＡＳＣ関数で使ってたので。
（３）英数は大文字・小文字、全角・半角が見て判別し難いとは思いますが。
（４）ロジックに付いては何度も使っているので
（５）私の凡ミスがあるかも知れませんが、それも含めて
見つけて直して修正していただくことが出来ないと、使っていただくのはむりですかね。

お礼

意味がわかりました。
私のエクセルには複数列入力したあったので、Ａ列がＣ列にコピーされたわけですね。
Ａ列だけ入力してみたら、Ｃ列にちゃんと半角が出ました。
素人なもので、理解できなくて申し訳ありませんでした。
詳しく説明してくださりありがとうございました。

回答No.2

imogasi

ＡＳＣ関数はカナも半角にするようです。
もしそれが都合悪ければ、英数だけなら、半角と全角が1対１対応なので（ぱのパのように１文字が２文字になることが無いので）
標準モジュールに貼りつけて実行して見てください。
Sub test01()
d = Range("A65536").End(xlUp).Row
MsgBox d
a = "１２３４５６７８９０ａｂｃｄｅｆｇｈｊｉｋｌｍｎｏｐｑｒｓｔｕｖｗｘｙｚ" & _
"ＡＢＣＤＥＦＧＨＩＪＫＬＭＮＯＰＱＲＳＴＵＶＷＸＹＺ"
b = "1234567890abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"
For j = 1 To d
t = ""
For i = 1 To Len(Cells(j, "A")) 'Ａ列の文字を変換
s = Mid(Cells(j, "A"), i, 1)
For k = 1 To Len(a)
If s = Mid(a, k, 1) Then
t = t & Mid(b, k, 1)
GoTo p02
Else
End If
Next k
t = t & s
p02:
Next i
Cells(j, "C") = t　'Ｃ列にセット
Next j
End Sub

お礼

回答ありがとうございます。
私のやり方が悪いのか、なぜかＡ列がＣ列にコピーされるだけであとは変りません。
何がいけないのでしょうか？

回答No.1

heycha

ＡＳＣ関数はダメですか？

お礼

早速の回答ありがとうございます。
素人に近い方なので、ＡＳＣ関数がどんなものかよくわらかないのですがこれはカナ・記号・スペースなども半角になりませんか？