VBAで集計をしたい

質問

エクセル２００３を使っています。大きな表があり、ファイルサイズも大きい為、VBAで処理したい

表構成：
表全体の大きさは、SHEET1 (A1:CQ5000) SHEET2 (A1:CQ10000)程あり、品目種類は600種類、１品目につき品番は５～５０種類ほど構成が付いております

SHEET1,B5:B8には、4行分を結合セルにした品目があり、E3:CQ3 (3ケ月分、日付), E4:CQ4(曜日) 、E5:CQ5(計画予定数)となって数値データが入っています、

SHEET2, 行E1:CO3(3ケ月分日付),、A２:A10000列には（SHEET1同様の品目）,B2:B10000には品目に使う部品各種の品番、D2:D10000には品目１台あたりの使用数などがあります。

質問内容：
シート１品目、シート２品目を照合し、シート１品目毎の計画予定数×シート２品目毎使用数の計算結果を、シート２該当セルに表示させたい、

シート２該当セルはE2:CQ10000です、宜しくおねがいします。

回答No.2

ki-aaa · ベストアンサー

こんにちわ。

いくつか前提があります。

シートの名前が、シート1、シー2になっていること。
計画予定数は、5，9，13・・・行に有ること
シート1、シー2の日付は同じ物であること
シート2は、A列でソートされていること
シート2のデータは3行目から(日付が、二行使っているので)
日付は、E3:CR3にしてあります。・・・一日増やしてあります。

それから、この表がすべてうまくいっても、このままでは使い物になりません。
なぜかというと、表の範囲が広すぎて探すのが大変だからです
なので、新しく質問を立ててください。

Sub 集計()
Dim myDic As Object
Dim 品目配列, シート1配列, シート2配列
Dim i As Long, j As Long, k As Long, n As Long

With Sheets("シート1")
j = .Range("B" & Rows.Count).End(xlUp).Row + 3
品目配列 = .Range("B1").Resize(j, 1).Value '対象範囲を配列に　B列
シート1配列 = .Range("E1").Resize(j, 92).Value '対象範囲を配列に　E...CR列
End With

With Sheets("シート2")
j = .Range("A" & Rows.Count).End(xlUp).Row
シート2配列 = .Range("A1").Resize(j, 96).Value '対象範囲を配列に A...CR列
End With

Set myDic = CreateObject("Scripting.Dictionary")

For i = 3 To UBound(シート2配列)
If Not myDic.exists(シート2配列(i, 1)) Then
myDic.Add シート2配列(i, 1), i 'keyに追加、itemにi・・iは行数
End If
Next i

For j = 5 To UBound(品目配列) Step 4 '...5行目から最終行まで
If myDic.exists(品目配列(j, 1)) Then
For i = 1 To 92
k = myDic.Item(品目配列(j, 1))
Do
シート2配列(k, i + 4) = シート2配列(k, 3) * シート1配列(j, i)
If シート2配列(k, 1) <> シート2配列(k + 1, 1) Then Exit Do
k = k + 1
Loop
Next i
Else
'マッチしなかったときの処理
End If
Next j

With Sheets("シート2")
.Range("A1").Resize(UBound(シート2配列), 96).Value = シート2配列
End With

Set myDic = Nothing
Erase シート1配列, シート2配列, 品目配列

End Sub

お礼

ありがとうございました。解決しました

補足

おはようございます。ご投稿頂きありがとうございます、私の説明も悪いので申し訳ありません、マクロ実行した所、
"シート2配列(k, i + 4) = シート2配列(k, 3) * シート1配列(j, i)"

部分（箇所）で停止しますが、再度教えて下さい

回答No.1

TAKA_R

読んでいるとＶＢＡのコード自体はそれほど複雑でも、難しくもなさそうです。
（ちなみに間違いがあった先日の質問文のほうが分かりやすいと思います）
が、「シート１」の説明がよく分かりません。
品目が６００種あって、４行分縦結合？
残りのｂ列は？
６００個が縦に４行分ずつ連なっているんでしょうか？
それとも品目１つにつき、１シート。６００枚あるんですか？
ここが分からないことには前にも後ろにも進めません。

補足

説明不足で申し訳ありません
>「シート１」の説明がよく分かりません。品目が６００種あって、４行分縦結合？
はい縦結合です。
>６００個が縦に４行分ずつ連なっているんでしょうか？
１品目につき、縦に４行分ずつ連っています、シート１、シート２の２つのシートのみです。