VBA：HTML から文字列を取得したい

質問

エクセルのVBAを使ってHTMLの操作をしようとしています。
実際のHTMLではなくて恐縮ですが、以下のようなテーブルがあります。

<tr class="hoge">
<td>ABC</td>
<td>fuga</td>
<td>piyo</td>
<td>テキスト：いろは</td>
<td>hogehoge</td>
</tr>

四つ目のtd要素に含まれている文字列「いろは」で、目的のtr要素を特定し（「いろは」はHTML中一回しか使われません）、一つ目のtd要素にある「ABC」を取得して変数に収め、利用したいと考えています。

このクラス名「hoge」を用いたtr要素は複数あって、かつその並び順は新しいデータの更新・追加に従って変わるので、添え番で指定することが出来ません。

このとき、GetElementsByClassName でクラス名「hoge」のエレメントコレクションを取得するところまでは判りますが、その後どういった処理を行えば希望する結果が得られるか思いつきません。

どういう方法を使えばよいか、なんらかヒントをご教示頂ければ助かります。
なにとぞよろしくお願い致しますm(__)m

回答No.1

real beatin（@realbeatin）

こんにちは。

少し抽象的過ぎて、お応えするのが難しい面があります。

> エクセルのVBAを使ってHTMLの操作をしようとしています。
「MSHTML」で「MSHTML.HTMLDocument」の「DOM操作」という前提(*1)でお応えします。

> 実際のHTMLではなくて恐縮ですが、以下のようなテーブルがあります。
例示なさったサンプルは、「テーブル」ではなくて「テーブル」配下の
「レコード」（trタグの付いたHTMLTableRow）を１例だけ挙げたもののようです。
なので、<tr class="hoge">だけを検索したとすると、
目標のテーブル以外のデータを拾ってしまう可能性もありますが、
その点で問題があるかどうか、確認した方が良さそうです。
前提(*2)　　目標のテーブル以外には<tr class="hoge">が存在しない、という場合

> 四つ目のtd要素に含まれている文字列「いろは」で、目的のtr要素を特定し（「いろは」はHTML中一回しか使われません）、
> 一つ目のtd要素にある「ABC」を取得して変数に収め、利用したいと考えています。
前提(*3)　　HTMLTableRow内のインデックスは、"四つ目""一つ目"で絶対的であるという場合。
　　　　　下記サンプルでは、0から始る添え字を使いますので、それぞれ、3、0、で表されています。
> このとき、GetElementsByClassName でクラス名「hoge」のエレメントコレクションを取得するところまでは判りますが、
前提(*4)　　「判ります」＝「出来ています」という意味だとして、
　　　　　ここでは仮に、
　　Set colElm = oDoc.getElementsByClassName("hoge")
　　　　　というような、変数（仮にcolElm）に
　　　　　MSHTML.IHTMLElementCollection　が格納されている場合を前提にします。

> その後どういった処理を行えば希望する結果が得られるか思いつきません。
前提(**)　　<td>タグ配下には、その他のタグが存在しない、として、、、。
前提(***)　　実は<table>タグ配下では無かった？場合はエラーになります。
' ' ///サンプル
'　　Set colElm = oDoc.getElementsByClassName("hoge")
Dim oTblRow As Object　'　As MSHTML.HTMLTableRow
　　For Each oTblRow In colElm
　　　　If 　oTblRow.Cells(3).innerText Like "*いろは*" Then
　　　　　　Debug.Print oTblRow.Cells(0).innerText　　'　　→　"ABC"
　　　　　　Exit For
　　　　End If
　　Next
' ' ///

直接的な答えとしては、以上のような感じ、になるかな、と。
（開発の段階では、MSHTML（Microsoft HTML Object Library）に参照設定しておくと、
　デバッグがやり易くなったり、ある程度の疑問は自己解決できる場合も多くなります。）

その他、テーブルそのものの属性など、条件によっては様々なトライが可能ではありますが、
> どういう方法を使えばよいか、なんらかヒントをご教示頂ければ助かります。
「DOM操作」で「テーブル」を扱うなら、TableRow、Cells、あたりを押さえておけば、
大抵答えには辿りつけるかと思います。

前提(*2)が確実で、HTMLが固定的な場合等では、DOMを離れて、
文字列値としてのHTMLを正規表現VBScript_RegExp_55（Microsoft VBScript Regular Expressions 5.5）
で処理する方が有利な場合も結構あります。（個人的にはこっちがやや多い？）
' ///走り書きですし、簡単な検証しかしていませんが、例示に忠実なダミーサンプルでは機能しました。
Sub try9060613w()
'Dim sHtml As String
'　　sHtml = oDoc.body.innerHTML　　'　　←　一例です。
Dim oRegExp As VBScript_RegExp_55.RegExp
Dim colMatch As VBScript_RegExp_55.MatchCollection
　　Set oRegExp = New VBScript_RegExp_55.RegExp
　　With oRegExp
　　　　.Global = True
　　　　.IgnoreCase = True
　　　　.Pattern = "\s*<td>([^<]*)</td>\n*(\s*<td>[^<]*</td>\n*){2}\s*<td>[^<]*いろは[^<]*</td>"
　　　　On Error GoTo ErrMatch_
　　　　Set colMatch = oRegExp.Execute(sHtml)
　　　　On Error GoTo 0
　　　　Debug.Print colMatch(0).SubMatches(0)　　'　　→　"ABC"
　　End With
　　Set colMatch = Nothing
Exit_:
　　Set oRegExp = Nothing
　　Exit Sub
ErrMatch_:
　　MsgBox Err & vbLf & Err.Description
　　Resume Exit_
End Sub
' ///

以上、お役に立てるか確信はありませんが、参考まで。

〓資料）テストに使ったサンプルの一部
　（インデントを表示する目的でタブの代りに全角スペースを当てています）
　　　<table class="hogepiyo">
　　　　<tr class="hoge">
　　　　　<td>XYZ</td>
　　　　　<td>foo</td>
　　　　　<td>bar</td>
　　　　　<td>テキスト：にほへ</td>
　　　　　<td>baz</td>
　　　　</tr>
　　　　<tr class="hoge">
　　　　　<td>ABC</td>
　　　　　<td>fuga</td>
　　　　　<td>piyo</td>
　　　　　<td>テキスト：いろは</td>
　　　　　<td>hogehoge</td>
　　　　</tr>
　　　</table>