createTextFieldを使う際にインスタンス名を動的に変える方法について

質問

お世話になります。
my_mc.createTextField("Menu_TXT",2,200,150,30,12)
通常、上記のようなスクリプトを書くとmy_mcにMenu_TXTというテキストフィールドを配置するのですが、これをMenu_TXT0～Menu_TXT10まで作成したい場合、for文を使って構築したいと思っています。
for文の構成は分かるのですが、インスタンス名を動的に変えたい場合の記述法が分かりません。例えば"Menu_TXT"+iとするとエラーですよね！？これをうまく書く方法はないでしょうか？

回答No.1

DPE

createTextField で空っぽのテキストフィールドを作成する時に指定する名前は、ただの文字列です。
ですから、for ループの中で "Menu_TXT" + i と書いてもエラーにはなりませんし、テキストフィールドも正常に作成されます。

しかし、できたテキストフィールドの書式を決めたり、表示させる内容を変更する時は、作られたテキストフィールドの参照を指定しなければなりません。
ActionScript では、文字列を参照に変換することができます。
この変換には eval 関数か配列演算子 [　] を利用しますが、eval 関数を使用する方法は旧式です。
特に Flash Player 6 以降は eval 関数の用法に制限がありますので、配列演算子 [　] を使うようにしましょう。

例えば、ムービークリップ my_mc の中にテキストフィールド” Menu_Text ”がある場合、文字列からこのテキストフィールドを操作する時は

　my_mc[ "Menu_TXT" ].text = "サンプル";

というように書きます。

[　] の中には文字列を入れますので、文字列の連結も利用できます。
for ループの中で

　my_mc[ "Menu_TXT" + i ].text = "サンプル";

↑このように使うと、テキストフィールドの名前を” Menu_TXT ”＋連番で付けておけば、該当する番号のテキストフィールドを次々に操作することができます。

------------------------------------------------------------

仮に、空っぽのムービークリップ” my_mc ”があるとします。
このムービークリップ内にテキストフィールド Menu_TXT0 ～ 4 （外枠あり）を作り、その中に決まったテキストを表示するスクリプトは、次のようになります。
このスクリプトは、my_mc があるタイムラインのフレームに設定してください。

（↓各行頭に全角のスペースが入っています。コピーする際は、全て半角のスペースかタブに置き換えてください）

　 //テキストフィールドに表示するテキストのリスト
　item_list = new Array();
　item_list = [ "トップ" , "製品情報" , "サポート" ,"会社情報" , "お問い合わせ" ];

　//テキストフィールドの書式
　format = new TextFormat();
　format.font = "_等幅";
　format.size = 15;
　format.align = "center";

　for( i = 0 ; i < 5 ; i++ )
　{
　　//空のテキストフィールドを作成
　　my_mc.createTextField( "Menu_TXT" + i , i , 0 , 20 * i , 150 , 20 );

　　//外枠を付ける
　　my_mc[ "Menu_TXT" + i ].border = true;

　　//配列変数を見て、テキストフィールドにテキストを表示
　　my_mc[ "Menu_TXT" + i ].text = item_list[ i ];

　　//書式を適用する
　　my_mc[ "Menu_TXT" + i ].setTextFormat( format );
　}

**********************

テキストフィールドに表示する内容は、各テキストフィールドが持っている text というプロパティで管理されています。
このプロパティを書き換えることで、テキストフィールドの表示内容を変更できます。

上記の作例では、表示するテキストを予め配列変数に入れておいて、作ったテキストフィールドに順次表示するようにしています。
配列変数は、同じ名前で管理番号（インデックス）だけが違う変数が集まったものです。
配列変数のインデックスは 0 からの連番になっているので、テキストフィールドを作る for のループも 0 から始めると、テキストフィールドの番号と配列変数のインデックスがズレなくなります。

[　] で文字列を参照に変換する手法は、テキストフィールドだけでなく、ムービークリップやボタン、ActionScript でいうところのオブジェクト（変数のようなもの）にも使えます。
このサイトでもいろいろな使い方が紹介されていますので、機会がありましたら研究してみてください。

**********************

なお、Flash Player 8 （作成ツールは Flash 8 ）からは、createTextField メソッドは作成したテキストフィールドの参照を返してくるようになりました。
上記のスクリプトでは、テキストフィールドの表示内容や書式を決める際にいちいち [　] 演算子で文字列を参照に変換しているのですが、

　//空のテキストフィールドを作成
　txt_obj = my_mc.createTextField( "Menu_TXT" + i , i , 0 , 20 * i , 150 , 20 );

↑このように、変数に createTextField の戻り値を保存しておくと便利です。

例えば、先の例は Flash Player 8 以降でパブリッシュする場合は

　for( i = 0 ; i < 5 ; i++ )
　{
　　//空のテキストフィールドを作成
　　txt_obj = my_mc.createTextField( "Menu_TXT" + i , i , 0 , 20 * i , 150 , 20 );

　　//配列変数を見て、テキストフィールドにテキストを表示
　　txt_obj.text = item_list[ i ];
　}

と、スッキリと書くこともできます。

繰り返しますが、この仕様は Flash Player 8 で追加されたものです。
Flash Player 7 以前の createTextFiled メソッドは戻り値がありません。
Flash 8 以降をお使いでも、古いバージョンでパブリッシュする時はご注意ください。

補足

有難うございます。
補足というか、インスタンスでの取り扱いはよく分かったのですが、テキストフィールド（ダイナミックテキスト）の変数の取り扱いも教えてください。このスレッドでお願いすることではないのでしょうが、少し似た疑問ですのでご了承ください。

ステージに配置されたMenu_MCインスタンスに、createTextFieldにてText_TXTというテキストフィールドを作成します。この時、このテキストフィールドの変数はmenu0とします。そして、これとは別にData_MCという空ムービークリップをMenu_MCと同じ階層に配置します。
＜Data_MCのAS(ムービークリップアクション）＞
onClipEvent (load) {
loadVariables("command.txt", this);
}

＜Menu_MCのAS（フレームアクション）＞
Menu_MC.Menu_TXT.text=Data_MC.menu0

これで、外部テキストからmenu0のデータを動的テキストフィールドに表示することができました。
質問は、Menu_MC.Menu_TXT.text=Data_MC.menu0のmenu0の部分を動的に変化させたいのです。インスタンスではeval("インスタンス名"+ 変化値)等で対応できますが、テキストフィールドの動的なコーディングはできるのでしょうか？menu + i(変化する値)みたいな・・・