VBAでIEを操作したいです。

質問

VBAでIEを操作したいです。

エクセルでデータ管理をしております。
VBA・マクロ等を使用して、ウェブページの入力フォームに自動で入力、ウェブページの結果を再度エクセルに返すことはできますでしょうか？

こちらがサイトになります。
モノレート
http://mnrate.com/

こちらのサイトはアマゾンの商品の年間の価格推移を調べることができます。
ここに商品の「JANコード」(13ケタの商品ごとについているバーコード)を入力して、「グラフを見る」というボタンを押すと表示されます。

例えば、「Smap！Tour！2002！ [DVD] 」という商品が知りたいとします。
その場合「4988002446582」(DVDの商品コード)を入力して「グラフを見る」を押します。

その後、ページが切り替わって切り餅のページが表示されると思います。
表示されたページの商品写真の横にあるASIN:「B00008GEUD」 という数字と、表示されたアドレス「http://mnrate.com/item/aid/B00008GEUD」をエクセルに返したいです。

話を整理させていただきます。
現在エクセルでは、A1セル～A100セルに「JANコード」(13ケタの商品ごとについているバーコード)が入力されております。
そこで「マクロ実行」をします。
そうすると、自動でIEが起動してB1セル～B100セルに「ASINコード」(例:B00008GEUD)、C1セル～C100セルに「ハイパーリンク」(例:http://mnrate.com/item/aid/B00008GEUD)
※エクセルから直接ジャンプできるように青色になったもの　を自動で入力。
すべて完了後、IEが閉じてその後MSGで「完了しました」と表示される。

「入門者のExcel VBA」という本と、「EXCEL VBAでIEを思いのままに操作できるプログラミング術」という本を買って、一通り読み切ったのですが難しくて困っております。
分かる方おられましたら宜しくお願い致します。

最初だけしかわかりませんでした。

'IEの起動
Set ie=CreateObject("InternetExplorer.Application")
ie.Visible=True

'URLへジャンプ
ie.Navigate "http://mnrate.com/"

回答No.1

ushi2015 · ベストアンサー

こんにちは
Sub test()
　　'参照設定　Microsoft HTML Object Library
　　Dim objIE As Object
　　Dim Button As Object
　　Dim i　　 As Long
　　Dim j　　 As Long
　　Dim htmlDoc As HTMLDocument
　　Dim el　　 As IHTMLElement

　　Set objIE = CreateObject("InternetExplorer.Application")
　　objIE.Visible = True

　　For i = 1 To 100
　　　　If Cells(i, 1) <> "" Then
　　　　　　j = 2
　　　　　　objIE.navigate "http://mnrate.com/search?i=All&kwd=" & Cells(i, 1)
　　　　　　While objIE.readyState <> 4 Or objIE.Busy = True
　　　　　　　　DoEvents
　　　　　　Wend

　　　　　　Set htmlDoc = objIE.document

　　　　　　For Each el In htmlDoc.Links
　　　　　　　　If InStr(1, el, "http://mnrate.com/item/aid/") > 0 Then
　　　　　　　　　　If Rows(i).Find(el, Cells(i, 2), xlValues, xlWhole) Is Nothing Then
　　　　　　　　　　　　j = j + 1
　　　　　　　　　　　　Cells(i, j) = el
　　　　　　　　　　End If
　　　　　　　　End If
　　　　　　Next
　　　　　　If j = 3 Then
　　　　　　　　Cells(i, j) = objIE.locationurl
　　　　　　End If
　　　　End If
　　Next
　　objIE.Quit

　　Set objIE = Nothing
End Sub
こんな感じで出来ますか？

お礼

返信ありがとうございました。

さすがカテゴリーマスターですね。
とても勉強になりました。

一つずつ理解していくのは、難しいけど頑張っていきます。
感謝してます。

回答No.3

nan93850673

こういうやり方もある

Option Explicit
Private Declare Sub Sleep Lib "kernel32" (ByVal ms As Long)

Sub test()
'参照設定　Microsoft HTML Object Library
'参照設定　Microsoft InternetExplorer
Dim objIE As InternetExplorer
Dim htmlDoc As HTMLDocument
Dim i As Long

Set objIE = New InternetExplorer
objIE.Visible = True

objIE.navigate "http://mnrate.com/"
While objIE.readyState <> 4 Or objIE.Busy = True
Sleep 1000
Wend

Set htmlDoc = objIE.document
For i = 1 To 100
If Cells(i, 1) <> "" Then
htmlDoc.forms(0).elements("_item_search_inp").Value = Cells(i, 1).Value
htmlDoc.forms(0).elements("_graph_search_btn").Click
Sleep 3000
While objIE.readyState <> 4 Or objIE.Busy = True
Sleep 1000
Wend

If htmlDoc.forms.Length > 1 Then
Cells(i, 2).Value = htmlDoc.forms(1).elements("asin").Value
Cells(i, 3).Value = objIE.locationurl
Else
Cells(i, 4).Value = "Hitしませんでした"
End If
End If
Next
objIE.Quit

Set objIE = Nothing
End Sub

お礼

返信ありがとうございます。

一つ一つのプログラミングがしっかりしていますね！
私は初心者なので、全てを理解することは難しかったのですが、一つずつ調べながら順を追って理解していきたいと思います。

とても感謝しております。ありがとうございました。

回答No.2

imogasi

ＯＫＷＡＶＥ16時着の質問とダブっているのではないか。
前質問なり本質問を適切に処理し、一本化すべきでしょう。
読者に迷惑をかける。このままだと結果的にＯＫＷＡＶＥ規約違反となる？
＝＝＝＝＝
それにＶＢ（Ａ）の質問をする前に、タグ打ちする方法での、ＷＥＢページづくりの初歩を勉強してみたら。ＨＴＭＬ文の仕組みなどをまず勉強してから、本質問を考えるべきと思う。済んでいるのかな？
ＸＭＬに関するhttp://gogodiet.net/z/xml/1.htmなどを一読して、HTMLと比較して考えると
勉強になるかもしれない。
（１）ＷＥＢ上で、テーブル（ＴＤタグなど）式で情報を提示しているもの以外は、望む情報項目をプログラムで見つけるのはコードが複雑になるように思う。常道はない？
目的のＷＥＢ記事をブラウザで出して、表示ーソースで出てくる内容（テキスト）の中から、求める項目をプログラムで見つけることになると思う。
（２）求める項目が１時点につき、多数ある場合にレスポンス時間は質問者の思っている許容範囲内か
（３）ＷＥＢ記事作成者（他社だよね）側で、長期的に見て、変更・更新されることについては大丈夫か。多少の変更で、ある項目を見つけるプログラムが変更せねばならない場合は、そのプログラムに頼るのは危険でしょうから。
ーー
ついでに現在ＩＥのＶＢＡ本は２種市販されている。
Ｇｏｏｇｌｅで「vba ie 本」で照会すると、まず最初に出てくる記事に出ている。
質問者が持っている本以外の１本も、良かったら購入したら。

お礼

返信ありがとうございます。

ご指摘の通りです。
前に同じ内容の投稿をしたのですが、文章の不備があったため書き直しました。OKwaveの利用の初心者のため、投稿の削除方法がわからなかったので、連投してしまいました。
調べた時に、OKwaveでは、回答がついた質問は削除できないという規定があるとでてきて困惑してしまいました。

VBAでIEを操作するためには、ほかの分野の知識も必要みたいですね。
そちらも併せて検討してみようと思います。

アドバイスありがとうございました。