EXCELのセル内改行について

質問

よくある質問としてExcelの見た目と印刷が違うというものがありますが、それを回避するために、セル内の強制改行を使うと思います。

内部統制のRCMで使っている表なのですが、縦書きの列のセルがあります。同じ行にある横書きのセルの内容が少ないため、セル幅を自動調整しようとすると、行の高さが異常に高くなってしまいます。
縦書きのセルはレイアウト上２行（列）に収める必要があるので、縦書きのセルで強制改行すると、思うように治まるのですが、行のセル幅を自動調整すると、勝手に３行（列）になってしまい、印刷できなくなってしまいます。
どの位置で改行してみても、勝手に１文字分が余分な１行（列）になってしまい、マクロで自動調整をした後に印刷をかけようとしているので、見ばえの悪い表になってしまいます。
（うまく表現できていないようでしたらお許し下さい）

縦書きのセルの自動調整をうまく行う方法は無いでしょうか？

回答No.2

kenpon24 · ベストアンサー

自動調節を行う方法ではないので申し訳ありませんが、
見た目どおりに印刷することが目的なら、

印刷したい範囲を選択(もしくは取得)して、
shift押しながら編集→図でコピー
新しいブックなどに貼り付け。
印刷範囲を元ブックと同じに設定

で印刷することで、見た目どおりに印刷できると思います。

マクロを使えるならこの辺の動作を自動でやってくれるものを以前作ったので貼っておきます。
とりあえず選択範囲のみを印刷するものです。

Sub 見た目通り印刷()

Dim my_Page As PageSetup
Dim tmpView As Integer
Dim tmpGrid As Integer
Dim tmpWb As String

tmpView = ActiveWindow.View
tmpGrid = ActiveWindow.DisplayGridlines
tmpWb = ActiveWorkbook.Name

'Application.ScreenUpdating = False
'改ページプレビューの場合は一旦解除、グリッドラインを無効にする
ActiveWindow.View = xlNormalView
ActiveWindow.DisplayGridlines = False

'印刷設定を格納
Set my_Page = ActiveSheet.PageSetup
'選択範囲　図のコピー　<-範囲を変えたければSelectionの代わりを考える
Selection.CopyPicture Appearance:=xlScreen, Format:=xlPicture

'新しいブックの作成
Workbooks.Add
'背景を白にする
Cells.Interior.ColorIndex = 2

'元シートの印刷設定を書き込み
With ActiveSheet.PageSetup
.LeftHeader = my_Page.LeftHeader
.CenterHeader = my_Page.CenterHeader
.RightHeader = my_Page.RightHeader
.LeftFooter = my_Page.LeftFooter
.CenterFooter = my_Page.CenterFooter
.RightFooter = my_Page.RightFooter
.LeftMargin = my_Page.LeftMargin
.RightMargin = my_Page.RightMargin
.TopMargin = my_Page.TopMargin
.BottomMargin = my_Page.BottomMargin
.HeaderMargin = my_Page.HeaderMargin
.FooterMargin = my_Page.FooterMargin
.PrintHeadings = my_Page.PrintHeadings
.PrintGridlines = my_Page.PrintGridlines
.PrintComments = my_Page.PrintComments
.PrintQuality = my_Page.PrintQuality
.CenterHorizontally = my_Page.CenterHorizontally
.CenterVertically = my_Page.CenterVertically
.Orientation = my_Page.Orientation
.Draft = my_Page.Draft
.PaperSize = my_Page.PaperSize
.FirstPageNumber = my_Page.FirstPageNumber
.Order = my_Page.Order
.BlackAndWhite = my_Page.BlackAndWhite
.Zoom = my_Page.Zoom
.PrintErrors = my_Page.PrintErrors
End With

'図の貼り付け
ActiveSheet.Paste
'Application.ScreenUpdating = True

'印刷プレビューのコール
ActiveWindow.SelectedSheets.PrintPreview
'プレビューを閉じたらブックをクローズ
'Application.DisplayAlerts = False
ActiveWorkbook.Close
'Application.DisplayAlerts = True

'画面設定を元に戻す
Workbooks(tmpWb).Activate
ActiveWindow.View = tmpView
ActiveWindow.DisplayGridlines = tmpGrid

End Sub

お礼

アドバイスありがとうございます。
こうした機能があることは知りませんでした。
今回のシートに適用できるかどうか考えてみます。

回答No.3

noname#263714

縦書き、横書きに関係なく強制改行したい文字列の頭へカーソルを移動して、「Ａｌｔ」を押したまま「Ｅｎｔｅｒ」を押してください。
２行になると思います。

回答No.1

nayuta_lot

こんにちは

フォントサイズを小さくするだけでは、だめなのでしょうか？
バランスの問題だと思いますので、１文字分入らないくらいなら
フォントサイズの調整で対応できそうな気がしますが？

とりあえず、ご参考まで・・＾＾；