Excelのセルに沿って罫線や棒線を引きたい

質問

Excel上の指定した二つのセルを結ぶような、横の棒線を引きたいのですが…
例えばセル番号 （x(1),y(1)） と （x(2),y(1)） で、上側の罫線でもなく下側の罫線でもなく、その中間に
引くイメージです。

また、上側の罫線を引く場合、もしくは下側の罫線を引く場合はどうしたらよいでしょうか。

回答No.3

Wendy02 · ベストアンサー

こんばんは。

以下は、2つのセルを結ぶように出来ています。
範囲を選択すれば、左端（または左端上）と右端（または右下端）のセルの真中にライン罫線が結ばれます。

MYSELECT の定数を
上側の罫線を引く場合－１、もしくは下側の罫線を引く場合－３
にしてください。

なお、端と端を結ぶ場合は、
a.Width / 2
b.Width / 2

となっている部分を取り去ればよいです。
比較的基本的なコードなのですが、この手のものは、相手の環境次第で、意外に、気が付かない失敗が出てきますので、経験的に気をつけたつもりですが、私のが必ずしもうまくいくとは限りません。

'標準モジュール
'-------------------------------------------------
Type Rect
　　x As Double
　　y As Double
End Type
Sub LineMakingBetweenCells()
　 Dim a As Range
　 Dim b As Range
　 Dim Asize As Rect
　 Dim Bsize As Rect

　 '罫線位置
　 Const MYSELECT As Integer = 2 '1-上, 2-中, 3-下

　 If TypeName(Selection) <> "Range" Then Exit Sub
　 If Selection.Areas.Count = 2 Then
　　　Set a = Selection.Areas(1)
　　　Set b = Selection.Areas(2)
　 ElseIf Selection.Count > 1 Then
　　　Set a = Selection.Cells(1, 1)
　　　Set b = Selection.Cells(Selection.Count)
　　　Else
　　　MsgBox "正しく2点のセルを選択していません。"
　　　Exit Sub
　 End If

　 With Asize
　　　Select Case MYSELECT
　　　　 Case 1 '上
　　　　　　.y = a.Top: .x = a.Left + a.Width / 2
　　　　 Case 2 '中
　　　　　　.y = a.Top + a.Height / 2: .x = a.Left + a.Width / 2
　　　　 Case 3 '下
　　　　　　.y = a.Top + a.Height: .x = a.Left + a.Width / 2
　　　End Select
　 End With
　 With Bsize
　　　Select Case MYSELECT
　　　　 Case 1
　　　　　　.y = b.Top: .x = b.Left + b.Width / 2
　　　　 Case 2
　　　　　　.y = b.Top + b.Height / 2: .x = b.Left + b.Width / 2
　　　　 Case 3
　　　　　　.y = b.Top + b.Height: .x = b.Left + b.Width / 2
　　　　 Case Else
　　　　　　MsgBox "MYSELECT の設定がヘンです", vbCritical
　　　　　　Exit Sub
　　　End Select
　 End With

　 With ActiveSheet.Shapes.AddLine(Asize.x, Asize.y, Bsize.x, Bsize.y)
　　　.Line.Weight = 0.75
　　　.Line.DashStyle = msoLineSolid
　　　.Line.Visible = msoTrue
　　　.Line.ForeColor.SchemeColor = 8
　 End With
End Sub

'------------------------------------------------

お礼

なるほど、このように考えるのですか。実装してみたところうまく動きました。ありがとうございます。

回答No.4

imogasi

オートシェイプの線をAddLineメソッドで引けばよい。
２セルの指定はどうするのですか。そこが難しい課題を持ち込むと思います。
斜め方向の結線を考えていますか。
それに言葉の表現に気をつけてください。
＞横の棒線
横線
＞セル番号 （x(1),y(1)） と （x(2),y(1)） で
エクセルのセルには番地という表現方法があります。それに従ってください。B3とH3セルを結ぶとか
＞上側の罫線を引く場合
普通の罫線を利用するのとどう違いますか

お礼

曖昧なるイメージのみに頼った不正確な表現、誠にもって汗顔、恐悦至極の面伏せ物の質問でございました。

回答No.2

o_tooru

こんばんは、疑問はつきませんね。

さてご質問の件ですが、基本的には、セルの外側に色を塗る様な概念の罫線ですね。後別解としては、オートシェイプで、線を置くと言うことも出来ますけど。

この二つくらいしか思い浮かびません。

お礼

VBAの本を見ていたら、確かにオートシェイブを扱うものがありました。応用できそうです（汗）

回答No.1

noname#22222

罫線の概念には該当するようなものは存在しないと思います。
Excelの与件のなかで工夫するしかないでしょう。

お礼

うー難しそうですねー。