［excel］複数のコメントをコピーしたい。

質問

編集　→　ジャンプ　→　セルの選択　→　コメント　→　ＯＫ

ctrl　＋　V　をすると

「そのコマンドは複数の選択範囲に対して実行できません。」
と出てできません。

ランダムにコメントが100個くらいあり、
一気にまとめて他シートに移したいのですが
どうすればよいのでしょうか？

よろしくお願い致します。

回答No.3

KenKen_SP · ベストアンサー

こんにちは。

下記のマクロで一括コピーできます。標準モジュールにコピペして下さい。

コピーではなく切り取りの場合は、※記号の次行にある先頭の（’）記号を
削除して下さい。

　　' Cmt.Delet　　--->　　Cmt.Delete

’シート内のコメントを他シートに全てコピーする
Sub CopyComments()

　　Dim rngDst As Range
　　Dim Sh_Src As Worksheet
　　Dim Sh_Dst As Worksheet
　　Dim Cmt　　As Comment

　　Const REF_CELL = 8 ' セル参照 (Range オブジェクト)

　　On Error Resume Next
　　Set rngDst = Application.InputBox( _
　　　　Prompt:="現在のシートにあるコメントを他シートにコピーします。" & vbLf _
　　　　　　　& "コピー先シートの任意のセルをひとつ選択して下さい。", _
　　　　Title:="コメントのコピー", _
　　　　Type:=REF_CELL)
　　If rngDst Is Nothing Or rngDst.Parent Is ActiveSheet Then
　　　　Exit Sub
　　End If
　　On Error GoTo 0

　　Application.ScreenUpdating = False
　　Set Sh_Dst = rngDst.Parent
　　Set Sh_Src = ActiveSheet
　　Sh_Dst.Activate
　　For Each Cmt In Sh_Src.Comments
　　　　With Cmt.Parent
　　　　　　.Copy
　　　　　　Sh_Dst.Range(.Address).PasteSpecial Paste:=xlPasteComments
　　　　End With
　　　　' ※コピー元のコメントを削除する場合はコメント解除
　　　　' Cmt.Delete
　　Next
　　Application.CutCopyMode = False
　　Application.ScreenUpdating = True

　　Set Sh_Dst = Nothing
　　Set Sh_Src = Nothing
　　Set rngDst = Nothing

End Sub

お礼

ご回答ありがとうございました。

回答No.4

KenKen_SP

#2 ご回答を見て
あーー。。マクロを使うまでもなかったですね...(´Д⊂
すみません...#3 はスルーして下さい。

お礼

ご回答ありがとうございました。

回答No.2

misatoanna

コピー～貼り付け
　　コメントのあるセルを含む範囲を選択してコピーし、コピー先で形式を選択
　　してコメントだけ貼り付けます。

元コメントの削除
　　編集 → ジャンプ → セルの選択 → コメント → ＯＫ　で選択されたセル
　　のひとつを右クリックし、「コメントの削除」を指定します。

お礼

ご回答ありがとうございました。

回答No.1

natsumipapa

シートごとコピーしてから、必要ならデータ削除して
コメントだけ残したほうが早いと思いますが…

お礼

その手がありましたね。
ご回答ありがとうございました。