スクリプトをまとめて書くには

質問

Actionscript 2.0で作成しています。

例えばムービークリップaaa1～aaa10までと、bbb1～bbb10があったとして、
aaa1をクリックするとaaa1とbbb1が動く、というようなスクリプトを書きたい場合、

for( i = 1 ; i <= 10 ; i++ ){
eval("aaa"+i).onRelease = function(){
this.gotoAndPlay(2);
_root.eval("bbb"+i).gotoAndPlay(2);
}
}

としてもbbbの方が動きません。
iの値がeval("bbb"+i)の時点で11になってしまってます。
なので現状forを使わずに書いているのですが、
このような方法を簡単な記述で実現するにはどうすればいいのでしょう？

それと、同じ動作を別のムービークリップにさせたい場合、
まとめて書くことはできますでしょうか？

（例えばこれをまとめて書くとか）
aaa.onRelease = function(){
_root.stop();
}
bbb.onRelease = function(){
_root.stop();
}

回答No.1

BlurFiltan · ベストアンサー

前置きとして...
eval は古い関数で昨今はほとんど使いません。
配列アクセス演算子 [] を使うのが一般的です。

「ドット演算子と配列アクセス演算子」
http://fumiononaka.com/TechNotes/Flash/FN0507001.html

まず
クリックイベントを設定する各「aaa○」 内に固有の i を保存しておいて
その固有の数を参照する方法があります↓。

for (i=1; i<=10; i++) {
//「aaa○」内の変数 num に i を保存
this["aaa"+i].num = i;
//「aaa○」クリック時
this["aaa"+i].onRelease = function() {
//この「aaa○」内をフレーム2から再生
this.gotoAndPlay(2);
//この「aaa○」の親にある「bbb○」をフレーム2から再生
this._parent["bbb"+this.num].gotoAndPlay(2);
};
}

推奨はしませんが
上のスクリプトを eval を使って書き直すと次のようになります。

for (i=1; i<=10; i++) {
//「aaa○」内の変数 num に i を保存
eval("this.aaa"+i).num = i;
//「aaa○」クリック時
eval("this.aaa"+i).onRelease = function() {
//この「aaa○」内をフレーム2から再生
this.gotoAndPlay(2);
//この「aaa○」の親にある「bbb○」をフレーム2から再生
eval("this._parent.bbb"+this.num).gotoAndPlay(2);
};
}

また
「クロージャ」というものを使っても良いと思います↓。

for (i=1; i<=10; i++) {
//「aaa○」クリック時の動作として
//関数 abGotoPlay の戻り値を代入
_root["aaa"+i].onRelease = abGotoPlay(i);
}
//関数 abGotoPlay の定義
function abGotoPlay(num) {
//関数を戻り値として返す
return function () {
//「aaa○」と「bbb○」をフレーム2から再生
_root["aaa"+num].gotoAndPlay(2);
_root["bbb"+num].gotoAndPlay(2);
};
}

これまた推奨はしませんが
上のスクリプトを eval を使って書き直すと次のようになります。

for (i=1; i<=10; i++) {
//「aaa○」クリック時の動作として
//関数 abGotoPlay の戻り値を代入
eval("_root.aaa"+i).onRelease = abGotoPlay(i);
}
//関数 abGotoPlay の定義
function abGotoPlay(num) {
//関数を戻り値として返す
return function () {
//「aaa○」と「bbb○」をフレーム2から再生
eval("aaa"+num).gotoAndPlay(2);
eval("bbb"+num).gotoAndPlay(2);
};
}