ムービークリップを特定の組み合わせでランダム再生

質問

Adobe Flash Pro CS6 でAction Script 3を使っています。
今現在複数あるループムービーを特定の組み合わせでランダム再生する方法を考えています。
使用するムービークリップの数は全部で5つです。
mcA,mcB,mcC,mcD,mcEと5つあります。クリップの再生時間はmcDのみが20フレームでほかはすべて10フレームです。これらのムービークリップをある程度のランダム性を持たせて特定の順番で再生したいのです。特定の順番は以下のとおりです。

mcA - mcB
mcA - mcB - mcB

mcC - mcD - mcE
mcC - mcD - mcD - mcE
mcC - mcD - mcD - mcD - mcE

この四通りの再生方法でムービークリップをランダムで再生し続けたいのです。
それぞれのクリップはループになっているのでmcBからmcA or mcC、mcEからmcA or mcCに繋がってもシームレスに再生し続けられる感じになっています。
どういった方法を用いるのが最善でしょうか？

今現在一つのレイヤーに
（mcA - mcB）（ mcA - mcB - mcB ）（mcC - mcD - mcE）（mcC - mcD - mcD - mcE）(mcC - mcD - mcD - mcD - mcE)
と言った感じにすべてのムービークリップを再生する順番に配置して、それぞれの区切りでフレームラベルを用意して、配列にフレームラベルをすべて入れて、その配列とMath.randomを組み合わせてフレームラベルをランダムで選び、再生位置を飛ばして再生し続けていますが、これだとレイヤーの管理がしにくいのでいまいちしっくりきません。

回答No.1

BlurFiltan · ベストアンサー

メインのタイムラインは１フレームのみで
mcA ～ mcE は全てその フレーム1 に置いてあるものとします。

その場合
その フレーム1 に書くスクリプト例です↓。

//=======================================
// MC の参照を登録する配列を作成
var mc_arr:Array = [mcA,mcB,mcC,mcD,mcE];

// MC の再生順を登録する配列を作成
var ord_arr:Array = new Array();
// MC の再生順を各要素に登録(２次元配列)
ord_arr[0] = [mcA,mcB];
ord_arr[1] = [mcA,mcB,mcB];
ord_arr[2] = [mcC,mcD,mcE];
ord_arr[3] = [mcC,mcD,mcD,mcE];
ord_arr[4] = [mcC,mcD,mcD,mcD,mcE];

//---↑以上が初期登録↑---

//登録した MC を全て非表示にして再生停止
for (var i:int = 0; i<mc_arr.length; i++) {
mc_arr[i].stop();
mc_arr[i].visible = false;
}

//ランダムな再生順の数を入れる変数の宣言
var rnd:int;

//再生順のカウンタを作成
var cnt:int = 0;

//関数 randomMCPlay の定義
function randomMCPlay():void {
//再生中のMCを非表示＆再生停止
ord_arr[rnd][cnt].visible = false;
ord_arr[rnd][cnt].gotoAndStop(1);
//ランダムな再生順の数を取得
rnd = Math.floor(Math.random() * ord_arr.length);
//再生順のカウンタを初期化
cnt = 0;
//ランダムな再生順の数の対応MCを表示＆再生開始
ord_arr[rnd][cnt].visible = true;
ord_arr[rnd][cnt].gotoAndPlay(1);
//毎フレーム 関数 watchMC を実行
this.addEventListener(Event.ENTER_FRAME,watchMC);
}

//関数 nextMCPlay の定義
function nextMCPlay():void {
//再生中のMCを非表示＆再生停止
ord_arr[rnd][cnt].visible = false;
ord_arr[rnd][cnt].gotoAndStop(1);
//再生順をカウントアップ
cnt++;
//対応MCを表示＆再生開始
ord_arr[rnd][cnt].visible = true;
ord_arr[rnd][cnt].gotoAndPlay(1);
//毎フレーム 関数 watchMC を実行
this.addEventListener(Event.ENTER_FRAME,watchMC);
}

//関数 watchMC の定義
function watchMC(e:Event):void {
//もし再生中のMCが最終フレームに達すれば
if (ord_arr[rnd][cnt].currentFrame == ord_arr[rnd][cnt].totalFrames) {
ord_arr[rnd][cnt].stop();
//毎フレーム 関数 watchMC を実行するのをやめる
this.removeEventListener(Event.ENTER_FRAME,watchMC);
//毎フレーム 関数 selectFunction を実行
this.addEventListener(Event.ENTER_FRAME,selectFunction);
}
}

//関数 selectFunction の定義
function selectFunction(e:Event):void {
//もし再生順が最後であれば
if (cnt == ord_arr[rnd].length - 1) {
//関数 randomMCPlay を実行
randomMCPlay();
} else {
//それ以外は 関数 nextMCPlay を実行
nextMCPlay();
}
//毎フレーム 関数 selectFunction を実行するのをやめる
this.removeEventListener(Event.ENTER_FRAME,selectFunction);
}

//関数 randomMCPlay の初回実行
randomMCPlay();
//=======================================

上記スクリプト中の
「---↑以上が初期登録↑---」より上の部分を変えれば
その他は触らなくても自動的にそれに従った動作になります。

内容を大まかに言えば
「関数 randomMCPlay」または
「関数 nextMCPlay」を実行させることによって
次のMCの再生を開始させています。

「関数 randomMCPlay」の方がランダムで順を選ぶ動作で
「関数 nextMCPlay」の方がその順内で次のMCを選ぶ動作です。

そして
再生中のMCのタイムラインを
「関数 watchMC」で見張らせておいて
再生中のMCが最終フレームになったとき
「関数 selectFunction」を実行させて
「関数 randomMCPlay」または
「関数 nextMCPlay」のどちらかを実行させる
というようなしくみにしています。

本当は
再生中のMCのタイムラインを
「関数 watchMC」で見張らせておいて
再生中のMCが最終フレームになったとき
「関数 selectFunction」を介さずに即
「関数 randomMCPlay」または
「関数 nextMCPlay」のどちらかを実行させる
というような動作にしたいところですが
そのようにすると mcA～mcE の
最終フレーム(MC内の フレーム10 や 20)が表示されないまま
次の MC の再生が開始されてしまいます。

そうならないように
「関数 randomMCPlay」または
「関数 nextMCPlay」のどちらかを実行させる
というタイミングを １フレーム 時間待たせるために
「関数 selectFunction」を用意して
Event.ENTER_FRAME で実行させて，即削除しています。

※ Event.ENTER_FRAME で実行される
　 イベントリスナーの初回実行タイミングは
　 addEventListener が実行された
　 次のフレーム時間に入った最初の瞬間です。

お礼

ありがとうございます。問題なく動きました。丁寧な解説ありがとうございます。自分のフラッシュ制作にはとても使えるスクリプトなのでこれからも大事に使わせて頂きます。それと今スクリプトを読んでどういう内容なのか理解しようとしています。自力で理解できないところがあったら補足で質問させてもらうかもしれません。