ユーザーフォーム動作で○○○.ｘｌｓはすでにひらいています警告文の対策

質問

excel2000 windowsXPを使用しています。マクロ超初心者です。
1）ワークシートにユーザーフォームＡ　が現れます。その中のコマンドボタンをクリックすると
　a b c ３個のボタンが配置されたフォームＢ　が現れます。
　フォームＢの　aボタンをクリックすると処理用のシートが現れ、このシートに入力複写が完了したので
戻るボタンをクリックして、前のフォームＢが表示されます。
問題はここでｂボタンを押すと、「○○○.ｘｌｓはすでに開いています。２重にひらくと・・・」と警告文がでます。
そこでこの警告文が出ないように

もし○○○.ｘｌｓが開いていないときは、開き、開いているときは開く命令をやめてその次の行からマクロを実行しなさいというスクリプトを作りたいのですが、どう書いたらよろしいでしょうか？

2）上記フォーム正常に動作していました。フォームの中のボタンを1個だけ削除しました。再度起動したところ
「実行時エラー指定されたオブジェクトをは見つかりません」と出てフォームの修正ができません。
すでに出来たフォームの修正はどうやったらよろしいでしょうか？

回答No.2

hana-hana3 · ベストアンサー

BookOpen というプロシージャでチェックするようにしてみました。

Sub 請求書作成() '・・・・・Ａ
Application.ScreenUpdating = False
Call BookOpen("19年度請求.xls")
Call 請求書データ入力
Worksheets("シート表紙").Activate
Application.ScreenUpdating = True
End Sub

'-------------------------------------

Sub 請求書印刷() '・・・・Ｂ
Application.ScreenUpdating = False
Call BookOpen("19年度請求.xls")
Worksheets("請求書印刷").Activate
Worksheets("請求書印刷").PrintPreview
ActiveWorkbook.Close False
ActiveWindow.WindowState = xlMaximized
Application.ScreenUpdating = True
End Sub

'-------------
Sub 請求一覧表印刷() '・・・・Ｃ

Application.ScreenUpdating = False
Call BookOpen("19年度請求.xls")
Worksheets("keiri").Select
Call 一覧表印刷用データ入力
ActiveWindow.WindowState = xlMaximized
End Sub

'-------------

Sub BookOpen(WB_name As String)
Dim WB As Workbook
Dim FLG As Boolean

FLG = False
For Each WB In Workbooks
If WB.Name = WB_name Then
FLG = True
Exit For
End If
Next

If FLG = False Then
'WB_name で指定されたブックが開いていない場合は開く。
Workbooks.Open Filename:=ThisWorkbook.Path & "\請求\" & WB_name
End If
End Sub

お礼

今ご指導のもと、実行しましたら私のやりたいことが完璧にできました。本当に感謝感激です。ありがとうございました。

回答No.1

hana-hana3

＞もし○○○.ｘｌｓが開いていないときは、開き、開いているときは開く命令をやめて

方法は２つあります。
１．開いているブック名をチェックする方法。（wb_chk1）
２．処理のエラーをチェックして適切な処理をさせる方法。（wb_chk2 / wb_chk3）

Sub wb_chk1()

Dim WB As Workbook
Dim FLG As Boolean

FLG = False
For Each WB In Workbooks
If WB.Name = "ABC.xls" Then
FLG = True
Exit For
End If
Next

If FLG = False Then
Workbooks.Open "ABC.xls"
End If

End Sub

Sub wb_chk2()

On Error Resume Next
Workbooks("ABC.xls").Activate
If Err() = 9 Then
Workbooks.Open "ABC.xls"
End If
On Error GoTo 0

End Sub

Sub wb_chk3()

On Error GoTo JobErr
Workbooks("ABC.xls").Activate
On Error GoTo 0

Exit Sub
JobErr:

If Err() = 9 Then
Workbooks.Open "ABC.xls"
End If
Resume

End Sub

＞フォームの中のボタンを1個だけ削除しました。

ボタンを削除しても、ボタンに割り当てられたプログラムが残っている空でしょう。

Private Sub CommandButton1_Click()
End Sub
削除したボタン名のプロシージャを削除してください。

補足

折角ご指導いただきましたが、あれこれやっても実行できませんでした。
「○○○.ｘｌｓはすでに開いています。２重にひらくと・・・」と警告文はＡからＡ、ＡからＢ、ＡからＣに移動するときに発生します。
（wb_chk2 / wb_chk3）を、この中にどう入れていいか分かりません。
本当に恐縮ですが再度ご指導をお願いします。

Sub 請求書作成()・・・・・Ａ
Application.ScreenUpdating = False
ChDrive ThisWorkbook.Path
ChDir ThisWorkbook.Path
Workbooks.Open Filename:=ThisWorkbook.Path & "\請求\19年度請求xls"
Call 請求書データ入力
Worksheets("シート表紙").Activate
Application.ScreenUpdating = True
End Sub
-------------------------------------
Sub 請求書印刷()・・・・Ｂ
Application.ScreenUpdating = False
ChDrive ThisWorkbook.Path
ChDir ThisWorkbook.Path
Workbooks.Open Filename:=ThisWorkbook.Path & "\請求\19年度請求.xls"
Worksheets("請求書印刷").Activate
Worksheets("請求書印刷").PrintPreview
ActiveWorkbook.Close False
ActiveWindow.WindowState = xlMaximized
Application.ScreenUpdating = True
End Sub
-------------
Sub 請求一覧表印刷()・・・・Ｃ
Application.ScreenUpdating = False
ChDrive ThisWorkbook.Path
ChDir ThisWorkbook.Path
Workbooks.Open Filename:=ThisWorkbook.Path & "\請求\19年度請求.xls"
Worksheets("keiri").Select
Call 一覧表印刷用データ入力
ActiveWindow.WindowState = xlMaximized
End Sub