バッチプログラム（コピー）

質問

バッチプログラムで、PSTファイルをサーバーにバックアップしようと思っています。
その際、Outlookが起動中かどうかを調べて、起動中ならば終了させてコピー、起動していないならばそのままコピーするようにしたいと思います。
そこで、バッチプログラムを作りたいのですが上手くいかないので教えてください。
下記のプログラムだと、Outlookが起動していないとエラーとなりますので、そこを何とかしたいと思っています。よろしくお願いします。
taskkill /im outlook.exe
TIMEOUT /T 10
copy "C:\Users\○○○\Documents\Outlook ファイル\○○○@△△△.co.jp.pst" "\\Server\○○○\○○○@△△△.co.jp.pst" /Y

回答No.1

chie65535 · ベストアンサー

＞下記のプログラムだと、Outlookが起動していないとエラーとなりますので、そこを何とかしたいと思っています。

「何とかしたい理由」は何ですか？

エラーが起きても、エラーを無視すれば問題無いと思いますが。

エラー表示されるのが嫌なのであれば

taskkill /im outlook.exe 2> nul

とやれば、エラー表示しなくなります。

「エラーが起きても、無視すれば、エラーが起きてないのと同じ」です。

どうしても「エラーが起きないようにしたい」と言うのであれば、以下のようにして下さい。

@echo off
:loop
tasklist | find "outlook.exe" > nul 2>nul
rem 終了コードが２ならエラー
if errorlevel 2 goto error
rem 終了コードが1なら検索失敗
if errorlevel 1 goto copyok
rem 終了コードが０なら検索成功
taskkill /im outlook.exe > nul 2> nul
TIMEOUT /T 10
rem 最初からやり直す
goto loop
:copyok
rem タスクが消えたのでコピー
copy "C:\Users\○○○\Documents\Outlook ファイル\○○○@△△△.co.jp.pst" "\\Server\○○○\○○○@△△△.co.jp.pst" /Y
goto end
:error
echo エラーです
:end

このバッチでは、タスクをキルしたら、１０秒待ってから、タスクが居残ってないか調べる為に、もう一度最初からやり直しています。

なので、outlook.exeが強制終了できない場合には永久に処理を繰り返しますので、注意して下さい。

お礼

お礼の操作漏れでした。