共有ブックのリンクについて

質問

以下のようなマクロを作成しました

１．Sheet2をコピーする（新規ブック）
２．Sheet1のＡ１のファイル名で保存する（入力済）
３．Ａ１にハイパーリンクを設定する

「ブックを共有」にしたら（３）のハイパーリンクの
設定でエラーが出るようになってしまいました。

で質問ですが
（１）共有ブックはハイパーリンクが設定できないのでしょうか？
　　マクロが間違っている？　
　　何かパラメータが足りない？
　　そんなことできない？

（２）設定できないとしたら、誰も使用しないような深夜に
　　ブックの共有を解除し、リンクを貼り付けるマクロを実行するということは可能でしょうか？

わかりにくい質問で申し訳ありませんが教えてください。
よろしくお願いします。

Sub Macro1()
Worksheets(2).Activate
Sheets(2).Copy
ActiveWorkbook.SaveAs Filename:="A1ファイル名"
ActiveWindow.Close
Worksheets(2).Activate
ActiveSheet.Hyperlinks.Add Anchor:=Range("A1"), Address:="A1ファイル名"
End Sub

回答No.2

papayuka · ベストアンサー

こんにちは。

（1）は既に回答が出てますので割愛して、（2）はExcelだけでは無理ではないかと思います。

共有中かどうかを判断して、マクロを実行するって感じのサンプルです。実際に共有環境がないので、共有環境で上手く動くかは確認出来てません。

必ずコピーブック等のテスト環境で試して下さい。

Sub Test()
Dim Users, wb As Workbook, myRange As Range
Dim saveFlg As Boolean

　On Error GoTo myExit:
　'警告を止める
　Application.DisplayAlerts = False
　'画面を止める
　Application.ScreenUpdating = False
　With ThisWorkbook
　　'ユーザーが複数の場合は何もしない
　　Users = .UserStatus
　　If UBound(Users, 1) > 1 Then Exit Sub
　　saveFlg = .MultiUserEditing
　　'共有なら解除する
　　If saveFlg Then .ExclusiveAccess
　　'ブックを追加
　　Set wb = Workbooks.Add(xlWBATWorksheet)
　　'保存するファイル名のあるセル
　　Set myRange = .Worksheets(1).Range("A1")
　　'コピー
　　.Worksheets(2).Cells.Copy
　　wb.ActiveSheet.Cells.PasteSpecial xlPasteAll
　　wb.ActiveSheet.Range("A1").Select
　　Application.CutCopyMode = False
　　'コピーを保存
　　wb.SaveAs FileName:=myRange.Text
　　wb.Close
　　'ハイパーリンクセット
　　.Worksheets(1).Hyperlinks.Add Anchor:=myRange, _
　　　　　　　　　 Address:=myRange.Text
　　'もともと共有なら共有で保存
　　If saveFlg Then
　　　 .SaveAs FileName:=.FullName, AccessMode:=xlShared
　　Else
　　　 .SaveAs FileName:=.FullName
　　End If
　End With
myExit:
　Set wb = Nothing: Set myRange = Nothing
　Application.DisplayAlerts = True
　Application.ScreenUpdating = True
End Sub

お礼

>（2）はExcelだけでは無理ではないかと思います

そうですか？無理ですか？残念です。
マクロはお書きいただきありがとうございます。
たとえ、共有環境でうまく動かなくても
マクロの勉強として利用させていただきます。
まずはチャレンジしてみます。

回答No.1

FlossenEngel

(1)だけ。ヘルプの「共有ブックの制限」に記載されています。と思います。

お礼

共有ブックにしてしまうとハイパーリンクが
選択できないようになってしまうことは知っていましたがもしかしたらマクロを使えば方法があるのではないかと
思い質問させていただきました。
やっぱり共有ブックではリンクは出来ないのでしょうか？
ご回答ありがとうございます。