VBA教えて下さい

質問

for nextの使い方がわかりません

変数を使用し条件に当てはまる数値だけ
処理するといった内容です

考えたコード
sub test()

dim a as variant
dim b as variant
dim i as variant

with workbooks("book1").activesheet
set a =.range("A5")
set b =.range("B5")
end with

with workbooks("book2").activesheet

for i = 80 to 110
if a = cells(i,1) then
b.value = cells(i,2)
end if
next i
end sub

このコードにてやりたい事は
まず、book1の今開いてるシートを参照し
A5セル、B5セルをセットし

(例えばA5は2と入力している
B5セルは10000と入力している)

次に、book2の今開いてるシートを参照し
もし、1行目の80～110どれかのセルの数字が
変数aと同じ値ならば
(A行80～110行のセルの数字2があれば
例えば85列)

変数bの数字を2行目の80～110に条件に当てはまるセルに移す
(B行85列にB5セルの値10000を移す)

()の部分は例えで書いてます
読みにくかったら無視でお願いしますm(__)m

指定の仕方など間違ってると思うので
コードを書いてくれると助かります
回答お願いしますm(__)m

回答No.2

kagakusuki · ベストアンサー

まず、

>変数aと同じ値ならば(A行80～110行のセルの数字2があれば例えば85列)
>変数bの数字を2行目の80～110に条件に当てはまるセルに移す(B行85列にB5セルの値10000を移す)

という処理において必要になるのは、「book1の今開いてるシートのA5セルとB5セルに"入力されている値"」であって、「book1の今開いてるシートのA5セルとB5セルに対して(値を変更する等の)処理を行う」という訳ではないのですから、変数aやbには「値」だけを格納すれば済む話であり、

set a =.range("A5")
set b =.range("B5")

などの様に「A5セル」や「B5セル」というセルそのものを格納する必要はありません。
　ですから、

set a =.range("A5")
set b =.range("B5")

の部分はSetは付けずに

a =.Range("A5").Value
b =.Range("B5").Value

とした方が良いと思います。
　また、

if a = cells(i,1) then
b.value = cells(i,2)
end if

という箇所では、「『book2の今開いてるシートの中で、A列のセルが変数aと同じ値となっている行のB列のセル』に、『変数bに格納されているセル』の値を入力する」という処理にはなっておらず、「『変数bに格納されているセル』に、『(book2ではなく)このVBAのマクロが書き込まれているBookの今開いてるシートの中で、A列のセルが変数aと同じ値となっている行のB列のセル』の値を入力する」という処理になってしまっています。
　ですから、前述の「変数aやbには「値」だけを格納」という点も併せて考えれば、上記の

if a = cells(i,1) then
b.value = cells(i,2)
end if

という箇所を次の様に変更した方が良いと思います。

If .Cells(i,1).Value = a Then .Cells(i,2).Value = b

　また、変数iには整数値が入るだけであり、小数点以下の桁数を含む数値データや文字列データ、セル範囲等のオブジェクトが格納される訳ではありませんから、変数iの型をVariant型にするのはパソコンの一時的なメモリーの容量の無駄になりますので、Variant型ではなくLong型にした方が良いと思います。(変数iの値が-32,768～32,767の範囲内に収まる事が確実である場合にはLong型の代わりにInteger型を使う事や、0～255の範囲内に収まる事が確実である場合にはLong型の代わりにByte型を使う事で、容量を更に節約する事も出来ます)

【参考URL】
　VBA基本(変数のデータ型)|Excelでお仕事!
　　http://www.asahi-net.or.jp/~ef2o-inue/vba_k/sub04_050_06.html

　従って、VBAの構文の全文は以下の様になります。

Sub test()

Dim a As Variant
Dim b As Variant
Dim i As Long

With Workbooks("book1").ActiveSheet
a = .Range("A5").Value
b = .Range("B5").Value
End With

With Workbooks("book2").ActiveSheet
For i = 80 To 110
If .Cells(i, 1).Value = a Then .Cells(i, 2).Value = b
Next i
End With

End Sub

お礼

詳しく解説して頂きありがとうございますm(__)m

思った結果がでて
更に応用していきたいと思います

回答No.1

nan93850673

Sub test()
Dim a As Range
Dim b As Range
Dim i As Integer
With Workbooks("book1").ActiveSheet
Set a = .Range("A5")
Set b = .Range("B5")
End With
With Workbooks("book2").ActiveSheet
For i = 80 To 110
If a.Value = .Cells(i, 1).Value Then
.Cells(i, 2) = b.Value
End If
Next i
End With
End Sub