Excel VBA ParamArray 可変個引数の渡し方

質問

Excel VBAで
可変個引数関数Fanc1から、その引数を
可変個引数関数Fanc2に渡したい。

下記例では、A1=a, B1=b, C1=cのとき、#VALUE!となります。
　Concatenate2(A1:B1,C1,"po")="abcpo" 問題無し
　Fanc1(A1:B1,C1,"po")=#VALUE!
Fanc1でも上と同じ出力にしたいのです。

Function Concatenate2(ParamArray MyArray()) As String
Dim S As String
Dim v As Variant
Dim c As Variant

For Each v In MyArray
If TypeName(v) = "Range" Then
For Each c In v
S = S & c.Value
Next
Else
S = S & v
End If
Next
Concatenate2 = S
End Function

Function Fanc1(ParamArray MyArray()) As String
Fanc1 = Concatenate2(MyArray())
End Function

回答No.2

noah7150

今回の条件で直接Concatenate2を呼び出した場合
MyArray()は３個の配列で渡されますが
Fanc1経由で呼び出された場合のConcatenate2での
MyArray()は１個の配列です
この１個の配列の中身が配列で渡されます。

なので１個の配列引数を持つ共通的な関数で展開する形にするのが妥当かと
ただ、ParamArrayは特殊な配列のようでそのまま他の関数に渡そうとするとエラーになるため別な配列に複写して渡さないと動作しませんでした
ただ、共通関数の受取をParamArrayにするとエラーにならないので下記
の２通りの方法を考えました。

Function ComFunc(MyArray As Variant) As String
Dim S As String
Dim v As Variant
Dim c As Variant

For Each v In MyArray
If TypeName(v) = "Range" Then
For Each c In v
S = S & c.Value
Next
Else
S = S & v
End If
Next
ComFunc = S
End Function

Function Concatenate2(ParamArray MyArray()) As String
Dim wArray()
wArray = MyArray
Concatenate2 = ComFunc(wArray)
End Function

Function Fanc1(ParamArray MyArray()) As String
Dim wArray()
wArray = MyArray
Fanc1 = ComFunc(wArray)
End Function

若しくは

Function ComFunc(ParamArray MyArray()) As String
Dim S As String
Dim v As Variant
Dim c As Variant

For Each v In MyArray(0)
If TypeName(v) = "Range" Then
For Each c In v
S = S & c.Value
Next
Else
S = S & v
End If
Next
ComFunc = S
End Function

Function Concatenate2(ParamArray MyArray()) As String
Concatenate2 = ComFunc(MyArray)
End Function

Function Fanc1(ParamArray MyArray()) As String
Fanc1 = ComFunc(MyArray)
End Function

実を言うと、もう１通りTypeName(v) = "Variant()"なら
この中でFor Eachを行う方法もあります。

お礼

なるほど、そんな対処法が。
下記相違が重要なのですね。
For Each v In MyArray(0)
For Each v In MyArray

回答No.1

pkh4989

そのまま、引数を渡すとConcatenate2側で、引数が0になります。
良い方法が有ると思いますが、取りあえず、以下のように変更してみてください。

Function Fanc1(ParamArray MyArray()) As String
　　Fanc1 = Concatenate2(MyArray())
End Function
　　↓
Function Fanc1(ParamArray MyArray()) As String
　　Dim i As Integer
　　Fanc1 = ""
　　For i = 0 To UBound(MyArray)
　　　　Fanc1 = Fanc1 & Concatenate2(MyArray(i))
　　Next
End Function

お礼

返答ありがとうございます。
これで取敢えず処理は可能になります。
でも、Concatenate2の処理によりFanc1を変える必要が有、隠蔽化に難。(> <
おっしゃるように、もっとよい方法があるとよいのですが。