エクセルVBAでPDF/実行時エラー

質問

以下はネットで検索して見つけたPDFのプリント用VBAですがやってみるとSet acroApp = CreateObject("AcroExch.APP")のところで実行時エラー「インターフェイスがサポートされていません」になります。
Adibe Acrobat 10.0 Type Liblaryも参照設定しました。
Windows11でエクセルは2019です。Acrobat Readerも入っています。
どうすればいいのでしょう？
https://ziomatrix18.blog.fc2.com/blog-entry-406.html

Sub test01()
Dim ret As Integer
Dim filePath As String

filePath = "C:\Temp\Test.pdf"

Dim acroApp As CAcroApp
Dim pdDoc As CAcroPDDoc
Dim avDoc As CAcroAVDoc

Set acroApp = CreateObject("AcroExch.APP")
Set pdDoc = CreateObject("AcroExch.PDDoc")
Set avDoc = CreateObject("AcroExch.AVDoc")

ret = acroApp.Show
ret = avDoc.Open(filePath, "")
Set pdDoc = avDoc.GetPDDoc()

Dim numPage As Long
numPage = pdDoc.GetNumPages

ret = avDoc.PrintPages(0, numPage - 1, 2, 0, 0)

ret = avDoc.Close(False)
acroApp.Exit

Set avDoc = Nothing
Set pdDoc = Nothing
Set acroApp = Nothing

End Sub

回答No.7

kkkkkm · ベストアンサー

No.6の追加です。
すぐだと印刷までにAcrobat Reader終了させてしまうので、時間をおいた方がいいですね、

Set wshObj = Nothing
の後に(10秒待ちだと)
Application.Wait Now() + TimeValue("00:00:10")
Call TerminateAcrobat

お礼

ありがとうございます。
10秒では足りませんでしたが終了させることができました。
お世話になりました。

回答No.6

kkkkkm

> このプリントで起動されたAcrobatReaderをプリント後自動的に終了させるにはどうしたらよろしいでしょうか？

これは気になっていたのですが、強制的に終了させるしかないみたいです。

Acrobat OLEのエラーを防ぐVBAロジック
https://pdf-file.nnn2.com/?p=1142
Acrobat ReaderではなくAcrobatのOLEでの操作(質問のコードと同じ)のページですが、強制終了はAcrobat Readerでも動きます。

上記の説明コードにある

'***************************************************
' メモリ上に残っているAcrobatプロセスを強制終了する。
'***************************************************
Private Sub TerminateAcrobat()
Dim items As Object
Dim item As Object
Set items = CreateObject("WbemScripting.SWbemLocator") _
.ConnectServer.ExecQuery( _
"Select * From Win32_Process " & _
"Where Name = 'Acrobat.exe'")
If items.Count > 0 Then
For Each item In items
item.Terminate
Next
End If
End Sub

現在のコードの最後に

'【2】Acrobatプロセスの強制終了：最後※非推奨
Call TerminateAcrobat

として実行してください。

また

AFormAut特有のVBA実行エラー
https://pdf-file.nnn2.com/?p=1141

上記の
処理の最後で強制終了しない理由
あたりにも目を通して強制終了するかどうかは決めてください。

お礼

ありがとうございました。
助かります。

回答No.5

kkkkkm

> printPdf = "Acrobat.exe/t " & filePath & " " & printerName

おしいです
Acrobat.exe/t
「/」の前にスペースが必要です。

printPdf = "Acrobat.exe/t " & filePath & " " & printerName
↓
printPdf = "Acrobat.exe /t " & filePath & " " & printerName

お礼

ありがとうございます！
無事プリントできました。
最後にもう一つだけ教えていただけませんか？
このプリントで起動されたAcrobatReaderをプリント後自動的に終了させるにはどうしたらよろしいでしょうか？

回答No.4

kkkkkm

> printPdf = "test01.pdf/t " & filePath & " " & printerName

ファイル名はそちらではなくAcrobat ReaderのEXEファイル名です。

Acrobat Readerのショートカット右クリックで
プロパティのリンク先で見るか
ファイルの場所を開くで確認してください。

