VBAでdosのcompコマンドの実行結果を得たい

質問

Excel2010のVBAで、
MS-DOSのcompコマンドの実行結果を取得したいのですが、
以下の方法ではうまくいきませんでした。
どのようにすればよいでしょうか。(Windows7)

------------------------------------------------------------
Sub test()

　Dim wshShell As Object
　Dim wshExec As Object
　Dim command As String
　Dim file1 As String
　Dim file2 As String
　Dim result As String

　file1 = "C:\test\0128\test.xlsx"
　file2 = "C:\test\0129\test.xlsx"

　'command = "dir /d " & file1 & " " & file2　　　　　'(OK)
　'command = "fc /b " & file1 & " " & file2　　　　　 '(OK)
　command = "comp " & file1 & " " & file2　　　　　 '(NG)
　'command = "echo n | comp " & file1 & " " & file2　 '(NG)
　Debug.Print command

　Set wshShell = CreateObject("WScript.Shell")
　Set wshExec = wshShell.exec("%ComSpec% /c " & command)

　Do Until wshExec.Status
　　DoEvents
　Loop

　If wshExec.StdErr.AtEndOfStream = False Then
　　'エラー
　　result = wshExec.StdErr.ReadAll
　Else
　　'正常
　　result = wshExec.StdOut.ReadAll
　End If

　Set wshExec = Nothing
　Set wshShell = Nothing

　MsgBox result

End Sub
------------------------------------------------------------

回答No.2

chie65535 · ベストアンサー

compコマンドは

ほかのファイルを比較しますか (Y/N)?

と言うプロンプトを「標準エラー出力」に出力します。

ですので

　If wshExec.StdErr.AtEndOfStream = False Then

が「真」になり

　　'エラー
　　result = wshExec.StdErr.ReadAll

だけが実行されます。

そして、resultには

ほかのファイルを比較しますか (Y/N)?

と言う文字列が返って来ます。

なので

MsgBox result

とやっても

ほかのファイルを比較しますか (Y/N)?

しか表示されず、欲しい結果は得られません。

なので「標準エラー出力になにか出力されても、無視する」ようにして下さい。

つまり

　'判定しない
　’If wshExec.StdErr.AtEndOfStream = False Then
　　'エラー
　　'result = wshExec.StdErr.ReadAll
　'Else
　　'正常
　　result = wshExec.StdOut.ReadAll
　'End If

のように、if文をコメントアウトして下さい。

なお「compコマンドは、プロンプトを出して、ｙかｎが入力されるまで、待ってしまう」ので

　command = "echo n | comp " & file1 & " " & file2

にしないといけません。じゃないと「手でｎを入力しないとcompコマンドが終了しない」です。

お礼

エラーが発生した時だけ
wshExec.StdErr.AtEndOfStream = False
が「真」になると思い込んでいました。

教えていただきました方法で、
compコマンドの実行結果を正しく
取得することができました。

ありがとうございました。

回答No.3

Prome_Lin

私が調べたサイトでは、以下のようになっていました。

Sub Test()
Dim w, x As Object
Dim c, r As String
Set w = CreateObject("WScript.Shell")
c = "comp D:\Programming\Book1.csv D:\Programming\Book2.csv"
Set x = w.Exec("%ComSpec% /c " & c)
Do While x.Status = 0
DoEvents
Loop
r = x.StdOut.ReadAll
MsgBox r
End Sub

ただ、そのサイトの説明では「%ComSpec% /c」の「/c」で実行後、コマンドプロンプトの画面が閉じる、ということでしたが、私が試したところ、閉じませんでしたが、エクセルの画面上に結果は表示されていましたので、文字列変数「r」には、間違いなく、コマンドプロンプト上で「comp」が実行され、その結果までの内容が格納されています。

お礼

上記のコードを試してみました。

コマンドプロンプトの画面は開いた状態のままで
Do～Loopの所で x.Status = 0 の条件が満たされずに
ループし続けていますので、
その後の MsgBox r は実行されず
結果は表示されませんでした。

なお、f272さん、chie65535さんから
頂きました方法で解決できました。

ありがとうございました。

回答No.1

f272

If wshExec.StdErr.AtEndOfStream = False Then
で分けなくてもいいんじゃないの？
単に，コマンドを
command = "echo n | comp " & file1 & " " & file2
これにして
result = wshExec.StdOut.ReadAll
これだけ

お礼

result = wshExec.StdOut.ReadAll
だけにしてみたらうまくいきました。

最初、このようにしなければならない理由が
よく分からなかったのですが
その後のchie65535さん頂いた回答で
この理由が理解できました。

ありがとうございました。