ユーザーコントロールの配列化

質問

VB.NETのWindowsコントロールライブラリで作成したコントロールをメインになるプロジェクトから動的に呼び出したいのですが、複数のコントロールをボタンで表示非表示を行いたいので、配列化したいと考えているのですが、どのようにすればよいですか？

public testControl() as Object
Private Sub Form_Load(...
testControl(0) = New Test1.Form1
testControl(1) = New Test2.Form1
testControl(2) = New Test3.Form1
...
For i = 0 to 10
testcontrol(i).Location = New Point(0,0)
testcontrol(i).Size = New Size(100,100)
testcontrol(i).Visible = False
Next
End Sub
見たいな処理を行いたいと考えています。
ほかによい方法があれば教えてください。

回答No.1

AlexSuns · ベストアンサー

？
問題点が良くわからないのですが？

下記のどの点がわからないのでしょうか？
・ユーザコントロールを作成したい
・コントロールライブラリ(DLL)をプロジェクトから参照したい
・ユーザコントロールを配列化したい
・ユーザコントロールを動的に配置したい

とちあえず、ラベルを使用した場合はこのような感じでやります
環境：WindowsVista+VB2005

Imports System
Imports System.Windows.Forms
Imports System.Collections.Generic
Imports System.Collections

Public Class Form3

　　Private _labels As Label()　　　　　　　'ラベル配列
　　Private _labelCount As Integer = 10　　 'ラベル配列のカウント

　　''コンストラクタ
　　Public Sub New()

　　　　' この呼び出しは、Windows フォーム デザイナで必要です。
　　　　InitializeComponent()

　　　　' InitializeComponent() 呼び出しの後で初期化を追加します。
　　　　Me._labels = Me.createLabels2005(Me._labelCount)

　　End Sub

　　''ボタン１をクリック時にラベル(配列)を配置する
　　Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
　　　　Dim labelHeight As Integer = 20
　　　　For i As Integer = 0 To Me._labelCount - 1 Step 1
　　　　　　With Me._labels(i)
　　　　　　　　.Location = New Point(10, 10 + (labelHeight * i))
　　　　　　　　.Size = New Size(100, labelHeight)
　　　　　　　　.Text = String.Format("ラベル{0}", i)
　　　　　　End With
　　　　　　Me.Controls.Add(Me._labels(i))
　　　　Next
　　End Sub

　　''ボタン２をクリック時にラベルの表示/非表示設定を切り替える
　　Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
　　　　Dim labelVisible As Boolean = Not Me._labels(0).Visible
　　　　For i As Integer = 0 To Me._labelCount - 1 Step 1
　　　　　　Me._labels(i).Visible = labelVisible
　　　　Next
　　End Sub

　　''指定されたカウント分のラベルを返す(2005用)
　　Private Function createLabels2005(ByVal count As Integer) As Label()
　　　　Dim labels As New List(Of Label)
　　　　For i As Integer = 0 To count - 1 Step 1
　　　　　　labels.Add(New Label())
　　　　Next
　　　　Return labels.ToArray()
　　End Function

　　''指定されたカウント分のラベルを返す(2002/2003用)
　　Private Function createLabels2003(ByVal count As Integer) As Label()
　　　　Dim labels As New ArrayList()
　　　　For i As Integer = 0 To count - 1 Step 1
　　　　　　labels.Add(New Label())
　　　　Next
　　　　Return CType(labels.ToArray(GetType(Label)), Label())
　　End Function

End Class

お礼

AlexSunsさん早速の回答ありがとうございます。

「testControl」の宣言時に配列数を宣言してあげることで問題は解決しました。
ユーザーコントロールなので、一応「Object」から「UserControl」に型は変更しておきました。

ありがとうございました。