OKWAVEのAI「あい」が美容・健康の悩みに最適な回答をご提案!
-PR-
解決
済み

VBにて起動アプリの取得

  • すぐに回答を!
  • 質問No.200123
  • 閲覧数171
  • ありがとう数1
  • 気になる数0
  • 回答数1
  • コメント数0

お礼率 30% (6/20)

VB6.0にて開発しています。

自分の端末でEXCELを使用している際
どのブックを開いているかVB側にて取得
する方法を教えて下さい。

現状)VBからあるフォルダのBOOKを
コピーし、そのBOOKにデータを
貼り付けています。しかし他のBO
OKを開いているとメモリエラーが
起こります。その為EXCELが立
ち上がっていたら警告を出そうと思
います。
通報する
  • 回答数1
  • 気になる
    質問をブックマークします。
    マイページでまとめて確認できます。

質問者が選んだベストアンサー

  • 回答No.1
レベル12

ベストアンサー率 65% (276/422)

サンプルです。

プロジェクトの参照設定で
Microsoft Excel x.0 Object Libraryを指定
(x.0はエクセルのバージョンによって、違う数字です)


Option Explicit

Sub Main()
  Dim xlApp  As Excel.Application
  Dim xlBook As Excel.Workbook
  Dim strDebug As String
  Dim strPath As String
  
  '起動しているエクセルアプリを取得する
  On Error Resume Next
  Set xlApp = GetObject(, "Excel.Application")
  On Error GoTo 0
  
  '取得失敗
  If xlApp Is Nothing Then
    Debug.Print "EXCELは起動していないようです"
  
  '取得成功
  Else
    'これより情報をデバッグウィンドウに出力
    Debug.Print xlApp.Workbooks.Count & "冊のワークブックが見つかりました"
    'ブックが存在する分だけ、ブックの情報を記す
    For Each xlBook In xlApp.Workbooks
      strPath = xlBook.Path
      If strPath = "" Then
        strPath = "未保存"
      End If
      strDebug = xlBook.Name & "[" & strPath & "]"
      Debug.Print strDebug
'      xlBook.Close False '保存せずにブックを終了させる時
    Next xlBook
    
'    xlApp.Quit   'エクセルアプリを終了させる時
    Set xlApp = Nothing
  End If
End Sub
お礼コメント
papa_kun

お礼率 30% (6/20)

助かりました。本当に有難うございます。
投稿日時 - 2002-01-17 17:05:42
-PR-
-PR-
このQ&Aのテーマ
このQ&Aで解決しましたか?
関連するQ&A
-PR-
-PR-
こんな書き方もあるよ!この情報は知ってる?あなたの知識を教えて!
このQ&Aにはまだコメントがありません。
あなたの思ったこと、知っていることをここにコメントしてみましょう。

その他の関連するQ&A、テーマをキーワードで探す

キーワードでQ&A、テーマを検索する
-PR-
-PR-
-PR-

特集


いま みんなが気になるQ&A

関連するQ&A

-PR-

ピックアップ

-PR-
ページ先頭へ