64bit版なら以下のようになるかもしれません。
printPdf = "Acrobat.exe /t " & filePath & " " & printerName

お礼

あ、すみません。
ショートカット右クリックで確認しました。Acrobat.exeでした。
しかし、
printPdf = "Acrobat.exe/t " & filePath & " " & printerName
でやりましたが同じところで同じエラーとなりました。

回答No.3

kkkkkm

No.1の追加です。

リンクだけ記載してテストしてなかったので追加です。

通常使うプリンタで印刷する場合printerNameは指定しなくてもいけました。
また、AcroRd32.exeですが実際のAcrobat Readerのファイル名を指定してください。

なお、ページ指定したい場合は(どちらもテストしていません)

ユーザーフォームのAcroPDFコントロールを使う
エクセルのVBAからページ数を指定してPDFを印刷したい
https://www.excel.studio-kazu.jp/kw/20120427163339.html

もしくは

PDF-XChange Viewerを使う
PDF-XChange Viewer コマンドライン印刷について
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q13201105318

お礼

ありがとうございます。ご教示のサイトのコードとアドバイスを参考に以下のようにやってみました。
オートメーションエラー「指定されたファイルが見つかりません」となってしまいました。

Sub Print_PDF()
Dim WSH As Object
Set WSH = CreateObject("Wscript.Shell")
Dim wshObj As IWshRuntimeLibrary.WshShell
Set wshObj = New IWshRuntimeLibrary.WshShell

Dim printPdf As String
Dim fileName As String
Dim filePath As String
Dim printerName As String

Path = "C:\Users\xxxx\Documents\" 'WSH.SpecialFolders("Desktop") & "\" & "請求書" & "\"
printerName = "EW-052A Series(ネットワーク) " '"Microsoft Print to PDF"
fileName = "test01.pdf" 'Dir(Path & "*.pdf")

' Do While fileName <> ""
filePath = Path & fileName
' printPdf = "AcroRd32.exe /t " & filePath & " " & printerName
printPdf = "test01.pdf/t " & filePath & " " & printerName
wshObj.Run (printPdf) 'ここでエラー！
' fileName = Dir()
' Loop
Set wshObj = Nothing
End Sub

回答No.2

MT765

有料版のAcrobatでないと使えないメソッドのようですね。

無料のAcrobat Readerの場合は下記サイトを参考にされたら良いかもしれません。

【VBAでPDFを印刷する方法・管理しやすいツールにする方法を解説！】
https://www.sejuku.net/blog/99169

お礼

ありがとうございます。
ご教示のサイトのコードを参考に以下のようにしてみましたが実行時エラーとなりました。

Sub PDF印刷_Shell()
Dim wshShellObj As IWshRuntimeLibrary.WshShell 'Shellオブジェクト
Set wshShellObj = New IWshRuntimeLibrary.WshShell
Dim strShellCommand As String 'Shellコマンド
Const folderPath = "C:\Users\xxxx\Documents\" '"C:UsersSiroDesktopPDF印刷_Shell" 'フォルダパス
Const printFileName = "test01.pdf" '分割元のPDFファイル名
Const printFilePath = folderPath & printFileName '分割元のファイルパス
Dim printerName As String 'プリンタ名
printerName = "EW-052A Series(ネットワーク) "
'Shellコマンドを設定
strShellCommand = "AcroRd32.exe /t " & printFilePath & " " & printerName
'Shellコマンドを実行
wshShellObj.Run (strShellCommand) '*ここでオートメーションエラー「指定したファイルが見つかりません」
'オブジェクトを強制開放
Set wshShellObj = Nothing
End Sub

回答No.1

kkkkkm

AcrobatだといけるけどReaderだと駄目っぽい感じの情報が多いですね。
こちらもReaderで同じエラーでした。

WScript.Shellを利用する方法とか紹介されてました。

マクロ（VBA）を使ってPDFをまとめて複数印刷する方法
https://zangyou-macro.com/vba-pdf1/

お礼

ありがとうございます。AcrobatReaderではだめということですね。