ブラウザの高さのみにあわせて伸縮するムービークリップのスクリプトについて

質問

よろしくお願い致します。
ステージの縦横中央に、800px×500pxのムービークリップ（インスタンス名：contents）を配置しています。
ステージの縦の長さが700pxより大きければ、contentsの大きさを800px×500pxで固定して、700px
より小さければ、ステージの縦の大きさに合わせてcontentsを縮小させていくスクリプトを書きたいと思っています。

ブラウザに合わせてムービークリップを拡大・縮小させるスクリプトは分かるのですが、ステージの縦の高さ
のみに限定して縦の高さが700px以上のときはムービークリップの大きさを固定する、というのがよく分かりません。

どなたかお分かりになられる方がいらっしゃいましたら、どうかご教授下さいますようお願い致します。

回答No.1

BlurFiltan · ベストアンサー

800px×500px のムービークリップ（インスタンス名：contents）は，
横幅が 800px で，高さが 500px ということですよね。

そして，その比はそのままで，
ステージの縦の高さが700px以上のときはムービークリップの高さを700px（横幅=1120px）で固定，
ステージの縦の高さが700px未満のときはムービークリップの高さをステージの高さ（横幅=800/500×ステージの高さ）で変動させる。
ということですね。

そうだとすると，
そのこと（上に書いたこと）を実行させれば良いのです。

まず，
ムービークリップ contents は左上のコーナーを基準点として作成します。
基準点の位置によってスクリプトは変わるので基準点の位置がものすごく大切です。

この ムービークリップ contents の基準点がステージの左上のコーナー（0，0）に来るように配置します。
つまりステージ左上にピッタリ付けるということです。

そして，このムービークリップ contents が存在するフレーム（_root の フレーム1 など）に，
次のスクリプトを書けばできあがりです。

----------------------------------------------
// ステージ内容の拡大縮小なし
Stage.scaleMode = "noScale";
// ステージの上左を拡大縮小の基準にする
Stage.align = "TL";

// MC(ムービークリップcontents)の横幅の設定
var MW:Number = 800;
// MCの高さの設定
var MH:Number = 500;
// MCの高さの上限を設定
var MHMax:Number = 700;

// ステージ監視用のインスタンスを作成
var sListener:Object = new Object();

// ステージのサイズが変わったときの動作定義
sListener.onResize = function() {
// もしステージの高さがMCの高さの上限以上であれば
if (Stage.height>=MHMax) {
// MCの高さと横幅を固定
contents._height = MHMax;
contents._width = MW/MH*MHMax;
} else {
// それ以外は　MCの高さをステージの高さで変動させる
contents._height = Stage.height;
// MCの横幅を同じ比で変動させる
contents._width = MW/MH*Stage.height;
}
// 即 表示を更新
updateAfterEvent();
};

// ステージ監視用インスタンスをステージのリスナーとして登録
Stage.addListener(sListener);

// 最初の表示段階で sListener.onResize を実行
sListener.onResize();
----------------------------------------------

スクリプト的には，
物によって変える部分は次の部分だけです。

// MC(ムービークリップcontents)の横幅の設定
var MW:Number = 800;
// MCの高さの設定
var MH:Number = 500;
// MCの高さの上限を設定
var MHMax:Number = 700;

しかし，
800 や 500 は ムービークリップ 自体からも取得できますから，
次のようにしても良いと思います。

// MC(ムービークリップcontents)の初期横幅を記録
var MW:Number = contents._width;
// MCの初期高さを記録
var MH:Number = contents._heighth;
// MCの高さの上限を設定
var MHMax:Number = 700;

こうすると，高さの上限の設定だけで済みます。
つまり，
ムービークリップを作成しなおした場合でも，高さの上限を変えないとすれば，
何も変える必要はなくなります。

お礼

丁寧にご回答頂き誠にありがとうございました。
お教え頂いたスクリプトで問題なく動作いたしました。

var MHMax:Number = 700;
上限を指定すれば良いのですね。勉強になりました。

// MC(ムービークリップcontents)の初期横幅を記録
var MW:Number = contents._width;
// MCの初期高さを記録
var MH:Number = contents._heighth;
// MCの高さの上限を設定
var MHMax:Number = 700;
この記述方法であれば、同じように縮小したいムービークリップに応用できるんですね。

色々とお手数をお掛け致しました。本当にありがとうございました。