Excelでの空白セルを除いた引き算

質問

Excel2007を使用しています。

A列にどんどん増えていく数値(増加量はランダム)が入力され、Ｂ列に１つ上の数値を引いた値を計算式で出したいのですが、A列にはたまに空白が入ります。

Ａ列　　　B列
50　　　
100 　 　 50 (←100-50)
160 　　 60

170 　　 10 (←170-160)
200 　　 30

このような感じにしたい時にB列に入力する式が分かりません。
初歩的な質問かもしれませんが、よろしくお願いします。

回答No.5

noname#204879 · ベストアンサー

添付図参照
B2:=IF(A2="","",A2-MAX(A$1:A1))

お礼

お礼が遅くなってしまい申し訳ありませんm(__)m
無事にシートを作ることができました。

たくさんの回答を頂きありがとうございました。
この場でみなさんへのお礼とさせていただきます。

回答No.4

mt2008

もっと単純にB2に↓で良いんじゃないかな
=IF(A2="","",A2-MAX(A$1:A1))

回答No.3

keithin

Ｂ２に
=IF(A2="","",A2-LOOKUP(MAX(A:A)+1,$A$1:A1))
以下コピー

とかでいいです。

回答No.2

aokii

データはA2セルから始まっているとして、B3セルに以下の式を入れて、下にドラッグコピーでいかがでしょう。

=IF(A3="","",IF(A3="",A2,A3)-IF(A2="",A1,A2))

回答No.1

tom04

こんにちは！
一例です。

データはA1セルから入力するとして・・・

B2セルに
=IF(A2="","",A2-INDEX(A$1:A1,MAX(IF(A$1:A1<>"",ROW(A$1:A1)))))
これは配列数式になってしまいますので、Shift＋Ctrl＋Enterで確定！

この画面からコピーする場合は、
上記数式をドラッグ＆コピー　→　B2セルを選択　→　数式バー内に貼り付け　→　そのまま（編集可能なまま）
Shift＋Ctrlキーを押しながらEnterキーで確定！
数式の前後に｛　｝マークが入り配列数式になります。

これをずぃ～～～！っと下へコピーしてみてください。

※　他に簡単な方法があればごめんなさいね。m（_ _）m