エクセルVBA記述方法についての質問です。

質問

初心者です。色々調べるとVBAを使わないと下記の処理はできないみたいで・・・
わかる方がいれば是非教えて頂きたいです。

今回、毎日入力している数値に対して作業日付（更新日時）を残したいのですが、
例えば、A列のセルに数値を入力すると、入力したセルの右側のセル（この場合Ｂ列）に
日付と時間が残るようにしたいです。

Private Sub Worksheet_Change(ByVal Target As Range)
If Target = Range("a1") Then
Target.Cells(1, 2).Value = Now()
End If
End Sub

自分でも色々調べてやってみましたが、上記の記述だと、Ａ１に入力すればＢ１に作業日時が残ります。
やりたいことはこれに限りなく近いのですが、対象入力範囲をＡ列にしたいです。
Ａ列のどのセルに数値を入力しても、入力したセルの右側（Ｂ列）に作業日時を残していきたいです。
どのように記述すれば良いのかわからないので是非アドバイスを下さい。
よろしくお願い致します。

回答No.1

kagakusuki · ベストアンサー

もしかしますと、コピー&ペースト等の方法によって複数のセルに対して同時に入力が行われる事もあるかも知れませんし、A列のセルに入力済みであった値を消去した場合には、その右隣に入力されている日時も消える様にした方が良いのではないでしょうか？
　その事を考えますと、A列のセルの値が変更された際に、変更後の値が空欄の場合と、空欄ではない場合に分けて、それぞれ異なる処理をVBAで行う様にするよりも、値が変更されたA列のセルの右隣のセルに対してのみ「A列が空欄の場合は何も表示せず、空欄ではない場合には現在の日時を表示する」というワークシート関数を一旦入力してから、そのワークシート関数によって得られた値を、同じセルに値のみを入力し直すというVBAとした方が簡単かも知れません。
　又、例えば2行目は各列のデータの名称(項目名)を入力するために使用されていて、実際のデータは3行目以下に入力される様になっている場合において、A2セルの項目名を変更した際にB2セルに入力されていた項目名が、日時のデータに上書きされて消えてしまう様な事があれば不味いのではないかと思いますので、A列の値が変更された際に、その右隣のセルに日時が入力される様になるのは、何行目以下の行からにするのかという制限を設けておいた方が良いと思います。

　そういった事を考えますと、次の様なVBAは如何でしょうか？
　尚、下記のVBAは、A3以下のセルの値が変更(入力されていた値の消去も含む)された場合にのみ、その右隣のセルにその時の日時を入力する様になっております。

Private Sub Worksheet_Change(ByVal Target As Range)

Dim myChange As Range, myColumn As String, _
FirstRow As Long, LastRow As Long, myNow As Date

myColumn = "A" 'データが入力される列
FirstRow = 3 '実際のデータが入力されている最初の行
LastRow = Cells.SpecialCells(xlCellTypeLastCell).Row
If FirstRow > LastRow Then Exit Sub
Set myChange = Application.Intersect(Target, _
Range(myColumn & FirstRow & ":" & myColumn & LastRow))
If Not myChange Is Nothing Then
myNow = Now()
With myChange.Offset(0, 1)
.FormulaR1C1 = "=IF(RC[-1]="""","""",""" & myNow & """)"
.Value = .Value
End With
End If

End Sub

お礼

kagakusukiさん、ありがとうございます。
ご丁寧に使用する時のことまでも考えてくださり、
説明文もとてもわかりやすいです。
kagakusukiさんのおっしゃるとおり、Ａ列の数値を削除した時に
Ｂ列の日時も一緒に削除できると助かりますね。
それに１行目と２行目には項目名等をいれる予定なのでkagakusukiさんの
お心遣いに感謝します。
ベストアンサーとさせて下さい！
またご迷惑でなければ困った時にご相談させて下さい。
本当にありがとうございました。

回答No.2

dogs_cats

列番号が1以外はsubを抜け、A列のセルが変化した場合は、同じ行のB列にNOW関数で日時を入力します。
但し、セルの状態変化なので値をA列の値を削除した場合でもB列の時刻入力されます。

Private Sub Worksheet_Change(ByVal Target As Range)

If Not Target.Column = 1 Then Exit Sub
Target.Offset(0, 1).Value = Now()

End Sub

お礼

dogs_catsさん、ありがとうございます。
助かりました！まだまだ初心者なので、これからもっと勉強して
いきたいと思います。
また、悩んだらご相談させて下さい。
本当にありがとうございました。