ＥＸＣＥＬでの集計について質問

質問

ＥＸＣＥＬ賢者の方々にお知恵を拝借したいのですが。
以下の様式の運行管理表があるのですが

　　Ａ　　　　　　　Ｂ　　　　　　　　　　　Ｃ　　　　　　　Ｄ
　1　日付　　　　　行き先　　　　　　　走行距離　　　合計
　2　○月○日　　会社～Ａ地点　　　20　Ｋｍ
　3　空白　　　　　Ａ地点～Ｂ地点　　10　Ｋｍ
　4　空白　　　　　Ｂ地点～会社　　　30　Ｋｍ
　5　空白　　　　　空白　　　　　　　　　　　　　　　　　60　Ｋｍ
　6　○月×日　　会社～Ｄ地点　　　15　Ｋｍ
　7　空白　　　　　Ｄ地点～会社　　　15　Ｋｍ
　8　空白　　　　　空白　　　　　　　　　　　　　　　　　30　Ｋｍ

何も入力されていない　Ｄ5　に○月○日分の合計を計算させたいのですが？
*日付は毎日では、ない。
*１日行き先のの行数は、不確定
*9行目以降　日付・行き先・走行距離　未記入も当然あり得ます。

要するに、日付が入力された以降行き先が空白になったら、合計を出したい。
要素が解りずらいかもしれませんが？

可能であれば、作業列、作業行を作らずに（無理ならば作れます）、
関数のみで解決できないでしょうか？

回答No.3

kagakusuki · ベストアンサー

A列の日付が必ずしも昇順になっていなくとも計算可能な方法です。

　まず、D2セルに次の関数を入力して下さい。

=IF(AND($B1<>"",$B2="",COUNT($A$1:$A1)),SUM(INDEX($C$1:$C1,MATCH(9E+99,$A$1:$A1)):$C1),"")

　そして、D2セルをコピーして、D3以下に貼り付けて下さい。
　以上です。

　尚、もしも、その表のA列～D列のセルに対して、セルの切り取りや削除、挿入等の「セルの位置関係がずれる恐れのある操作」が行われる恐れがある場合には、その様な操作を行っても正しい結果が得られる様にするために、D2セルに入力する関数を次の様にして下さい。

=IF(AND(INDEX($B:$B,ROW()-1)<>"",INDEX($B:$B,ROW())="",COUNT($A$1:INDEX($A:$A,ROW()-1))),SUM(INDEX($C$1:INDEX($C:$C,ROW()-1),MATCH(9E+99,$A$1:INDEX($A:$A,ROW()-1))):INDEX($C:$C,ROW()-1)),"")

お礼

早々とご回答頂き有難うございました。

実際に入力して検証させて頂きました。
望むような結果が得られました。

また、”日付の昇順に関わらず”・”その後のセルの編集操作”
までご配慮頂き有難うございました。

自作では、あまり難しく考えすぎていたようです。

ご回答のいずれかを参考・採用させて頂きたいと思います。

回答No.2

tom04

こんにちは！
A列に日付はシリアル値で昇順になっている！という前提です。

↓の画像でD2セルに
=IF(AND(COUNTBLANK(A2:C2)=3,B1<>""),SUM(INDIRECT("C"&MATCH(MAX(A$2:A2),A$2:A2,0)&":C"&ROW()-1)),"")
という数式を入れオートフィルで下へコピー！

これで画像のような感じになります。m（_ _）m

お礼

早々とご回答頂き有難うございました。

実際に入力して検証させて頂きました。
望むような結果が得られました。

自作していても長い数式になり、分け解らなくなり質問させて頂いた次第

参考にさせて頂きます。

回答No.1

noname#203218

D2セルに下記敷を入力し、下方にオートフィルで可能だと思います。
=IF(C2="",SUM(C$1:C2)-SUM(D$1:D1),"")

ｋｍはセルのユーザー定義で書式設定して下さい

お礼

早々とご回答頂き有難うございました。

実際に入力して検証させて頂きましたが、
余分な数値　”0”までひょうじされてしまいました。
私に、ミスがあるのかもしれませんけど、

参考にさせて頂きます。