[Flash]actionscript2.0を用いて歯車を作りたいのですが

質問

Adobe FLASH CS2を使い２つのかみ合った歯車を制作しています。
ドラッグで片方の歯車を回転させると
もう片方の方は逆回転になるはずですが、
うまいことactionscriptをかくことができません。
片方はこのようなactionscriptを使っているのですが
うまい作り方はないでしょうか。
よろしくおねがいします。
on (press) {
//このMCの基準点からのマウス座標を取得
rx0 = _root._xmouse-this._x;
ry0 = _root._ymouse-this._y;
//このMCの基準点とマウスとの距離を算出
td0 = Math.sqrt(rx0*rx0+ry0*ry0);
//マウスによる回転の差分を算出
tr0 = (Math.PI/2+Math.atan2(ry0, rx0))*180/Math.PI-this._rotation;
//onEnterFrame を定義
this.onEnterFrame = function() {
//現在のMCの基準点からのマウス座標を取得
rx1 = _root._xmouse-this._x;
ry1 = _root._ymouse-this._y;
//このMCの回転を計算
this._rotation = (Math.PI/2+Math.atan2(ry1, rx1))*180/Math.PI-tr0;
//このMCの移動を計算
};
}
on (release, releaseOutside) {
//この onEnterFrame を削除
delete this.onEnterFrame;
}

回答No.2

kikousya

これは動きっぱなしですが　参考になるのでは？
ドラッグも同じ要領ですね
onClipEvent (enterFrame) {
step = _parent.KN.step/(80/10);//歯数を合わせる
_rotation = step*-1;//逆回転
_parent._parent.K2 = step;
}
onClipEvent (load) {
step = 0;
}

onClipEvent (enterFrame) {
step += speed;
_rotation = step;
_parent._parent.K1 = step;
if (step>(360*8)-speed) {//初期化
step = 0;
}
}
onClipEvent (load) {
step = 0;
speed = 10;
}
参考までに僕のサイトで紹介しています

参考URL：

http://kikousya.jp/M02_Gallery/G02_watch/index.html

回答No.1

BlurFiltan

場合によるので何とも言えません。

２つの歯車は同じ大きさでインスタンスで同じ歯の数を持つムービークリップであったとします。
そうでなければ以下とは全く別物になります。

また仮に，２つの歯車には両方とも歯が20度ずつ18本あるとします。

さらに２つの歯車は左右に真横に並べるものとします。

歯が20度ずつあって左右に真横に並べるという場合には，
そのままの角度(_rotation=0)では歯車がかみ合いません。
そこで左右どちらかの歯車のうち一方を10度傾ける必要があります。

その歯が20度ずつ18本ある歯車ムービークリップ２つを
左右に並べて右側の歯車を10度時計回りに回転させて配置し，
左のムービークリップには 「gear_mc1」
右のムービークリップには 「gear_mc2」
というインスタンス名を付けたのが下の図↓です。

この場合は(この場合に限っては)，
左の 「gear_mc1」 には次のように書けば良いと思います。

コピペ可能
-------------------------------------------------
on (press) {
//このMCの基準点からのマウス座標を取得
rx0 = _root._xmouse-this._x;
ry0 = _root._ymouse-this._y;
//マウスによる回転の差分を算出
tr0 = (Math.PI/2+Math.atan2(ry0, rx0))*180/Math.PI-this._rotation;
//onMouseMove を定義
this.onMouseMove = function() {
//現在のMCの基準点からのマウス座標を取得
rx1 = _root._xmouse-this._x;
ry1 = _root._ymouse-this._y;
//このMCの回転を計算
this._rotation = (Math.PI/2+Math.atan2(ry1, rx1))*180/Math.PI-tr0;
// ★親階層の gear_mc2 の回転を このMCの回転+10 にする
_parent.gear_mc2._rotation=-this._rotation+10;
// 即表示を更新
updateAfterEvent();
};
}

on (release, releaseOutside) {
//この onMouseMove を削除
delete this.onMouseMove;
}
-------------------------------------------------

右の歯車 「gear_mc2」 は，上とほぼ同じですが，

// ★親階層の gear_mc2 の回転を このMCの回転+10 にする
_parent.gear_mc2._rotation=-this._rotation+10;

この部分のみを次のように変えます。

// ★親階層の gear_mc1 の回転を -(このMCの回転)-10 にする
_parent.gear_mc1._rotation=-this._rotation-10;

これで左の歯車を回すことによって右の歯車が回転し，
右の歯車を回すことによっても左の歯車が回転するものができます。

なお，Flash CS2 というものが売られていたかどうかは知りませんので
なるべく書かれていらっしゃるスクリプトをそのまま使うような形で書き替えました。
Flash MX (Flash 6) 以上で使用可能で Flash Player 6 以上で再生可能な ActionScript1.0 です。

> うまい作り方はないでしょうか。

場合によって「どう動かすのか」を考えるしかないでしょう。

全く別のアプローチのしかたとしては，
モーショントゥイーンによって２つの歯車がかみ合ったまま回転するアニメーションをムービークリップの中にあらかじめ作成しておいて，
マウスの動向によってそのムービークリップ内のフレームを MovieClip.gotoAndStop(**) させても良いかもしれません。

　_root
　　　└２つの歯車入りムービークリップ
　　　　　├歯車ムービークリップ1
　　　　　└歯車ムービークリップ2

この方法を使ってもかなり考えないとできませんよ。