VBEでこんなことができますか。

質問

エクセルのVBA（ＶＢＥ）で、以下のことが可能でしょうか。
シート上のＡ列に並んだｎ個のセル内に文字列があります。
このｎ個の文字列をファイル名として、特定のフォルダ内に、
中身のない（０バイト）のｎ個のファイルを作成したいと思います。

こんなことができるｖｂのコードの作り方がありましたら、教えてください。
よろしくお願いします。

回答No.1

watabe007 · ベストアンサー

0バイトのテキストファイルを作成します。
Sub Test()
　　Dim fn As Long
　　Dim c As Range
　　Dim myPath As String

　　myPath = "C:\Users\******\Desktop\" '特定のフォルダのパスを記述(例：デスクトップ)
　　For Each c In Range("A1:A3") 'Ａ列に並んだｎ個のセルを記述(例：A1～A3セル)
　　　　fn = FreeFile
　　　　Open myPath & c.Value & ".txt" For Output As fn
　　　　Close fn
　　Next
End Sub

お礼

短時間で、的確な回答を頂戴し、恐縮です。教えて頂いた内容を、自分の環境に合わせてやってみたら、無事動作しました。ｖｂをもっと学びたくなります。ありがとうございました。心から感謝します。

回答No.2

kmetu

たとえば以下のような感じで

Sub Sample()

Dim MyMakeFile As Object
Dim MyPath As String
Dim MyFileName As String
Dim i As Integer

Set MyMakeFile = CreateObject("Scripting.FileSystemObject")

MyPath = "D:\temp"

For i = 1 To Range("A" & Rows.Count).End(xlUp).Row
MyFileName = MyMakeFile.BuildPath(MyPath, Range("A" & i).Value)
MyMakeFile.CreateTextFile MyFileName
Next i
Set MyMakeFile = Nothing

End Sub

お礼

すばらしい回答をありがとうございました。
うまくいきました。ｎ個を指定しなくても、
ファイルの終端まで繰り返す点や、
私が身につけていない方法があり、感心しました。
勉強になります。ありがとうございました。