VBAでWEB上のデータを変数に代入するには？

質問

VBAで仕事上のデータを処理するシステムを作成しており、
どうしてもWEB上のデータを変数に入れたいのですが、どのような方法が良いでしょうか？

取得したいデータは関税協会にある為替相場です。
http://www.kanzei.or.jp/check/rate_all/2012/20120318.htm
上記のページに行くとアメリカ合衆国の為替レートが81.33というのがわかります。

VBA上の変数に81.33という数値を入れる方法を教えてください。
よろしくお願いします。

回答No.4

NOBNNN

#2　です。

＃２ よりも効率的なやり方が見つかりましたので実験ソースを公開します。
下記のサイトを参考にしました。＜！感謝＞

　◆ブラウザでサイトを開くことなく、プログラムからHTMLソースを取得する方法です。
　 　http://www.kanaya440.com/contents/tips/vbs/007.html

このソースで実験してみたところ　＃２にくらべて　かなり高速です。
Ｅｘｃｅｌ でなくても使えます。

#3の方もいっているとおり、あとは　ＵＲＬ　のアドレスをどうするのかが問題ですけど。

++++++++++++++++++++++<サンプル　実験ソース >+++++++++++++++++++
Option Explicit

Const cns_URL As String = "http://www.kanzei.or.jp/check/rate_all/2012/20120318.htm"

Const FindString As String = "アメリカ合衆国", FindMoney As String = "ドル(USD)"

Private m_strHTML As String

Private m_FindOK As Boolean

Private m_Anser As String

Sub DollerYen_GET_PROC()

Dim arryHTML As Variant

Dim row As Integer
Dim I As Integer
Dim strWk As String

m_FindOK = False
m_Anser = Empty

If GetHtmlSource(cns_URL, m_strHTML, False) = False Then
GoTo MSG_DollerYen_GET_PROC
End If

arryHTML = Split(m_strHTML, vbLf)

For row = 0 To UBound(arryHTML)

'Debug.Print (arryHTML(row))

If InStr(1, arryHTML(row), FindString) > 0 Then
If InStr(1, arryHTML(row + 2), FindMoney) > 0 Then
m_FindOK = True
strWk = ""

For I = 1 To Len(arryHTML(row + 4))

strWk = Mid(arryHTML(row + 4), I, 1)

If IsNumeric(strWk) Or strWk = "." Then
m_Anser = m_Anser & strWk
End If
Next I
Exit For
End If
End If
Next row

MSG_DollerYen_GET_PROC:
If m_FindOK Then
MsgBox "アメリカ合衆国 ドル(USD) は（" & m_Anser & "円)です。"
Else
MsgBox "為替（アメリカ合衆国）の値が見つかりません。", vbExclamation
End If
Exit_DollerYen_GET_PROC:
Exit Sub
End Sub
'####################################################################################
'#
'# 関数名：GetHtmlSource
'#-----------------------------------------------------------------------------------
'# 機能 ：指定のURLからHTMLソースを取得する
'# 引数 ：strURL I URL
'# strRetVal O 取得した文字列
'# isSJIS I ソースが Shift-JIS の場合 True
'# strID I ドメイン認証が必要な場合のユーザーID
'# strPass I ドメイン認証が必要な場合のパスワード
'# 戻り値：True 正常、False 失敗
'#
'####################################################################################
Private Function GetHtmlSource(ByVal strURL As String, _
ByRef strRetVal As String, _
Optional ByVal isSJIS As Boolean, _
Optional ByVal strID As String, _
Optional ByVal strPass As String) As Boolean

Dim oHttp As Object

'オブジェクト変数に参照をセットします
On Error Resume Next
Set oHttp = CreateObject("MSXML2.XMLHTTP")
If (Err.Number <> 0) Then
Set oHttp = CreateObject("MSXML.XMLHTTPRequest")
End If
On Error GoTo 0
If oHttp Is Nothing Then
MsgBox "XMLHTTP オブジェクトを作成できませんでした。", vbCritical
Exit Function
End If

'ドメイン認証が必要な場合
If strID <> "" Then
oHttp.Open "GET", strURL, False, strID, strPass
Else
oHttp.Open "GET", strURL, False
End If
oHttp.Send

'失敗した場合は関数を終了します。
If (oHttp.Status < 200 Or oHttp.Status >= 300) Then Exit Function

'ソースを格納します
If isSJIS Then
'ソースが Shift-JIS の場合
strRetVal = StrConv(oHttp.responseBody, vbUnicode)
Else
'ソースが Unicode の場合
strRetVal = oHttp.responseText
End If

'オブジェクト変数の参照を解放します
Set oHttp = Nothing

'戻り値をセットします
GetHtmlSource = True

End Function

+++++++++++++++++++++++++++++++++++++++++++++

参考URL：

http://www.kanaya440.com/contents/tips/vbs/007.html

補足

NOBNNN様
色々調べてくださったようで詳細なご回答に感謝します。

是非実行したかったのですが、まだVBAの勉強をしたばかりでして
せっかく頂いたコードを活用できずにいます、、

ボタンを設置して、それを押したらドル円の値を変数に入れる形にしたかったので
ボタンを設置し、上記のコードを貼り付けましたが、プロシージャー内では無効というエラーがでてしまいます。

おそらく私が使い方を理解していないからだと思います。
もうちょっと勉強してみますが、もし追加で実行に移せるアドバイスを頂けたら嬉しいです。

お手数をおかけして申し訳ありませんが、もしお時間ありましたらお願いします。