ヘルプの起動のしかた

質問

こんにちは。
最近、ＶＢ６を始めた初心者です。
HelpDesignerでヘルプファイルを作成したのですが、これを
自作したＶＢ６アプリケーションから起動をかけるようにしたいのですが
どのようにすれば良いのでしょう？
shellを使い
Private Sub suihelp_Click()
　Dim retVal As Variant
　retVal = Shell("App.Path & " \ " & Helpsim.hlp")
End Sub
としてみたのですがダメでした。
ヘルプファイル名はHelpsim.hlpです。どなたか分かる方がみえましたら
よろしくお願いします。

回答No.1

project-a · ベストアンサー

ヘルプファイルの表示には、APIを使用します。
以下のようにすれば、ＯＫだと思います。

(例）
<<標準モジュール>>
Declare Function WinHelp Lib "user32" Alias "WinHelpA" (ByVal hwnd As Long, ByVal lpHelpFile As String, ByVal wCommand As Long, dwData As Any) As Long

Public Const HELP_CONTEXTPOPUP = &H8&
Public Const HELP_COMMAND = &H102&
Public Const HELP_FINDER = &HB
Public Const HELP_FORCEFILE = &H9&
Public Const HELP_HELPONHELP = &H4
Public Const HELP_INDEX = &H3
Public Const HELP_KEY = &H101
Public Const HELP_MULTIKEY = &H201&
Public Const HELP_PARTIALKEY = &H105&
Public Const HELP_QUIT = &H2
Public Const HELP_SETCONTENTS = &H5&
Public Const HELP_SETINDEX = &H5
Public Const HELP_SETWINPOS = &H203&
Public Const HELP_CONTEXT = &H1

------------------------------------------------
<<画面>>
'フォームを読み込んだ。
Private Sub Form_Load()
'ヘルプファイルの指定
If Right$(App.Path, 1) = "\" Then
App.HelpFile = App.Path + "Helpsim.hlp"
Else
App.HelpFile = App.Path + "\Helpsim.hlp"
End If
End Sub

'フォームを閉じた。
Private Sub Form_Unload(Cancel As Integer)
Dim ret As Long
ret = WinHelp(hwnd, App.HelpFile, HELP_QUIT, 0)
End Sub

'ヘルプボタンを押した（目次の表示）
Private Sub suihelp_Click()
　Dim retVal As Long
retVal = WinHelp(hwnd, App.HelpFile, HELP_FINDER, 0)
End Sub

お礼

project-aさま
完璧です。ありがとうございました。これでやっとヘルプファイルが読み出せるようになりました。
ＶＢを使用していろいろなソフトが作るのが最近楽しくてたまりません。
これからもお世話になるかも知れませんがその時はよろしくお願いします。
では