このソースで、仕組みについて教えてください。

質問

現在、スクリプトを勉強しているんですが、XMLから画像URLを呼び込むソースで調べ方が分からない箇所がありますので、どなたか解説して頂けないでしょうか？

●下記はどういった式になるのでしょうか？
_root.total = this.childNodes[0].childNodes.length;
※totalの時 = このチルドノード[0]の子ノードを調べる？
（自分の解釈です。この[0]はなんなのでしょうか？）

●例えばトータルの最後尾から逆再生させるにはどんな式が必要でしょうか？
※mainasu = cnt-1;
（間違ってるとはおもいますが、内容をまだ反映できないので確認ができません）

●初期値
// ストップ
stop();
// カウント用変数 cnt の初期値を設定
cnt = -1;

// XMLインスタンスの作成
myXML = new XML();
// 余分な空白などを削除
myXML.ignoreWhite = true;

// XMLデータロード時の動作定義
myXML.onLoad = function() {
// 変数 total にノードのトータル数を取得
_root.total = this.childNodes[0].childNodes.length;
// フレーム2でストップ
_root.gotoAndStop(2);
};

// 外部 XML ファイルのロード
myXML.load("my_data.xml");

●2フレーム
// カウント用変数がノード数-1より小さいとき
if (cnt<total-1) {
// カウントを 1 加算
cnt++;
} else {
// それ以外は 0 に戻す
cnt = 0;
}

// テキストフィールド 「number_txt」に 番号を表示
_root.number_txt.text = myXML.childNodes[0].childNodes[cnt].firstChild.nodeValue;

// MovieClipLoaderクラスのインスタンスを作成
myMCL = new MovieClipLoader();
// ロード監視用のインスタンスを作成
myObj = new Object();

// JPEG ロード完了時
myObj.onLoadInit = function(target_mc) {
// load_mc にリンクを設定
target_mc.onRelease = function() {
getURL(myXML.childNodes[0].childNodes[cnt].attributes.linkURL, "_blank");
};
// 再生開始
_root.play();
};

// myMCL のリスナーとして myObj を登録
myMCL.addListener(myObj);

// JPEG をロード
myMCL.loadClip(myXML.childNodes[0].childNodes[cnt].attributes.jpegURL, load_mc);

回答No.1

DPE · ベストアンサー

XML は階層を構築して記述できる言語で、XML の階層構造によってスクリプトも変わってきます。
スクリプトから察するに、想定している XML は

　<Menu>
　　<Item jpegURL="image1.jpg" linkURL="ｈttp://○○○.jp">１</Item>
　　<Item jpegURL="image2.jpg" linkURL="ｈttp://△△△.jp">２</Item>
　　<Item jpegURL="image3.jpg" linkURL="ｈttp://□□□.jp">３</Item>
　</Menu>

↑タグの名前はさておき、このような構造ではないでしょうか？

ActionScript 2.0 までの XML は、XML オブジェクトの中に様々な変数が作られ、取得した値は前後のノードの情報を参照するための手掛かりなどと一緒に記録されます。
先述の XML の構造ですと、読み込みを担当した myXML には、<Menu> という子ノードが１つあります。
子ノードの情報は childNodes という名前の配列変数で記録されます。
この場合の this は myXML のことですから、this.childNodes[0] は、myXML が持っている最初の子（配列変数は０番から始まるので、０番目の子）との意味で、最も外側にある <Menu> ノードを表します。

myXML が持つノードは <Menu> ノード１つだけで、childNodes も 0 番までしかありません。
肝心の画像やリンク先などの情報は全て、<Menu> ノードの子になっています。
this.childNodes[0] が <Menu> ノードのことですから、その階層の childNodes[ 番号 ] で、<Menu> ノードが持っているそれぞれの子ノードの情報を見ることができます。
こちらも同様に、各ノードの情報が配列変数で記録されています。０番に１、１番に２、２番に３の情報が入っています。
この配列変数の 0 ～ 2 という管理番号を変数 cnt で管理し、画像や URL の情報を取り出すわけです。

＊＊＊＊＊

その、変数 cnt ですが。
上記の例ですと、<Menu> の子ノードは３つですから、その情報を持つ配列変数 this.childNodes[0].childNodes も要素が３つ、番号にして 0 ～ 2 まであります。
従って、cnt が取りうる値も 0 ～ 2 となります。

childNodes は配列変数なので、length というプロパティを見ると配列変数の中に要素がいくつあるのかが分かります。今回の例では３つですから、childNodes.length は 3 です。
ご提示のスクリプトでは、この length の値を変数 total に記録しています。
cnt の最大値は 2 、これはつまり total - 1 （＝ length - 1 ）です。
cnt が total - 1 未満の時は次のノードがあるので cnt を +1 して次のノードの情報を見ることができますが、cnt が 2 の時は次のノードがありません。
そこで、if 文を使って 2 の時は 0 に戻すことで、0 ～ 2 の間に収まるようにしているのです。

配列変数は管理番号が 0 から始まり、length には管理番号の最大値 + 1 が記録されるという特徴があります。
この点を利用して、剰余を使って if 文を使わずに計算する方法もあります。
total（＝length ）の値である 3 の剰余は、cnt の値が何であれ、必ず 0 ～ 2 のいずれかになります。
つまり、cnt を +1 した後で total の剰余を求めたものを cnt の新しい値にしておくと、if 文で判断しなくても 0 ～ 2 のカウントアップ（ 2 の次は 0 に戻る）になります。
スクリプトにしますと、

　_root.cnt = ( ++_root.cnt ) % _root.total;

このようになります。剰余は % 演算子で求められます。

後ろから求める場合も、同様に剰余を利用することができます。
cnt が 0 の時に -1 すると剰余が負の数になってしまいますから、-1 したあとで total の値を加算して正の数に戻し、改めて total の剰余を求めます。これで、2 ～ 0 のカウントダウン（ 0 の次は 2 ）になります。
スクリプトは

　_root.cnt = ( ( --_root.cnt ) + _root.total ) % _root.total;

このようになります。