【VB2005】コントロールを配列に。

質問

下記のコードを変更して、コントロールの値を配列に代入して、
その値をもとに、ボタンを複製して追加したいと思っています。

Public Class frmStart

Dim btnNewButton1 As New Button

Private Sub frmStart_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

NewButton1.Text = "処理1"

btnNewButton1.ForeColor = Color.DimGray
btnNewButton1.Location = New Point(10, 100)
btnNewButton1.Size = New Size(180, 30)

'// ボタンを追加します
Me.Controls.Add(btnNewButton1)

end sub

End Class

やりたいことは、Dim btnNewButton() As New Button　のようにデータを配列にして、

btnNewButton(0).ForeColor = Color.DimGray
btnNewButton(0).Location = New Point(10, 100)
btnNewButton(0).Size = New Size(180, 30)

btnNewButton(1).ForeColor = Color.DimGray
btnNewButton(1).Location = New Point(380, 100)
btnNewButton(1).Size = New Size(180, 30)

'// ボタンを追加します
Me.Controls.Add(btnNewButton(0))
　　　　Me.Controls.Add(btnNewButton(1))

という事をしたいのですが、方法が解らなくて困ってます。
お知恵を貸してください。

回答No.1

unamana19 · ベストアンサー

VB2005でコントロール配列は、VB6のようにはいきませんから、面倒ですよね。
面倒ですけど、配列に格納して、イベントを割り付けるみたいなことをしないと駄目ですね。

Public Class Form1

　　Private _Buttons As New List(Of Button)

　　Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

　　　　'ボタンを配列に追加
　　　　Me._Buttons.Add(New Button)
　　　　Me._Buttons.Add(New Button)
　　　　Me._Buttons.Add(New Button)

　　　　'初期化
　　　　For i As Integer = 0 To Me._Buttons.Count - 1
　　　　　　''フォームへボタンを追加
　　　　　　Me.Controls.Add(Me._Buttons(i))

　　　　　　''Clickイベント
　　　　　　AddHandler Me._Buttons(i).Click, AddressOf Buttons_Click

　　　　　　''Buttonのプロパティを設定
　　　　　　With Me._Buttons(i)
　　　　　　　　.Text = i.ToString
　　　　　　　　.ForeColor = Color.DimGray
　　　　　　　　.Location = New Point(10, i * 50)
　　　　　　　　.Size = New Size(180, 30)
　　　　　　　　.Tag = i.ToString
　　　　　　End With
　　　　Next

　　End Sub

　　Private Sub Buttons_Click(ByVal sender As System.Object, ByVal e As System.EventArgs)
　　　　Dim btn As Button = CType(sender, Button)
　　　　If btn.Tag Is Nothing Then Exit Sub
　　　　MessageBox.Show(String.Format("{0}番のボタンが押されました", btn.Tag.ToString), "クリック")
　　End Sub

End Class

このサンプルでは、ButtonのTagプロパティに配列番号を格納して、それをもとに、どのボタンが
押されたかを判断しています。

【注意】上記ソースの空白は、表示の関係で全角スペースになっています。

お礼

自分の先輩など、教えてもらいながら、仮のコードが
できたのですが、配列の考えまではTagっぽいと思ってたのですが、
一般的に使えると思って、ほっとしました。
自分のやり方↓
Public Class frmStart
Dim btnNewButton() As Button
Private Sub frmStart_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

Dim intCnt As Integer
Dim intIndex As Integer
Dim intLocation() As Integer

intIndex = 8

ReDim intLocation(intIndex)
ReDim btnNewButton(intIndex)

For intCnt = 0 To intIndex

Select Case intCnt
Case 0, 3, 6
intLocation(intCnt) = 69
Case 1, 4, 7
intLocation(intCnt) = 255
Case 2, 5, 8
intLocation(intCnt) = 441
End Select

Next

For intCnt = 0 To intIndex
btnNewButton(intCnt) = New Button
Next

For intCnt = 0 To intIndex
btnNewButton(intCnt).Text = intCnt
btnNewButton(intCnt).ForeColor = Color.DimGray
btnNewButton(intCnt).Size = New Size(180, 30)
Select Case intCnt

Case 0 To 2
btnNewButton(intCnt).Location = New Point(intLocation(intCnt), 83)
Case 3 To 5
btnNewButton(intCnt).Location = New Point(intLocation(intCnt), 119)
Case 6 To 8
btnNewButton(intCnt).Location = New Point(intLocation(intCnt), 155)
End Select

'// ボタンを追加します
Me.Controls.Add(btnNewButton(intCnt))

'// 関連付けるイベント
AddHandler btnNewButton(intCnt).Click, AddressOf btnNewButton_Click

Next

End Sub

クリックイベントは省略してます。