Rows("3836:3836").Selec

質問

お世話になります。

エクセルVBAで
Rows("3836:3836").Select
の数字の部分を変更するにはどうしたら良いでしょうか？
Rows("Mdata:Mdata").Select
Rows("& Mdata & ":" & Mdata &").Select
では、エラーとなってしまいます。

変数の処理って私には難しいです。
よろしくお願いします。

回答No.2

chie65535 · ベストアンサー

Rows(Mdata & ":" & Mdata).Select
で良いです。

「Formula =」に与える文字列とは違うので「素直にそのまま」で良いです。

前回の質問の「Formula =に文字列として指定する」のとは違いますから、頭を切り替えましょう。

お礼

ありがとうございます
なかなか切り替えが難しいのですね。

明日、会社で試してみます。

いつもありがとうございます

回答No.4

imogasi

Sub test01()
'Rows("Mdata:Mdata").Select
mdata = 4
Rows(mdata & ":" & mdata).Select
End Sub
を
やってみること。第４行目を選択するよ。
Rows()の括弧内は数値で指定する。
Rows("Mdata:Mdata").Select　は（）内が文字列になっているので不可。
---
Sub test02()
mdata: mdata = 4
Rows(mdata & ":" & mdata).Select
End Sub
とでもしない限り通らないだろう。mdata: mdata = 4は不自然。
参考に
Sub test03()
mdata: mdata = "4:5"
Rows(mdata & ":" & mdata).Select
End Sub
---
Sub test04()
x = "4:5"
Rows(x).Select
End Sub
test03はダメで test04はOK.
＞変数の処理って私には難しいです
マクロの記録から始めたような場合は、そういう過程はあるだろう。
プログラムとは「変数の学である」。学習をやめるか、繰り返してなれるか。
こういう文字列と数字の引数の指定表現の違いも、エクセルで気を利かしてくれる場合もあったりするので、慣れて覚えていくしかない。
この働きの機序を、よく知った人は理屈を通して説明するかもしれないが。
＞Rows("3836:3836").Select
の数字の部分を変更するにはどうしたら良いでしょうか？
この３８３６は何の数字なん崗。説明する必要がある。
たとえばある合計が入っている行とか。それなら人間が３８３６と書くのではなくて、
別途VBAのスキルを使ってその行（番号）を割り出さなくてはならない。プログラムの中で
できるだけこういう具体的な数値は避けたくなってくる。セル範囲に名前付けというのをしたりしてね。コードを読む人が意味をつかみにくいからだ。
２つ３８２６を並べる意味が意図的なのかどうかわからない。１つでも同じではないか。
ーー
１回限りの変更なら数字を変えて記述すればよい。
変数化するなら
Sub test08()
x = "11"
Rows(x).Select
End Sub
Sub test09()
x = 11
y = CStr(x) '文字列化
Rows(y).Select
End Sub
Sub test10()
x = 11
Rows(x).Select
End Sub
もOK
しかし
Sub test11()
Rows(5:8).Select
End Sub
はエラー。
ーーー
とびとび複数行を選択するなら
Sub test06()
Application.Union(Rows(3), Rows(8)).Select
End Sub
連続した行の場合は
Sub test07()
Rows("5:8").Select
End Sub
CTRLキーを押して、行を追加選択するのは
Sub test13()
Range("3:3,7:7").Select
Range("A7").Activate
End Sub
の("3:3,7:7").のような文字列を（）内に作る必要がある。

お礼

ありがとうございます
様々なアプローチがあるおですね。

凄く学習になります。

回答No.3

real beatin（@realbeatin）

こんにちは。お邪魔します。

直接の回答としては、
　　Rows(Mdata & ":" & Mdata).Select
のようになりますが、
　　"3836:3836"
文字列での参照に拘るのでしたら、
　　Range("3836:3836").Select
　　↓
　　Range(Mdata & ":" & Mdata).Select
とするか、
或いはRowsの平易な使い方として、、
　　Rows(3836).Select
　　↓
　　Rows(Mdata).Select
とするのが普通のやり方です。
「行単位での処理が必要」というような特殊な場面でもない限りは、
Rangeで指定するように覚えておいた方が紛れがないですし、アクセスも僅かながら速いです。
　　単行を指定するのか／区間としての複数行を指定するのか
　　行範囲として指定して行単位で処理したいのか／セル範囲としてセル単位で処理したいのか
条件や目的によって使い分けが必要な場面もありますので、覚えておいてください。
「単行を指定」して「行単位で処理する」（.Selectする）
という場合なら、
　　Rows(3836).Select
のように、行位置を表すインデックスとしての数値を指定するのが、
普通に簡単な方法です。
区間としての複数行の場合は、よくあるFor Each ... Next ループなどの例として、
' ' ///
Sub ReW9099719()
Dim c As Range
Dim FirstRow As Long, LastRow As Long

　　FirstRow = 3836
　　LastRow = 3842

　　For Each c In Rows(FirstRow & ":" & LastRow)
'　　　　行単位の処理
　　　　c.Select　'　例として、行が選択されます。
　　　　MsgBox c.Row & "行めを選択"　'　例としてメッセージボックス
　　　　Exit For　'　例として、ひとつめの行を選択したらループを抜けます。
　　Next
　　For Each c In Range(FirstRow & ":" & LastRow)
'　　　　セル単位の処理
　　　　c.Select　'　例として、セルが選択されます。
　　　　MsgBox c.Address(0, 0) & " を選択"　'　例としてメッセージボックス
　　　　Exit For　'　例として、ひとつめのセルを選択したらループを抜けます。
　　Next
　　For Each c In Rows(FirstRow & ":" & LastRow).Cells
'　　　　セル単位の処理
　　　　c.Select　'　例として、セルが選択されます。
　　　　MsgBox c.Address(0, 0) & " を選択"　'　例としてメッセージボックス
　　　　Exit For　'　例として、ひとつめのセルを選択したらループを抜けます。
　　Next

End Sub
' ' ///
のように目的に適う指定（参照）方法を選べるようにしておかないと、
意図した通りに処理されないことも起こりますから留意しておいてください。

以上です。

お礼

ありがとうございます

いやーこんなに親切に、
素晴らしい。
凄く、勉強になります。

回答No.1

MSZ006

Rows("" & Mdata & ":" & Mdata & "").Select

としてみてください。
ダブルクォーテーションを文字として扱う場合には　""　と２個続けます。

お礼

ありがとうございます

こういうやり方もあるのですね。
勉強になります。
明日、会社で試します。