EXCELで隣のセルにデータがあるセルの平均を表示

質問

EXCELで隣のセルにデータがあるセルの平均を表示をさせる方法を教えてください。

A B
1 1
2 2
3 3
4 4
5 5
6 6
7
8
9

Aにはデータが大量に入っています。
Bには１日１つずつデータが入っていきます。
毎日、AのAVERAGEの範囲を変えて入力しなおしていますが、
Bにデータがある行までのAの平均値を自動的に出す方法はありますか？

回答No.2

zap35 · ベストアンサー

質問の例では
　=SUMPRODUCT((B1:B9<>"")*(A1:A9))/COUNTIF(B1:B9,"<>")
でB列が空白でないA列の値の平均を求めることができます

範囲は変更してください

お礼

配列数式を使わずに入力したかったので、こちらを採用させていただきました。
ありがとうございました。

回答No.4

izmlz

=AVERAGE(A1:INDEX(A:A,COUNT(B:B)))

でいかがでしょう？

参考URL：

http://www2.odn.ne.jp/excel/waza/function.html#SEC62

お礼

教えていただいた、サイトを見させていただきます。
ありがとうございました。

回答No.3

imogasi

=AVERAGE(OFFSET($B$2,0,0,COUNTA($B$2:$B$10000),1))
質問者の状況が良くわからないが、上から詰めてＢ列が入力される場合です。
そうでなければ
=SUMPRODUCT((B2:B1000<>"")*(B2:B1000))/COUNTA($B$2:$B$1000)
配列数式では
=AVERAGE(IF(B2:B1000<>"",B2:B1000,""))
ＳＨＩＦＴ，ＣＴＲＬ，ＥＮＴＥＲキーを同時押しする。

お礼

OFFSETという関数を初めて見ました。勉強になります。
２パターンも教えていただき、ありがとうございます。

回答No.1

mu2011

次の方法は如何でしょうか。
=AVERAGE(IF(B1:B65535<>"",A1:A65535))
配列数式の為、入力完了時にshift＋ctrl＋enterキーを同時押下して下さい。

お礼

分かりやすい関数ですね。
エクセルに詳しくない者の業務で使用する為、配列数式ではないものを
使いたかったので今回は見合わせましたが、非常に分かりやすい関数なので、
私の業務で利用させていただこうと思います。
ありがとうございました。