ブックを開かずにデータを読む方法を教えてください

質問

エクセルVBAでブックを開かずにデータ読み取る方法をどなたか教えていただけないでしょうか？ExecuteExcel4Macroメソッドを使用する方法を検討しているのですが、ヘルプを見ても使い方が良くわかりません。例えば
　　　Book1のsheet(1)のRange("A1")
に既存する
　　　Book2のsheet(1)のRange("B1")
の値をコピーする場合、Book2を開かずに処理したいのですが、やり方がわからず困っています。よろしくお願いします！

回答No.3

Wendy02 · ベストアンサー

こんばんは。

ブックを開かずに開く方法は、いくつかありますが、よほどの理由がなれば、そのような必要はありません。

#1さんのおっしゃるような方法で、特に、オートメーション・オブジェクトを作って取り出すような方法なら、何の支障もないはずです。

ExecuteExcel4Macro　で取り出すのは、通常は、ワン・セルの値だけですが、関数も埋め込めます。コツは、R1C1 方式で書くということだけです。

以下のサンプルで、イミィディエイトウィンドウで出力された数式をごらんください。

Sub Test1()
Dim ret As Variant
　ret = getValue("Book2.xls", "Sheet1", "A1")
End Sub

Function getValue(ByVal Bk As String, _
　　　　　　　　　ByVal strSht As String, _
　　　　　　　　　ByVal strCell As String, _
　　　　　　　　　Optional ByVal strPath As String)

　If Not strCell Like "R#*C#*" Then
　 strCell = Application.ConvertFormula(strCell, xlA1, xlR1C1, xlAbsolute)
　End If
　If strPath = "" Then
　　 strPath = Application.DefaultFilePath & "\"
　End If
　Debug.Print "'" & strPath & "[" & Bk & "]" & strSht & "'!" & strCell
　getValue = ExecuteExcel4Macro("'" & strPath & "[" & Bk & "]" & strSht & "'!" & strCell)
End Function

------------------------------------------------
ただし、
>　Book2のsheet(1)のRange("B1")

シートインデックスから取り出す方法は、このような方法では難しいではないかと思います。

補足

サンプル付きのご解答ありがとうございました。参考にさせていただきます。ところで

> ExecuteExcel4Macro　で取り出すのは、通常は、ワン・セルの値だけですが

　範囲を指定して取り出すことは不可能でしょうか？もし方法があれば教えていただけませんか？

回答No.5

Wendy02

こんばんは。

>範囲を指定して取り出すことは不可能でしょうか？

遅くなりました。書きかけでアップロードしませんでした。
それは、数字でしたら、統合(Consolidate)という方法がありますが、それ以外は、ADOで取り出すという方法があります。両方とも、一応、フィールド行が必要になります。ADOなら、文字列でも取り出すことが可能ですし、検索も可能です。
ただ、同じExcelシートなら、直接開いたほうがおそらく手数などは簡単ではないかと思います。

また、INDEX 関数を使って、範囲自体は認識はしているようですが、Ver.4 マクロ関数では、やはり一つずつしか取り出せないようです。Evaluate 関数は使えません。他には、やはり、ダミーのシートを用いて、数式で取り出すという方法があります。それが、一番簡単なのですが……。

お礼

> ただ、同じExcelシートなら、直接開いたほうがおそらく手数などは簡単ではないかと思います。
> Ver.4 マクロ関数では、やはり一つずつしか取り出せないようです。

　大量のデータを取り出したいので、おっしゃる通り直接開いた方が手間も時間もかからない感じですね。

> 数字でしたら、統合(Consolidate)という方法がありますが、それ以外は、ADOで取り出すという方法があります。

　知りませんでした。私はVBA経験1年半(エクセルのみ)で初級の参考書２冊程度の勉強量なのでまだまだ知識不足ですね..少し上級の本で勉強したいと思います。どうもありがとうございました！

回答No.4

onlyrom

詳しくはWendy02さんにお任せして、、(^^;;;

>範囲を指定して取り出すことは不可能でしょうか
範囲の値を単純に取出すだけなら、Forで回すという方法もありますね。

ThisWorkBookのSheet1のA1以降に
Book2のSheet1のB1:B10の値を転記する場合

'------------------------------------
Sub Test()
Dim N As Long
Dim myValue
For N = 1 To 10
　myValue = ExecuteExcel4Macro("'C:\BBB\[Book2.xls]Sheet1'!R" & N & "C2")
　Sheets("Sheet1").Cells(N, "A").Value = myValue
Next N
End Sub
'---------------------------------

ところで、質問者のVBAスキルはどの程度なのでしょう。
そこらあたりも提示しておくと回答するほうもし易いかと。

お礼

遅くなってすみません。私のVBAのスキルは初級の参考書2冊を駆使して実践している程度です。現在処理速度の向上を図っているのですが「ブックを開いてデータをコピーする」という作業に代わる高速化の方法がないものかと思案していました。forで回すしかないということは大量のデータになるとブックを開いてコピーした方が速そうですね。どうもありがとうございました！

回答No.2

onlyrom

Book2.xlsがＣドライブのフォルダーＢＢＢにある場合。
'---------------------------------------
Sub Test()
　Dim myValue
　myValue = ExecuteExcel4Macro("'C:\BBB\[Book2.xls]Sheet1'!R1C2")
　Sheets("Sheet1").Range("A1").Value = myValue
End Sub
'--------------------------------------

気をつける点は、セル参照の仕方が、R1C1形式だということだけです。

お礼

R1C1形式で行えばいいのですね。ありがとうございました！

回答No.1

wolf03

不可能です。
bookの内部のデータにアクセスするには可視不可視かは問いませんがbookを開く必要があります。

ユーザに見せたくないだけなら不可視で開いて使うことになります。

お礼

不可視で開いて使ってみます。ありがとうございました。