エクセルVBAのシート削除について

質問

エクセルのワークシートに

「テストシート１」、「テストシート２」、「テストシート３」

があるとします。

誰かにテストシート１が意図的に削除されてしまった場合
同時に「テストシート２」もマクロで削除したいのですが、
どうすればよいのでしょうか？

回答No.1

end-u · ベストアンサー

単純に、手作業での削除に対応するなら、ThisWorkbook Moduleに

'ThisWorkbook Module
Option Explicit
Const chk = "テストシート１" '監視対象シート名
'-------------------------------------------------
Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
　　If Sh.Name = chk Then
　　　　Application.OnTime Now, Me.CodeName & ".shtchk"
　　End If
End Sub
'-------------------------------------------------
Private Sub shtchk()
　　Dim ws As Worksheet

　　On Error Resume Next
　　Set ws = Sheets(chk)
　　On Error GoTo 0
　　If ws Is Nothing Then
　　　　MsgBox "削除されました。"
　　Else
　　　　Set ws = Nothing
　　End If
End Sub

..こんな感じで可能ですが、
シート名を変更しての削除や、マクロでの削除には対応できません。

それにも対応するなら
非表示のダミーシートを準備して、そのA1セルに
=テストシート１!IV65536
という数式を入れます。
#2007以降なら　=テストシート１!XFD1048576

数式を入れた後、そのダミーシートのSheet Moduleに以下。

'Sheet Module
Option Explicit
Private Sub Worksheet_Calculate()
　　Dim ws As Worksheet
　　Dim x　As String

　　With Range("A1")
　　　　If IsError(.Value) Then
　　　　　　x = .Formula
　　　　　　On Error Resume Next
　　　　　　Set ws = Sheets(Mid$(x, 2, InStr(x, "!") - 2))
　　　　　　On Error GoTo 0
　　　　　　If ws Is Nothing Then
　　　　　　　　.ClearContents
　　　　　　　　MsgBox "削除されました。"
　　　　　　　　Me.Visible = xlSheetVisible
　　　　　　　　Application.DisplayAlerts = False
　　　　　　　　On Error Resume Next
　　　　　　　　Sheets("テストシート２").Delete
　　　　　　　　Me.Visible = xlSheetVeryHidden
　　　　　　　　Application.DisplayAlerts = True
　　　　　　　　On Error GoTo 0
　　　　　　Else
　　　　　　　　Application.EnableEvents = False
　　　　　　　　.Formula = "=" & ws.Name & "!IV65536" '!XFD1048576
　　　　　　　　Application.EnableEvents = True
　　　　　　　　Set ws = Nothing
　　　　　　End If
　　　　End If
　　End With
End Sub

お礼

すばらしいです。
ありがとうございました。