コマンドプロンプト ファイル名変更

質問

お世話になります。

コマンドプロンプトで”123HOGE.txt”というファイル名に"123-HOGE.txt"という風に123とHOGEの間に"-"を挿入したいのです。

ただこの123は伝票番号で長さが123-99999まで可変なのです。
HOGEは固定なので、"HOGEの前に-を入れろ"というロジックが作りたいのです。

どなたかご教授いただけませんでしょうか？
よろしくお願い致します。

回答No.4

dscripty · ベストアンサー

<!--[ANo.3]さんの回答より引用
for文と環境変数を駆使するか
-->

駆使してみたよ！

[hoge.cmd]
Rem @Echo Off
For %%i in (*HOGE.txt) Do Call :DO_PROCESS "%%~i"
Exit /b 0

:DO_PROCESS
Set TARGET=%~1
Set NUMBER=%TARGET:HOGE.txt=%
Set CHECK=%NUMBER:~0,1%
Rem 10進数以外は無視
If "%CHECK%"=="0" Exit /b 0
Set /a STATUS="%NUMBER%" 2>nul
Rem 数値以外は無視
If ERRORLEVEL 1 Exit /b 0
Rem 123 より小さいときは無視
If "%NUMBER%" LSS "123" Exit /b 0
Rem 99999 より大きいときは無視
If "99999" LSS "%NUMBER%" Exit /b 0
Rem ファイル名変更
Ren "%TARGET%" "%NUMBER%-HOGE.txt"
Exit /b 0

お礼

discriptyさん、早速のご連絡ありがとうございました。

ご教授いただきました方法で実現することができました！
本当にありがとうございました。

ただ、1点だけ気になるところがありまして、以下のロジックがあると動作しなかったため、試しに削除しましたところ動作するようになりました。
ちゃんとファイル名には123～99999までの数字を入れているのですが・・。

Rem 数値以外は無視
If ERRORLEVEL 1 Exit /b 0

いずれにしましても、やりたかった事はdscriptyさんのロジックで出来ましたのでこの度は本当にありがとうございました。

ご教授いただきました詳細なロジックにつきましては今後勉強させていただきます。
本当にありがとうございました。

回答No.5

pita-gora

簡単なサンプルです。該当ファイル名有無や大文字小文字は考慮していません。
表示される内容が思い通りだったら、後ろから二行目のecho を削除して
echo ren %1 %x%
　　↓
ren %1 %x%
に修正して下さい。実際にリネームされます。

:----------------------------------------------
echo off

for /F "delims=" %%f in ('dir /b *log.txt') do call :sub "%%f"
pause
dir *log.txt
exit /b

:sub
set x=%1
set x=%x:log=-log%
echo ren %1 %x%
goto :EOF

お礼

pita-goraさん、ご連絡ありがとうございました。

少し前にdscriptyさんからご教授いただきました方法で実現できましたが、今回pita-goraさんにご教授いただきました方法でも実現できました！
本当にありがとうございます。

pita-goraさんのロジックを見てあらためて色々な方法があることを勉強させていただきました。
大変勉強になりました。
ありがとうございました。

回答No.3

m-take0220

OSの種類くらい書いた方がいいと思いますが。

基本的に、MS-DOSやWindowsのコマンドプロンプトのRENコマンドは、

・リネームするファイルの指定に使用したワイルドカードと変更後のファイル名の指定に使用するワイルドカードは連動しない

ということになっています。

ren 1234567?.txt ?2345678.txt

を実行した場合、12345678.txtが82345678.txtになるわけではありません。最初の指定で?の部分の文字が8でも、変更後の?に使用されるのは元々のファイル名の1文字目である1なので、ファイル名は変わりません。

ren *HOGE.txt *-HOGE.txt

とすると、123HOGE.txtはリネームの対象となりますが、*-HOGE.txtの*の部分は、元々のファイル名全体が使用されるので、123HOGE.txt-HOGE.txtになります。

よって、文字を挿入するようなことはできないので、for文と環境変数を駆使するか(できるかどうかまでは検証してません)、VBScriptなど別のテクノロジを使用するしかないでしょう。

補足

m-take0220さん、早速のご連絡ありがとうございました。

大変失礼いたしました。
何も当方の環境情報を書かずに質問だけしておりました。
今更ですが私の環境はWindowsXP Pro SP3です。

renについて細かなご説明いただきまして誠にありがとうございます。
こういった場合はrenではダメで、for分などのテクニックが必要なのですね。大変勉強になりました。
ありがとうございました。

回答No.2

lupin-333333

これ、マジで聞いています？

＞コマンドプロンプトで”123HOGE.txt”というファイル名に"123-HOGE.txt"

ren ”123HOGE.txt" "123-HOGE.txt"

です。

補足

lupin-333333さん　早速のご連絡ありがとうございました。

すいません、私コマンドプロンプトと書いてしまいましたがバッチファイルを作成して実行しようと思っておりました。大変申し訳ございません。

ただ"-"を入れるだけならネットで調べて分かったのですが、ファイル名の"123"部分が可変の時にどうやったらいいかが分からなかったのです・・。

ご回答ありがとうございました。
当方、勉強不足で申し訳ありませんでした。

回答No.1

Higurashi777

単に
ren *HOGE.txt *-HOGE.txt
では駄目ですか？

補足

Higurashi777さん　早速のご連絡ありがとうございました。

すいません、私コマンドプロンプトと書いてしまいましたがバッチファイルを作成して実行しようと思っておりました。大変申し訳ございません。

早速教えていただきました"ren *HOGE.txt *-HOGE.txt"という記述でバッチファイルを作成して試してみましたが以下の様になってしまいました。

(実施前)
123HOGE.txt
↓
(実施後)
123HOGE.txt-HOGE.txt

となってしまいました・・。