VB6でのプリンタ設定について

質問

メモ帳等のように通常使うプリンタを変更することなく、アプリが起動している間は
任意のプリンタを選択することが出来、アプリ専用のプリンタ設定を保持するには
どうしたらいいでしょう。

1.OpenPrinter
2.GetPrinter で PRINTER_INFO_2 から DEVMODE を取得
3.DEVNAMES を設定
4.PRINTDLG で設定画面を表示

上記の手順でプリントダイアログを表示するとこまでは出来ましたが
ここで設定された情報を Printer オブジェクトに反映させる方法がわかりません。

ResetDC だと色、用紙の向きなど基本的なものは反映されましたがプリンタ固有の
情報（スタンプマークなど）までは反映されませんでした。

SetPrinter だとすべての情報が反映されましたが通常使うプリンタの設定まで
変わってしまいました。

わかりづらい部分が多々あるとは思いますが、どなたか教えていただけませんでしょうか
よろしくお願いします。

VB6
XP SP2

回答No.3

kiki_s

>変えないようにも出来るのでしょうか？

APIで一時的に変更出来るかは分かりません。
しかし方法は色々あると思います。

例えば・・・
印刷時に現在の設定を記憶、変更して、印刷終了時に元に戻す
（プリンタ設定を表示させずに変更する）
※この方法は可能かどうかです

アプリ起動時に現在の設定を記憶、変更して、印刷終了時に元に戻す
※この方法はアプリが異常終了などのトラブルがあった場合対処出来ません。

お礼

ありがとうございます、もう少しトライしてみます。

補足

下記のサイトからダウンロードしたPrinterModule.basとWin32API.basを使用して
プリント機能を実現することが出来ました。
http://www.itmedia.co.jp/help/howto/win/win2000/0007complus_vb/chap07/65.html

もうかなり前のことで申し訳ないのですが、おかしな箇所がありましたら
アドバイスしてもらえませんでしょうか？よろしくお願いします。

ソースコードは下記の通りです。

'Form1
Option Explicit

Private Sub Command1_Click()

Dim ret As Long

　　ret = PrintSetup2(PD_PRINTSETUP, Me.hWnd)
End Sub

Private Sub Command2_Click()

Dim ret As Long

　　ret = PrintSetup2(0, Me.hWnd)

　　If ret = True Then
　　　　Printer.ForeColor = vbRed
　　　　Printer.Print "ABCDEFG"
　　　　Printer.EndDoc
　　End If
End Sub

'Module1
Option Explicit

Public Declare Function ResetDC Lib "gdi32" Alias "ResetDCA" (ByVal hdc As Long, lpInitData As Any) As Long
Public Declare Function DeviceCapabilities Lib "winspool.drv" Alias "DeviceCapabilitiesA" (ByVal lpDeviceName As String, ByVal lpPort As String, ByVal iIndex As Long, lpOutput As Any, ByVal Dev As Long) As Long

Public Const DC_SIZE = 8
Public Const DC_EXTRA = 9

Public vDevModeData() As Byte
Public PrinterName As String
Public NeedSize As Long

Public Function PrintSetup2(ByVal Flags As Long, ByVal FormHwnd As Long) As Boolean

Dim lpDevMode As Long
Dim lpDevNames As Long
Dim hDevMode As Long
Dim hDevNames As Long
Dim dmSize As Long
Dim DmExSize As Long
Dim Pri As Printer
Dim ret As Long

If PrinterName = "" Then

　　For Each Pri In Printers
　　　　dmSize = DeviceCapabilities(Pri.DeviceName, Pri.Port, DC_SIZE, ByVal vbNullString, 0)
　　　　DmExSize = DeviceCapabilities(Pri.DeviceName, Pri.Port, DC_EXTRA, ByVal vbNullString, 0)

　　　　If dmSize + DmExSize > NeedSize Then
　　　　　　NeedSize = dmSize + DmExSize
　　　　End If
　　Next

　　NeedSize = NeedSize + 100
　　ReDim vDevModeData(0 To NeedSize - 1) As Byte

Else
　　hDevMode = GlobalAlloc(GHND, NeedSize)
　　lpDevMode = GlobalLock(hDevMode)
　　CopyMemory ByVal lpDevMode, vDevModeData(0), NeedSize
　　GlobalUnlock hDevMode

　　hDevNames = GlobalAlloc(GHND, Len(vDevNames))
　　lpDevNames = GlobalLock(hDevNames)
　　CopyMemory ByVal lpDevNames, vDevNames, Len(vDevNames)
　　GlobalUnlock hDevNames
End If

vPrintDlg.lStructSize = Len(vPrintDlg)
vPrintDlg.hwndOwner = FormHwnd
vPrintDlg.hDevMode = hDevMode
vPrintDlg.hDevNames = hDevNames
vPrintDlg.Flags = Flags

If PRINTDLG(vPrintDlg) <> 0 Then

　　If vPrintDlg.hDevMode <> 0 Then
　　　　lpDevMode = GlobalLock(vPrintDlg.hDevMode)
　　　　CopyMemory vDevModeData(0), ByVal lpDevMode, NeedSize
　　　　GlobalUnlock lpDevMode
　　　　GlobalFree vPrintDlg.hDevMode
　　End If

　　If vPrintDlg.hDevNames <> 0 Then
　　　　lpDevNames = GlobalLock(vPrintDlg.hDevNames)
　　　　CopyMemory vDevNames, ByVal lpDevNames, Len(vDevNames)
　　　　GlobalUnlock lpDevNames
　　　　GlobalFree vPrintDlg.hDevNames
　　End If

　　PrinterName = Mid(vDevNames.extData, vDevNames.wDeviceOffset - 8 + 1)
　　PrinterName = Left(PrinterName, InStr(PrinterName, Chr(0)) - 1)

　　For Each Pri In Printers
　　　　If UCase(Pri.DeviceName) = UCase(PrinterName) Then
　　　　　　Set Printer = Pri
　　　　　　Exit For
　　　　End If
　　Next

　　ret = ResetDC(Printer.hdc, vDevModeData(0))
　　If ret = 0 Then Exit Function

　　PrintSetup2 = True

Else
　　PrintSetup2 = False
End If

End Function